1SUMMARY = "An image containing the build system itself"
2DESCRIPTION = "An image containing the build system that you can boot and run using either VirtualBox, VMware Player or VMware Workstation."
3HOMEPAGE = "http://www.yoctoproject.org/documentation/build-appliance"
4
5LICENSE = "MIT"
6LIC_FILES_CHKSUM = "file://${COREBASE}/meta/COPYING.MIT;md5=3da9cfbcb788c80a0384361b4de20420"
7
8IMAGE_INSTALL = "packagegroup-core-boot packagegroup-core-ssh-openssh packagegroup-self-hosted \
9                 kernel-dev kernel-devsrc connman connman-plugin-ethernet dhcp-client \
10                 tzdata python3-pip perl-misc"
11
12IMAGE_FEATURES += "x11-base package-management splash"
13
14# Ensure there's enough space to do a core-image-sato build, with rm_work enabled
15IMAGE_ROOTFS_EXTRA_SPACE = "41943040"
16
17# Do a quiet boot with limited console messages
18APPEND += "rootfstype=ext4 quiet"
19
20DEPENDS = "zip-native python3-pip-native"
21IMAGE_FSTYPES = "wic.vmdk"
22
23inherit core-image module-base setuptools3
24
25SRCREV ?= "14d62d5c14e3552f2aeabdbd80d1504bb2c6ed64"
26SRC_URI = "git://git.yoctoproject.org/poky;branch=sumo \
27           file://Yocto_Build_Appliance.vmx \
28           file://Yocto_Build_Appliance.vmxf \
29           file://README_VirtualBox_Guest_Additions.txt \
30           file://README_VirtualBox_Toaster.txt \
31          "
32BA_INCLUDE_SOURCES ??= "0"
33
34IMAGE_CMD_ext4_append () {
35	# We don't need to reserve much space for root, 0.5% is more than enough
36	tune2fs -m 0.5 ${IMGDEPLOYDIR}/${IMAGE_NAME}.rootfs.ext4
37}
38
39fakeroot do_populate_poky_src () {
40	# Because fetch2's git's unpack uses -s cloneflag, the unpacked git repo
41	# will become invalid in the target.
42	rm -rf ${WORKDIR}/git/.git
43	rm -f ${WORKDIR}/git/.gitignore
44
45	cp -R ${WORKDIR}/git ${IMAGE_ROOTFS}/home/builder/poky
46
47	mkdir -p ${IMAGE_ROOTFS}/home/builder/poky/build/conf
48	mkdir -p ${IMAGE_ROOTFS}/home/builder/poky/build/downloads
49	if [ ${BA_INCLUDE_SOURCES} != 0 ]; then
50		cp -RpL ${DL_DIR}/* ${IMAGE_ROOTFS}/home/builder/poky/build/downloads/
51		# Remove the git2_* tarballs -- this is ok since we still have the git2/.
52		rm -rf ${IMAGE_ROOTFS}/home/builder/poky/build/downloads/git2_*
53	fi
54
55	# Place the README_VirtualBox_Guest_Additions file in builders home folder.
56	cp ${WORKDIR}/README_VirtualBox_Guest_Additions.txt ${IMAGE_ROOTFS}/home/builder/
57
58	# Place the README_VirtualBox_Toaster file in builders home folder.
59	cp ${WORKDIR}/README_VirtualBox_Toaster.txt ${IMAGE_ROOTFS}/home/builder/
60
61	# Create a symlink, needed for out-of-tree kernel modules build
62	rm -f  ${IMAGE_ROOTFS}/lib/modules/${KERNEL_VERSION}/build
63	lnr ${IMAGE_ROOTFS}${KERNEL_SRC_PATH} ${IMAGE_ROOTFS}/lib/modules/${KERNEL_VERSION}/build
64
65	echo "INHERIT += \"rm_work\"" >> ${IMAGE_ROOTFS}/home/builder/poky/build/conf/auto.conf
66	echo "export LC_ALL=en_US.utf8" >> ${IMAGE_ROOTFS}/home/builder/.bashrc
67
68	# Also save (for reference only) the actual SRCREV used to create this image
69	echo "export BA_SRCREV=${SRCREV}" >> ${IMAGE_ROOTFS}/home/builder/.bashrc
70	echo "" >> ${IMAGE_ROOTFS}/home/builder/.bashrc
71	echo 'export PATH=$PATH:/sbin' >> ${IMAGE_ROOTFS}/home/builder/.bashrc
72	echo "" >> ${IMAGE_ROOTFS}/home/builder/.bashrc
73
74	echo "# If working behind a proxy and using the provided oe-git-proxy script" >> ${IMAGE_ROOTFS}/home/builder/.bashrc
75	echo "# you need to set ALL_PROXY based on your proxy settings." >> ${IMAGE_ROOTFS}/home/builder/.bashrc
76	echo "# Example ALL_PROXY values:" >> ${IMAGE_ROOTFS}/home/builder/.bashrc
77	echo "# export ALL_PROXY=https://proxy.example.com:8080" >> ${IMAGE_ROOTFS}/home/builder/.bashrc
78	echo "# export ALL_PROXY=socks://socks.example.com:1080" >> ${IMAGE_ROOTFS}/home/builder/.bashrc
79
80	chown -R builder.builder ${IMAGE_ROOTFS}/home/builder/poky
81	chmod -R ug+rw ${IMAGE_ROOTFS}/home/builder/poky
82
83	# Assume we will need CDROM to install guest additions
84	mkdir -p ${IMAGE_ROOTFS}/media/cdrom
85
86	# Allow builder to use sudo
87	echo "builder ALL=(ALL) NOPASSWD: ALL" >> ${IMAGE_ROOTFS}/etc/sudoers
88
89	# Load tap/tun at startup
90	rm -f ${IMAGE_ROOTFS}/sbin/iptables
91	lnr ${IMAGE_ROOTFS}/usr/sbin/iptables ${IMAGE_ROOTFS}/sbin/iptables
92	echo "tun" >> ${IMAGE_ROOTFS}/etc/modules
93
94	# Use Clearlooks GTK+ theme
95	mkdir -p ${IMAGE_ROOTFS}/etc/gtk-2.0
96	echo 'gtk-theme-name = "Clearlooks"' > ${IMAGE_ROOTFS}/etc/gtk-2.0/gtkrc
97
98	# Install modules needed for toaster
99	export STAGING_LIBDIR=${STAGING_LIBDIR_NATIVE}
100	export STAGING_INCDIR=${STAGING_INCDIR_NATIVE}
101	export HOME=${IMAGE_ROOTFS}/home/builder
102	mkdir -p ${IMAGE_ROOTFS}/home/builder/.cache/pip
103	pip3_install_params="--user -I -U -v -r ${IMAGE_ROOTFS}/home/builder/poky/bitbake/toaster-requirements.txt"
104	if [ -n "${http_proxy}" ]; then
105	   pip3_install_params="${pip3_install_params} --proxy ${http_proxy}"
106	fi
107	pip3 install ${pip3_install_params}
108	chown -R builder.builder ${IMAGE_ROOTFS}/home/builder/.local
109	chown -R builder.builder ${IMAGE_ROOTFS}/home/builder/.cache
110}
111
112IMAGE_PREPROCESS_COMMAND += "do_populate_poky_src; "
113
114addtask rootfs after do_unpack
115
116python () {
117	# Ensure we run these usually noexec tasks
118	d.delVarFlag("do_fetch", "noexec")
119	d.delVarFlag("do_unpack", "noexec")
120}
121
122create_bundle_files () {
123	cd ${WORKDIR}
124	mkdir -p Yocto_Build_Appliance
125	cp *.vmx* Yocto_Build_Appliance
126	ln -sf ${IMGDEPLOYDIR}/${IMAGE_NAME}${IMAGE_NAME_SUFFIX}.wic.vmdk Yocto_Build_Appliance/Yocto_Build_Appliance.vmdk
127	zip -r ${IMGDEPLOYDIR}/Yocto_Build_Appliance-${DATETIME}.zip Yocto_Build_Appliance
128	ln -sf Yocto_Build_Appliance-${DATETIME}.zip ${IMGDEPLOYDIR}/Yocto_Build_Appliance.zip
129}
130create_bundle_files[vardepsexclude] = "DATETIME"
131
132python do_bundle_files() {
133    bb.build.exec_func('create_bundle_files', d)
134}
135
136addtask bundle_files after do_image_wic before do_image_complete
137