1SUMMARY = "Userspace framebuffer boot logo based on usplash"
2DESCRIPTION = "PSplash is a userspace graphical boot splash screen for mainly embedded Linux devices supporting a 16bpp or 32bpp framebuffer. It has few dependencies (just libc), supports basic images and text and handles rotation. Its visual look is configurable by basic source changes. Also included is a 'client' command utility for sending information to psplash such as boot progress information."
3HOMEPAGE = "http://git.yoctoproject.org/cgit/cgit.cgi/psplash"
4SECTION = "base"
5LICENSE = "GPLv2+"
6LIC_FILES_CHKSUM = "file://psplash.h;beginline=1;endline=8;md5=8f232c1e95929eacab37f00900580224"
7DEPENDS = "gdk-pixbuf-native"
8
9SRCREV = "0a902f7cd875ccf018456451be369f05fa55f962"
10PV = "0.1+git${SRCPV}"
11PR = "r15"
12
13SRC_URI = "git://git.yoctoproject.org/${BPN} \
14           file://psplash-init \
15           file://psplash-start.service \
16           file://psplash-systemd.service \
17           ${SPLASH_IMAGES}"
18UPSTREAM_CHECK_COMMITS = "1"
19
20SPLASH_IMAGES = "file://psplash-poky-img.h;outsuffix=default"
21
22python __anonymous() {
23    oldpkgs = d.getVar("PACKAGES").split()
24    splashfiles = d.getVar('SPLASH_IMAGES').split()
25    mlprefix = d.getVar('MLPREFIX') or ''
26    pkgs = []
27    localpaths = []
28    for uri in splashfiles:
29        fetcher = bb.fetch2.Fetch([uri], d)
30        flocal = os.path.basename(fetcher.localpath(uri))
31        fbase = os.path.splitext(flocal)[0]
32        outsuffix = fetcher.ud[uri].parm.get("outsuffix")
33        if not outsuffix:
34            if fbase.startswith("psplash-"):
35                outsuffix = fbase[8:]
36            else:
37                outsuffix = fbase
38            if outsuffix.endswith('-img'):
39                outsuffix = outsuffix[:-4]
40        outname = "psplash-%s" % outsuffix
41        if outname == '' or outname in oldpkgs:
42            bb.fatal("The output name '%s' derived from the URI %s is not valid, please specify the outsuffix parameter" % (outname, uri))
43        else:
44            pkgs.append(outname)
45        localpaths.append(flocal)
46
47    # Set these so that we have less work to do in do_compile and do_install:append
48    d.setVar("SPLASH_INSTALL", " ".join(pkgs))
49    d.setVar("SPLASH_LOCALPATHS", " ".join(localpaths))
50    for p in pkgs:
51        d.prependVar("PACKAGES", "%s%s " % (mlprefix, p))
52
53    pn = d.getVar('PN') or ''
54    for p in pkgs:
55        ep = '%s%s' % (mlprefix, p)
56        epsplash = '%s%s' % (mlprefix, 'psplash')
57        d.setVar("FILES:%s" % ep, "${bindir}/%s" % p)
58        d.setVar("ALTERNATIVE:%s" % ep, 'psplash')
59        d.setVarFlag("ALTERNATIVE_TARGET_%s" % ep, 'psplash', '${bindir}/%s' % p)
60        d.appendVar("RDEPENDS:%s" % ep, " %s" % pn)
61        if p == "psplash-default":
62            d.appendVar("RRECOMMENDS:%s" % pn, " %s" % ep)
63}
64
65S = "${WORKDIR}/git"
66
67inherit autotools pkgconfig update-rc.d update-alternatives systemd
68
69PACKAGECONFIG ??= "${@bb.utils.filter('DISTRO_FEATURES', 'systemd', d)}"
70
71PACKAGECONFIG[systemd] = "--with-systemd,--without-systemd,systemd"
72
73ALTERNATIVE_PRIORITY = "100"
74ALTERNATIVE_LINK_NAME[psplash] = "${bindir}/psplash"
75
76python do_compile () {
77    import shutil
78    import subprocess
79
80    # Build a separate executable for each splash image
81    workdir = d.getVar('WORKDIR')
82    convertscript = "%s/make-image-header.sh" % d.getVar('S')
83    destfile = "%s/psplash-poky-img.h" % d.getVar('B')
84    localfiles = d.getVar('SPLASH_LOCALPATHS').split()
85    outputfiles = d.getVar('SPLASH_INSTALL').split()
86    for localfile, outputfile in zip(localfiles, outputfiles):
87        if localfile.endswith(".png"):
88            if subprocess.call([ convertscript, os.path.join(workdir, localfile), 'POKY' ], cwd=workdir):
89                bb.fatal("Error calling convert script '%s'" % (convertscript))
90            fbase = os.path.splitext(localfile)[0]
91            shutil.copyfile(os.path.join(workdir, "%s-img.h" % fbase), destfile)
92        else:
93            shutil.copyfile(os.path.join(workdir, localfile), destfile)
94        # For some reason just updating the header is not enough, we have to touch the .c
95        # file in order to get it to rebuild
96        os.utime("%s/psplash.c" % d.getVar('S'), None)
97        bb.build.exec_func("oe_runmake", d)
98        shutil.copyfile("psplash", outputfile)
99}
100
101do_install:append() {
102	if ${@bb.utils.contains('DISTRO_FEATURES', 'sysvinit', 'true', 'false', d)}; then
103		install -d ${D}${sysconfdir}/init.d/
104		install -m 0755 ${WORKDIR}/psplash-init ${D}${sysconfdir}/init.d/psplash.sh
105
106		# make fifo for psplash
107		install -d ${D}/mnt
108		mkfifo ${D}/mnt/psplash_fifo
109	fi
110
111	if ${@bb.utils.contains('DISTRO_FEATURES', 'systemd', 'true', 'false', d)}; then
112		install -d ${D}${systemd_unitdir}/system
113		install -m 644 ${WORKDIR}/psplash-start.service ${D}/${systemd_unitdir}/system
114		install -m 644 ${WORKDIR}/psplash-systemd.service ${D}/${systemd_unitdir}/system
115	fi
116
117	install -d ${D}${bindir}
118	for i in ${SPLASH_INSTALL} ; do
119		install -m 0755 $i ${D}${bindir}/$i
120	done
121	rm -f ${D}${bindir}/psplash
122}
123
124SYSTEMD_PACKAGES = "${@bb.utils.contains('DISTRO_FEATURES','systemd','${PN}','',d)}"
125SYSTEMD_SERVICE:${PN} += "${@bb.utils.contains('PACKAGECONFIG', 'systemd', 'psplash-start.service psplash-systemd.service', '', d)}"
126
127INITSCRIPT_NAME = "psplash.sh"
128INITSCRIPT_PARAMS = "start 0 S . stop 20 0 1 6 ."
129
130FILES:${PN} += "/mnt"
131