1require automake.inc
2LICENSE = "GPL-2.0-only"
3LIC_FILES_CHKSUM = "file://COPYING;md5=751419260aa954499f7abaabaa882bbe"
4DEPENDS:class-native = "autoconf-native"
5
6NAMEVER = "${@oe.utils.trim_version("${PV}", 2)}"
7
8RDEPENDS:${PN} += "\
9    autoconf \
10    perl \
11    perl-module-bytes \
12    perl-module-data-dumper \
13    perl-module-strict \
14    perl-module-text-parsewords \
15    perl-module-thread-queue \
16    perl-module-threads \
17    perl-module-vars "
18
19RDEPENDS:${PN}:class-native = "autoconf-native hostperl-runtime-native"
20
21SRC_URI += "\
22           file://0001-automake-Update-for-python.m4-to-respect-libdir.patch \
23           file://buildtest.patch \
24           file://performance.patch \
25           file://new_rt_path_for_test-driver.patch \
26           file://0001-automake-Add-default-libtool_tag-to-cppasm.patch \
27           file://0001-build-fix-race-in-parallel-builds.patch \
28           file://0001-Drop-ar-u-argument.patch \
29           "
30
31SRC_URI[sha256sum] = "07bd24ad08a64bc17250ce09ec56e921d6343903943e99ccf63bbf0705e34605"
32
33PERL = "${USRBINPATH}/perl"
34PERL:class-native = "${USRBINPATH}/env perl"
35PERL:class-nativesdk = "${USRBINPATH}/env perl"
36
37CACHED_CONFIGUREVARS += "ac_cv_path_PERL='${PERL}'"
38
39do_install:append () {
40    install -d ${D}${datadir}
41}
42
43BBCLASSEXTEND = "native nativesdk"
44