1SUMMARY = "Userspace framebuffer boot logo based on usplash"
2DESCRIPTION = "PSplash is a userspace graphical boot splash screen for mainly embedded Linux devices supporting a 16bpp or 32bpp framebuffer. It has few dependencies (just libc), supports basic images and text and handles rotation. Its visual look is configurable by basic source changes. Also included is a 'client' command utility for sending information to psplash such as boot progress information."
3HOMEPAGE = "http://git.yoctoproject.org/cgit/cgit.cgi/psplash"
4SECTION = "base"
5LICENSE = "GPL-2.0-or-later"
6LIC_FILES_CHKSUM = "file://psplash.h;beginline=1;endline=8;md5=8f232c1e95929eacab37f00900580224"
7DEPENDS = "gdk-pixbuf-native"
8
9SRCREV = "44afb7506d43cca15582b4c5b90ba5580344d75d"
10PV = "0.1+git${SRCPV}"
11
12SRC_URI = "git://git.yoctoproject.org/${BPN};branch=master \
13           file://psplash-init \
14           file://psplash-start.service \
15           file://psplash-systemd.service \
16           ${SPLASH_IMAGES}"
17UPSTREAM_CHECK_COMMITS = "1"
18
19SPLASH_IMAGES = "file://psplash-poky-img.h;outsuffix=default"
20
21python __anonymous() {
22    oldpkgs = d.getVar("PACKAGES").split()
23    splashfiles = d.getVar('SPLASH_IMAGES').split()
24    mlprefix = d.getVar('MLPREFIX') or ''
25    pkgs = []
26    localpaths = []
27    for uri in splashfiles:
28        fetcher = bb.fetch2.Fetch([uri], d)
29        flocal = os.path.basename(fetcher.localpath(uri))
30        fbase = os.path.splitext(flocal)[0]
31        outsuffix = fetcher.ud[uri].parm.get("outsuffix")
32        if not outsuffix:
33            if fbase.startswith("psplash-"):
34                outsuffix = fbase[8:]
35            else:
36                outsuffix = fbase
37            if outsuffix.endswith('-img'):
38                outsuffix = outsuffix[:-4]
39        outname = "psplash-%s" % outsuffix
40        if outname == '' or outname in oldpkgs:
41            bb.fatal("The output name '%s' derived from the URI %s is not valid, please specify the outsuffix parameter" % (outname, uri))
42        else:
43            pkgs.append(outname)
44        localpaths.append(flocal)
45
46    # Set these so that we have less work to do in do_compile and do_install:append
47    d.setVar("SPLASH_INSTALL", " ".join(pkgs))
48    d.setVar("SPLASH_LOCALPATHS", " ".join(localpaths))
49    for p in pkgs:
50        d.prependVar("PACKAGES", "%s%s " % (mlprefix, p))
51
52    pn = d.getVar('PN') or ''
53    for p in pkgs:
54        ep = '%s%s' % (mlprefix, p)
55        epsplash = '%s%s' % (mlprefix, 'psplash')
56        d.setVar("FILES:%s" % ep, "${bindir}/%s" % p)
57        d.setVar("ALTERNATIVE:%s" % ep, 'psplash')
58        d.setVarFlag("ALTERNATIVE_TARGET_%s" % ep, 'psplash', '${bindir}/%s' % p)
59        d.appendVar("RDEPENDS:%s" % ep, " %s" % pn)
60        if p == "psplash-default":
61            d.appendVar("RRECOMMENDS:%s" % pn, " %s" % ep)
62}
63
64S = "${WORKDIR}/git"
65
66inherit autotools pkgconfig update-rc.d update-alternatives systemd
67
68PACKAGECONFIG ??= "${@bb.utils.filter('DISTRO_FEATURES', 'systemd', d)}"
69
70PACKAGECONFIG[systemd] = "--with-systemd,--without-systemd,systemd"
71
72ALTERNATIVE_PRIORITY = "100"
73ALTERNATIVE_LINK_NAME[psplash] = "${bindir}/psplash"
74
75python do_compile () {
76    import shutil
77    import subprocess
78
79    # Build a separate executable for each splash image
80    workdir = d.getVar('WORKDIR')
81    convertscript = "%s/make-image-header.sh" % d.getVar('S')
82    destfile = "%s/psplash-poky-img.h" % d.getVar('B')
83    localfiles = d.getVar('SPLASH_LOCALPATHS').split()
84    outputfiles = d.getVar('SPLASH_INSTALL').split()
85    for localfile, outputfile in zip(localfiles, outputfiles):
86        if localfile.endswith(".png"):
87            if subprocess.call([ convertscript, os.path.join(workdir, localfile), 'POKY' ], cwd=workdir):
88                bb.fatal("Error calling convert script '%s'" % (convertscript))
89            fbase = os.path.splitext(localfile)[0]
90            shutil.copyfile(os.path.join(workdir, "%s-img.h" % fbase), destfile)
91        else:
92            shutil.copyfile(os.path.join(workdir, localfile), destfile)
93        # For some reason just updating the header is not enough, we have to touch the .c
94        # file in order to get it to rebuild
95        os.utime("%s/psplash.c" % d.getVar('S'), None)
96        bb.build.exec_func("oe_runmake", d)
97        shutil.copyfile("psplash", outputfile)
98}
99
100do_install:append() {
101	if ${@bb.utils.contains('DISTRO_FEATURES', 'sysvinit', 'true', 'false', d)}; then
102		install -d ${D}${sysconfdir}/init.d/
103		install -m 0755 ${WORKDIR}/psplash-init ${D}${sysconfdir}/init.d/psplash.sh
104
105		# make fifo for psplash
106		install -d ${D}/mnt
107		mkfifo ${D}/mnt/psplash_fifo
108	fi
109
110	if ${@bb.utils.contains('DISTRO_FEATURES', 'systemd', 'true', 'false', d)}; then
111		install -d ${D}${systemd_system_unitdir}
112		install -m 644 ${WORKDIR}/psplash-start.service ${D}/${systemd_system_unitdir}
113		install -m 644 ${WORKDIR}/psplash-systemd.service ${D}/${systemd_system_unitdir}
114	fi
115
116	install -d ${D}${bindir}
117	for i in ${SPLASH_INSTALL} ; do
118		install -m 0755 $i ${D}${bindir}/$i
119	done
120	rm -f ${D}${bindir}/psplash
121}
122
123SYSTEMD_PACKAGES = "${@bb.utils.contains('DISTRO_FEATURES','systemd','${PN}','',d)}"
124SYSTEMD_SERVICE:${PN} += "${@bb.utils.contains('PACKAGECONFIG', 'systemd', 'psplash-start.service psplash-systemd.service', '', d)}"
125
126INITSCRIPT_NAME = "psplash.sh"
127INITSCRIPT_PARAMS = "start 0 S . stop 20 0 1 6 ."
128
129FILES:${PN} += "/mnt"
130