1SUMMARY = "C implementation of createrepo."
2HOMEPAGE = "https://github.com/rpm-software-management/createrepo_c/wiki"
3
4LICENSE = "GPL-2.0-only"
5LIC_FILES_CHKSUM = "file://COPYING;md5=b234ee4d69f5fce4486a80fdaf4a4263"
6
7SRC_URI = "git://github.com/rpm-software-management/createrepo_c;branch=master;protocol=https \
8           file://0001-Do-not-set-PYTHON_INSTALL_DIR-by-running-python.patch \
9           file://0001-include-rpm-rpmstring.h.patch \
10           "
11
12SRCREV = "10a8a7af4f1de3f98a21a7d08fe3a46ef306d197"
13
14S = "${WORKDIR}/git"
15
16DEPENDS = "expat curl glib-2.0 libxml2 openssl bzip2 zlib file sqlite3 xz rpm"
17DEPENDS:append:class-native = " file-replacement-native"
18
19inherit cmake pkgconfig bash-completion setuptools3-base
20
21EXTRA_OECMAKE = " -DPYTHON_INSTALL_DIR=${PYTHON_SITEPACKAGES_DIR} -DPYTHON_DESIRED=3 -DWITH_ZCHUNK=OFF -DENABLE_DRPM=OFF -DWITH_LIBMODULEMD=OFF"
22
23BBCLASSEXTEND = "native nativesdk"
24
25# Direct createrepo to read rpm configuration from our sysroot, not the one it was compiled in
26do_install:append:class-native() {
27        create_wrapper ${D}/${bindir}/createrepo_c \
28                RPM_CONFIGDIR=${STAGING_LIBDIR_NATIVE}/rpm \
29                MAGIC=${STAGING_DIR_NATIVE}${datadir_native}/misc/magic.mgc
30        create_wrapper ${D}/${bindir}/modifyrepo_c \
31                MAGIC=${STAGING_DIR_NATIVE}${datadir_native}/misc/magic.mgc
32}
33
34do_install:append:class-nativesdk() {
35        create_wrapper ${D}/${bindir}/createrepo_c \
36                RPM_CONFIGDIR=${SDKPATHNATIVE}${libdir_nativesdk}/rpm \
37                MAGIC=${datadir}/misc/magic.mgc
38        create_wrapper ${D}/${bindir}/modifyrepo_c \
39                MAGIC=${datadir}/misc/magic.mgc
40        rm -rf ${D}/etc
41}
42