1# Copyright (C) 2014 Khem Raj <raj.khem@gmail.com>
2# Released under the MIT license (see COPYING.MIT for the terms)
3
4require musl.inc
5inherit linuxloader
6
7SRCREV = "79bdacff83a6bd5b70ff5ae5eb8b6de82c2f7c30"
8
9BASEVER = "1.2.4"
10
11PV = "${BASEVER}+git"
12
13SRC_URI = "git://git.etalabs.net/git/musl;branch=master;protocol=https \
14           file://0001-Make-dynamic-linker-a-relative-symlink-to-libc.patch \
15           file://0002-ldso-Use-syslibdir-and-libdir-as-default-pathes-to-l.patch \
16           file://0003-elf.h-add-typedefs-for-Elf64_Relr-and-Elf32_Relr.patch \
17          "
18
19S = "${WORKDIR}/git"
20
21PROVIDES += "virtual/libc virtual/libiconv virtual/libintl virtual/crypt"
22
23DEPENDS = "virtual/${TARGET_PREFIX}binutils \
24           virtual/${TARGET_PREFIX}gcc \
25           libgcc-initial \
26           linux-libc-headers \
27           bsd-headers \
28           libssp-nonshared \
29          "
30GLIBC_LDSO = "${@get_glibc_loader(d)}"
31MUSL_LDSO_ARCH = "${@get_musl_loader_arch(d)}"
32
33export CROSS_COMPILE="${TARGET_PREFIX}"
34
35LDFLAGS += "-Wl,-soname,libc.so"
36
37# When compiling for Thumb or Thumb2, frame pointers _must_ be disabled since the
38# Thumb frame pointer in r7 clashes with musl's use of inline asm to make syscalls
39# (where r7 is used for the syscall NR). In most cases, frame pointers will be
40# disabled automatically due to the optimisation level, but append an explicit
41# -fomit-frame-pointer to handle cases where optimisation is set to -O0 or frame
42# pointers have been enabled by -fno-omit-frame-pointer earlier in CFLAGS, etc.
43CFLAGS:append:arm = " ${@bb.utils.contains('TUNE_CCARGS', '-mthumb', '-fomit-frame-pointer', '', d)}"
44
45CONFIGUREOPTS = " \
46    --prefix=${prefix} \
47    --exec-prefix=${exec_prefix} \
48    --bindir=${bindir} \
49    --libdir=${libdir} \
50    --includedir=${includedir} \
51    --syslibdir=${nonarch_base_libdir} \
52"
53
54do_configure() {
55	${S}/configure ${CONFIGUREOPTS}
56}
57
58do_compile() {
59	oe_runmake
60}
61
62do_install() {
63	oe_runmake install DESTDIR='${D}'
64	install -d ${D}${bindir} ${D}${sysconfdir}
65        echo "${base_libdir}" > ${D}${sysconfdir}/ld-musl-${MUSL_LDSO_ARCH}.path
66        echo "${libdir}" >> ${D}${sysconfdir}/ld-musl-${MUSL_LDSO_ARCH}.path
67	rm -f ${D}${bindir}/ldd ${D}${GLIBC_LDSO}
68	ln -rs ${D}${libdir}/libc.so ${D}${bindir}/ldd
69}
70
71FILES:${PN} += "${nonarch_base_libdir}/ld-musl-${MUSL_LDSO_ARCH}.so.1 ${sysconfdir}/ld-musl-${MUSL_LDSO_ARCH}.path"
72FILES:${PN}-staticdev = "${libdir}/libc.a"
73FILES:${PN}-dev =+ "${libdir}/libcrypt.a ${libdir}/libdl.a ${libdir}/libm.a \
74                    ${libdir}/libpthread.a ${libdir}/libresolv.a \
75                    ${libdir}/librt.a ${libdir}/libutil.a ${libdir}/libxnet.a \
76                   "
77
78RDEPENDS:${PN}-dev += "linux-libc-headers-dev bsd-headers-dev libssp-nonshared-staticdev"
79RPROVIDES:${PN}-dev += "libc-dev virtual-libc-dev"
80RPROVIDES:${PN} += "ldd rtld(GNU_HASH)"
81
82LEAD_SONAME = "libc.so"
83INSANE_SKIP:${PN}-dev = "staticdev"
84INSANE_SKIP:${PN} = "libdir"
85
86UPSTREAM_CHECK_COMMITS = "1"
87