1SUMMARY = "Document type definitions for verification of XML data files"
2DESCRIPTION = "Document type definitions for verification of XML data \
3files against the DocBook rule set, it ships with the latest DocBook 4.5 \
4XML DTD, as well as a selected set of legacy DTDs for use with older \
5documents, including 4.0, 4.1.2, 4.2, 4.3 and 4.4"
6HOMEPAGE = "http://www.docbook.org/xml/"
7
8LICENSE = "OASIS"
9LIC_FILES_CHKSUM = "file://${WORKDIR}/LICENSE-OASIS;md5=c608985dd5f7f215e669e7639a0b1d2e"
10
11DEPENDS = "libxml2-native"
12
13# Note: the upstream sources are not distributed with a license file.
14# LICENSE-OASIS is included as a "patch" to workaround this. When
15# upgrading this recipe, please verify whether this is still needed.
16SRC_URI = "http://snapshot.debian.org/archive/debian/20160728T043443Z/pool/main/d/docbook-xml/docbook-xml_${PV}.orig.tar.gz \
17           file://LICENSE-OASIS \
18           file://docbook-xml-update-catalog.xml.patch \
19"
20
21SRC_URI[md5sum] = "487b4d44e15cffb1f4048af23f98208e"
22SRC_URI[sha256sum] = "b0f8edcf697f5318e63dd98c9a931f3fee167af0805ba441db372e0f17b2a44f"
23
24UPSTREAM_CHECK_URI = "${DEBIAN_MIRROR}/main/d/docbook-xml/"
25
26S = "${WORKDIR}/docbook-xml-4.5.c31424"
27
28inherit allarch
29BBCLASSEXTEND = "native"
30
31do_configure (){
32    :
33}
34
35do_compile (){
36    :
37}
38
39do_install () {
40    install -d ${D}${sysconfdir}/xml/
41    xmlcatalog --create --noout ${D}${sysconfdir}/xml/docbook-xml.xml
42
43    for DTDVERSION in 4.0 4.1.2 4.2 4.3 4.4 4.5; do
44        DEST=${datadir}/xml/docbook/schema/dtd/$DTDVERSION
45        install -d -m 755 ${D}$DEST
46        cp -v -R docbook-$DTDVERSION/* ${D}$DEST
47        xmlcatalog --verbose --noout --add nextCatalog unused file://$DEST/catalog.xml ${D}${sysconfdir}/xml/docbook-xml.xml
48    done
49}
50
51XMLCATALOGS = "${sysconfdir}/xml/docbook-xml.xml"
52inherit xmlcatalog
53
54FILES_${PN} = "${datadir}/* ${sysconfdir}/xml/docbook-xml.xml"
55