1# Copyright (C) 2014 Khem Raj <raj.khem@gmail.com>
2# Released under the MIT license (see COPYING.MIT for the terms)
3
4require musl.inc
5inherit linuxloader
6
7SRCREV = "aad50fcd791e009961621ddfbe3d4c245fd689a3"
8
9BASEVER = "1.2.2"
10
11PV = "${BASEVER}+git${SRCPV}"
12
13# mirror is at git://github.com/kraj/musl.git
14
15SRC_URI = "git://git.musl-libc.org/musl \
16           file://0001-Make-dynamic-linker-a-relative-symlink-to-libc.patch \
17           file://0002-ldso-Use-syslibdir-and-libdir-as-default-pathes-to-l.patch \
18           file://0001-riscv-Rename-__NR_fstatat-__NR_newfstatat.patch \
19          "
20
21S = "${WORKDIR}/git"
22
23PROVIDES += "virtual/libc virtual/libiconv virtual/libintl virtual/crypt"
24
25DEPENDS = "virtual/${TARGET_PREFIX}binutils \
26           virtual/${TARGET_PREFIX}gcc \
27           libgcc-initial \
28           linux-libc-headers \
29           bsd-headers \
30           libssp-nonshared \
31          "
32GLIBC_LDSO = "${@get_glibc_loader(d)}"
33MUSL_LDSO_ARCH = "${@get_musl_loader_arch(d)}"
34
35export CROSS_COMPILE="${TARGET_PREFIX}"
36
37LDFLAGS += "-Wl,-soname,libc.so"
38
39# When compiling for Thumb or Thumb2, frame pointers _must_ be disabled since the
40# Thumb frame pointer in r7 clashes with musl's use of inline asm to make syscalls
41# (where r7 is used for the syscall NR). In most cases, frame pointers will be
42# disabled automatically due to the optimisation level, but append an explicit
43# -fomit-frame-pointer to handle cases where optimisation is set to -O0 or frame
44# pointers have been enabled by -fno-omit-frame-pointer earlier in CFLAGS, etc.
45CFLAGS:append:arm = " ${@bb.utils.contains('TUNE_CCARGS', '-mthumb', '-fomit-frame-pointer', '', d)}"
46
47CONFIGUREOPTS = " \
48    --prefix=${prefix} \
49    --exec-prefix=${exec_prefix} \
50    --bindir=${bindir} \
51    --libdir=${libdir} \
52    --includedir=${includedir} \
53    --syslibdir=/lib \
54"
55
56do_configure() {
57	${S}/configure ${CONFIGUREOPTS}
58}
59
60do_compile() {
61	oe_runmake
62}
63
64do_install() {
65	oe_runmake install DESTDIR='${D}'
66	install -d ${D}${bindir} ${D}/lib ${D}${sysconfdir}
67        echo "${base_libdir}" > ${D}${sysconfdir}/ld-musl-${MUSL_LDSO_ARCH}.path
68        echo "${libdir}" >> ${D}${sysconfdir}/ld-musl-${MUSL_LDSO_ARCH}.path
69	rm -f ${D}${bindir}/ldd ${D}${GLIBC_LDSO}
70	lnr ${D}${libdir}/libc.so ${D}${bindir}/ldd
71}
72
73FILES:${PN} += "/lib/ld-musl-${MUSL_LDSO_ARCH}.so.1 ${sysconfdir}/ld-musl-${MUSL_LDSO_ARCH}.path"
74FILES:${PN}-staticdev = "${libdir}/libc.a"
75FILES:${PN}-dev =+ "${libdir}/libcrypt.a ${libdir}/libdl.a ${libdir}/libm.a \
76                    ${libdir}/libpthread.a ${libdir}/libresolv.a \
77                    ${libdir}/librt.a ${libdir}/libutil.a ${libdir}/libxnet.a \
78                   "
79
80RDEPENDS:${PN}-dev += "linux-libc-headers-dev bsd-headers-dev libssp-nonshared-staticdev"
81RPROVIDES:${PN}-dev += "libc-dev virtual-libc-dev"
82RPROVIDES:${PN} += "ldd libsegfault rtld(GNU_HASH)"
83
84LEAD_SONAME = "libc.so"
85INSANE_SKIP:${PN}-dev = "staticdev"
86INSANE_SKIP:${PN} = "libdir"
87
88UPSTREAM_CHECK_COMMITS = "1"
89