1# Copyright (C) 2014 Khem Raj <raj.khem@gmail.com>
2# Released under the MIT license (see COPYING.MIT for the terms)
3
4require musl.inc
5inherit linuxloader
6
7SRCREV = "43e7efb46555f13a556d92944ac05c19b8929b60"
8
9BASEVER = "1.1.21"
10
11PV = "${BASEVER}+git${SRCPV}"
12
13# mirror is at git://github.com/kraj/musl.git
14
15SRC_URI = "git://git.musl-libc.org/musl \
16           file://0001-Make-dynamic-linker-a-relative-symlink-to-libc.patch \
17           file://0002-ldso-Use-syslibdir-and-libdir-as-default-pathes-to-l.patch \
18          "
19
20S = "${WORKDIR}/git"
21
22PROVIDES += "virtual/libc virtual/libiconv virtual/libintl virtual/crypt"
23
24DEPENDS = "virtual/${TARGET_PREFIX}binutils \
25           virtual/${TARGET_PREFIX}gcc \
26           libgcc-initial \
27           linux-libc-headers \
28           bsd-headers \
29           libssp-nonshared \
30          "
31GLIBC_LDSO = "${@get_glibc_loader(d)}"
32
33export CROSS_COMPILE="${TARGET_PREFIX}"
34
35LDFLAGS += "-Wl,-soname,libc.so"
36
37# When compiling for Thumb or Thumb2, frame pointers _must_ be disabled since the
38# Thumb frame pointer in r7 clashes with musl's use of inline asm to make syscalls
39# (where r7 is used for the syscall NR). In most cases, frame pointers will be
40# disabled automatically due to the optimisation level, but append an explicit
41# -fomit-frame-pointer to handle cases where optimisation is set to -O0 or frame
42# pointers have been enabled by -fno-omit-frame-pointer earlier in CFLAGS, etc.
43CFLAGS_append_arm = " ${@bb.utils.contains('TUNE_CCARGS', '-mthumb', '-fomit-frame-pointer', '', d)}"
44
45CONFIGUREOPTS = " \
46    --prefix=${prefix} \
47    --exec-prefix=${exec_prefix} \
48    --bindir=${bindir} \
49    --libdir=${libdir} \
50    --includedir=${includedir} \
51    --syslibdir=${base_libdir} \
52"
53
54do_configure() {
55	${S}/configure ${CONFIGUREOPTS}
56}
57
58do_compile() {
59	oe_runmake
60}
61
62do_install() {
63	oe_runmake install DESTDIR='${D}'
64
65	install -d ${D}${bindir}
66	rm -f ${D}${bindir}/ldd
67	lnr ${D}${libdir}/libc.so ${D}${bindir}/ldd
68	lnr ${D}${libdir}/libc.so ${D}${GLIBC_LDSO}
69	for l in crypt dl m pthread resolv rt util xnet
70	do
71		ln -sf libc.so ${D}${libdir}/lib$l.so
72	done
73	for i in libc.so.6 libcrypt.so.1 libdl.so.2 libm.so.6 libpthread.so.0 libresolv.so.2 librt.so.1 libutil.so.1; do
74		ln -sf libc.so ${D}${libdir}/$i
75	done
76}
77
78PACKAGES =+ "${PN}-glibc-compat"
79
80FILES_${PN}-glibc-compat += "\
81                ${libdir}/libc.so.6 ${libdir}/libcrypt.so.1 \
82                ${libdir}/libdl.so.2 ${libdir}/libm.so.6 \
83                ${libdir}/libpthread.so.0 ${libdir}/libresolv.so.2 \
84                ${libdir}/librt.so.1 ${libdir}/libutil.so.1 \
85                ${GLIBC_LDSO} \
86                "
87
88RDEPENDS_${PN}-dev += "linux-libc-headers-dev bsd-headers-dev libssp-nonshared-staticdev"
89RPROVIDES_${PN}-dev += "libc-dev virtual-libc-dev"
90RPROVIDES_${PN} += "ldd libsegfault rtld(GNU_HASH)"
91
92LEAD_SONAME = "libc.so"
93