1SUMMARY = "Extra machine specific configuration files"
2HOMEPAGE = "https://wiki.gentoo.org/wiki/Eudev"
3DESCRIPTION = "Extra machine specific configuration files for udev, specifically information on devices to ignore."
4LICENSE = "MIT"
5LIC_FILES_CHKSUM = "file://${COREBASE}/meta/COPYING.MIT;md5=3da9cfbcb788c80a0384361b4de20420"
6
7SRC_URI = " \
8       file://automount.rules \
9       file://mount.sh \
10       file://mount.ignorelist \
11       file://autonet.rules \
12       file://network.sh \
13       file://localextra.rules \
14"
15
16S = "${WORKDIR}"
17
18MOUNT_BASE = "/run/media"
19
20do_install() {
21    install -d ${D}${sysconfdir}/udev/rules.d
22
23    install -m 0644 ${WORKDIR}/automount.rules     ${D}${sysconfdir}/udev/rules.d/automount.rules
24    install -m 0644 ${WORKDIR}/autonet.rules       ${D}${sysconfdir}/udev/rules.d/autonet.rules
25    install -m 0644 ${WORKDIR}/localextra.rules    ${D}${sysconfdir}/udev/rules.d/localextra.rules
26
27    install -d ${D}${sysconfdir}/udev/mount.ignorelist.d
28    install -m 0644 ${WORKDIR}/mount.ignorelist     ${D}${sysconfdir}/udev/
29
30    install -d ${D}${sysconfdir}/udev/scripts/
31
32    install -m 0755 ${WORKDIR}/mount.sh ${D}${sysconfdir}/udev/scripts/mount.sh
33    sed -i 's|@systemd_unitdir@|${systemd_unitdir}|g' ${D}${sysconfdir}/udev/scripts/mount.sh
34    sed -i 's|@base_sbindir@|${base_sbindir}|g' ${D}${sysconfdir}/udev/scripts/mount.sh
35    sed -i 's|@MOUNT_BASE@|${MOUNT_BASE}|g' ${D}${sysconfdir}/udev/scripts/mount.sh
36
37    install -m 0755 ${WORKDIR}/network.sh ${D}${sysconfdir}/udev/scripts
38}
39
40pkg_postinst:${PN} () {
41	if [ -e $D${systemd_unitdir}/system/systemd-udevd.service ]; then
42		sed -i "/\[Service\]/aMountFlags=shared" $D${systemd_unitdir}/system/systemd-udevd.service
43	fi
44}
45
46pkg_postrm:${PN} () {
47	if [ -e $D${systemd_unitdir}/system/systemd-udevd.service ]; then
48		sed -i "/MountFlags=shared/d" $D${systemd_unitdir}/system/systemd-udevd.service
49	fi
50}
51
52RDEPENDS:${PN} = "udev util-linux-blkid ${@bb.utils.contains('DISTRO_FEATURES', 'systemd', 'util-linux-lsblk', '', d)}"
53CONFFILES:${PN} = "${sysconfdir}/udev/mount.ignorelist"
54
55# to replace udev-extra-rules from meta-oe
56RPROVIDES:${PN} = "udev-extra-rules"
57RREPLACES:${PN} = "udev-extra-rules"
58RCONFLICTS:${PN} = "udev-extra-rules"
59