1SUMMARY = "Newlib is a C library intended for use on embedded systems"
2HOMEPAGE = "https://sourceware.org/newlib/"
3DESCRIPTION = "C library intended for use on embedded systems. It is a conglomeration of several library parts, all under free software licenses that make them easily usable on embedded products."
4SECTION = "libs"
5
6LICENSE = "GPL-2.0-only & LGPL-3.0-only & GPL-3.0-only & LGPL-2.0-only & BSD-2-Clause & BSD-3-Clause & TCL"
7LIC_FILES_CHKSUM = " \
8		file://COPYING;md5=59530bdf33659b29e73d4adb9f9f6552 \
9		file://COPYING3.LIB;md5=6a6a8e020838b23406c81b19c1d46df6 \
10		file://COPYING3;md5=d32239bcb673463ab874e80d47fae504 \
11		file://COPYING.LIBGLOSS;md5=c0469b6ebb847a75781066be515f032d \
12		file://COPYING.LIB;md5=2d5025d4aa3495befef8f17206a5b0a1 \
13		file://COPYING.NEWLIB;md5=5a9d477b5f4eab20dccf655a77107a6e \
14		file://newlib/libc/posix/COPYRIGHT;md5=103468ff1982be840fdf4ee9f8b51bbf \
15		"
16
17BASEVER = "4.3.0"
18PV = "${BASEVER}+git"
19SRC_URI = "git://sourceware.org/git/newlib-cygwin.git;protocol=https;branch=main"
20SRCREV="9e09d6ed83cce4777a5950412647ccc603040409"
21
22INHIBIT_DEFAULT_DEPS = "1"
23DEPENDS = "virtual/${TARGET_PREFIX}gcc"
24
25S = "${WORKDIR}/git"
26B = "${WORKDIR}/build"
27
28## disable stdlib
29TARGET_CC_ARCH:append = " -nostdlib"
30
31EXTRA_OECONF = " \
32                --build=${BUILD_SYS}  \
33                --target=${TARGET_SYS} \
34		--host=${HOST_SYS} \
35                --prefix=${prefix}  \
36                --exec-prefix=${exec_prefix} \
37                --bindir=${bindir} \
38                --libdir=${libdir} \
39                --includedir=${includedir} \
40		--enable-languages=c \
41		--with-newlib \
42		--with-gnu-as \
43		--with-gnu-ld \
44		--disable-multilib \
45		--disable-newlib-supplied-syscalls \
46		"
47
48do_configure[cleandirs] = "${B}"
49
50# We need a dummy limits.h to pass preprocessor checks
51do_configure:append(){
52    install -d ${STAGING_INCDIR}
53    touch  ${STAGING_INCDIR}/limits.h
54}
55
56do_install() {
57	oe_runmake install DESTDIR='${D}'
58}
59
60COMPATIBLE_HOST:libc-musl:class-target = "null"
61COMPATIBLE_HOST:libc-glibc:class-target = "null"
62