1INHIBIT_SYSROOT_STRIP = "1"
2
3PACKAGES = "${PN}-dbg sln nscd ldconfig ldd ldso tzcode glibc-thread-db ${PN}-pic libmemusage malloc-debug libnss-db ${PN}-pcprofile libsotruss ${PN} ${PN}-utils glibc-extra-nss ${PN}-dev ${PN}-staticdev ${PN}-doc ${PN}-src"
4
5# The ld.so in this glibc supports the GNU_HASH
6RPROVIDES:${PN} = "eglibc rtld(GNU_HASH)"
7RPROVIDES:${PN}-utils = "eglibc-utils"
8RPROVIDES:${PN}-mtrace = "eglibc-mtrace libc-mtrace"
9RPROVIDES:${PN}-pic = "eglibc-pic"
10RPROVIDES:${PN}-dev = "eglibc-dev libc6-dev virtual-libc-dev"
11RPROVIDES:${PN}-staticdev = "eglibc-staticdev"
12RPROVIDES:${PN}-doc = "eglibc-doc"
13RPROVIDES:glibc-extra-nss = "eglibc-extra-nss"
14RPROVIDES:glibc-thread-db = "eglibc-thread-db"
15RPROVIDES:${PN}-pcprofile = "eglibc-pcprofile"
16RPROVIDES:${PN}-dbg = "eglibc-dbg"
17libc_baselibs = "${base_libdir}/libc.so.* ${base_libdir}/libc-*.so ${base_libdir}/libm*.so.* ${base_libdir}/libm-*.so ${base_libdir}/libmvec-*.so ${base_libdir}/ld*.so.* ${base_libdir}/ld-*.so ${base_libdir}/libpthread*.so.* ${base_libdir}/libpthread-*.so ${base_libdir}/libresolv*.so.* ${base_libdir}/libresolv-*.so ${base_libdir}/librt*.so.* ${base_libdir}/librt-*.so ${base_libdir}/libutil*.so.* ${base_libdir}/libutil-*.so ${base_libdir}/libnsl*.so.* ${base_libdir}/libnsl-*.so ${base_libdir}/libnss_files*.so.* ${base_libdir}/libnss_files-*.so ${base_libdir}/libnss_compat*.so.* ${base_libdir}/libnss_compat-*.so ${base_libdir}/libnss_dns*.so.* ${base_libdir}/libnss_dns-*.so ${base_libdir}/libdl*.so.* ${base_libdir}/libdl-*.so ${base_libdir}/libanl*.so.* ${base_libdir}/libanl-*.so ${base_libdir}/libBrokenLocale*.so.* ${base_libdir}/libBrokenLocale-*.so"
18ARCH_DYNAMIC_LOADER = ""
19# The aarch64 ABI says the dynamic linker -must- be
20# /lib/ld-linux-aarch64{,_be}.so.1. With usrmerge, that may mean that
21# we need to install it in /usr/lib.
22ARCH_DYNAMIC_LOADER:aarch64 = "ld-linux-${TARGET_ARCH}.so.1"
23libc_baselibs:append = " ${@oe.utils.conditional('ARCH_DYNAMIC_LOADER', '', '', '${root_prefix}/lib/${ARCH_DYNAMIC_LOADER}', d)}"
24INSANE_SKIP:${PN}:append:aarch64 = " libdir"
25INSANE_SKIP:${PN}-dev += "staticdev"
26INSANE_SKIP:${MLPREFIX}ldso:append = " dev-so libdir"
27
28FILES:${PN} = "${libc_baselibs} ${libexecdir}/* ${sysconfdir}/ld.so.conf"
29RRECOMMENDS:${PN} = "${@bb.utils.contains('DISTRO_FEATURES', 'ldconfig', '${MLPREFIX}ldconfig', '', d)}"
30FILES:ldconfig = "${base_sbindir}/ldconfig"
31FILES:ldd = "${bindir}/ldd"
32FILES:ldso = "${bindir}/${MLPREFIX}ld.so"
33FILES:libmemusage = "${base_libdir}/libmemusage.so"
34FILES:malloc-debug = "${base_libdir}/libc_malloc_debug.so.0"
35FILES:libnss-db = "${base_libdir}/libnss_db.so.* ${base_libdir}/libnss_db-*.so ${localstatedir}/db/Makefile ${localstatedir}/db/makedbs.sh"
36RDEPENDS:libnss-db = "${PN}-utils"
37FILES:glibc-extra-nss = "${base_libdir}/libnss_*-*.so ${base_libdir}/libnss_*.so.*"
38FILES:sln = "${base_sbindir}/sln"
39FILES:${PN}-pic = "${libdir}/*_pic.a ${libdir}/*_pic.map ${libdir}/libc_pic/*.o"
40FILES:libsotruss = "${libdir}/audit/sotruss-lib.so"
41FILES_SOLIBSDEV = "${libdir}/lib*${SOLIBSDEV}"
42FILES:${PN}-dev += "${libdir}/libpthread.a ${libdir}/libdl.a ${libdir}/libutil.a ${libdir}/libanl.a ${libdir}/*_nonshared.a ${base_libdir}/*_nonshared.a ${base_libdir}/*.o ${datadir}/aclocal"
43DEV_PKG_DEPENDENCY = "linux-libc-headers-dev"
44FILES:${PN}-staticdev += "${libdir}/*.a ${base_libdir}/*.a"
45FILES:nscd = "${sbindir}/nscd* ${sysconfdir}/init.d/nscd ${systemd_system_unitdir}/nscd* ${sysconfdir}/tmpfiles.d/nscd.conf \
46              ${sysconfdir}/nscd.conf ${sysconfdir}/default/volatiles/98_nscd ${localstatedir}/db/nscd"
47FILES:${PN}-mtrace = "${bindir}/mtrace"
48FILES:tzcode = "${bindir}/tzselect ${sbindir}/zic ${bindir}/zdump"
49FILES:${PN}-utils = "${bindir}/* ${sbindir}/*"
50FILES:${PN}-pcprofile = "${base_libdir}/libpcprofile.so"
51FILES:glibc-thread-db = "${base_libdir}/libthread_db.so.* ${base_libdir}/libthread_db-*.so"
52RPROVIDES:${PN}-dev += "libc-dev"
53RPROVIDES:${PN}-staticdev += "libc-staticdev"
54
55SUMMARY:sln = "The static ln"
56DESCRIPTION:sln = "Similar to the 'ln' utility, but statically linked.  sln is useful to make symbolic links to dynamic libraries if the dynamic linking system, for some reason, is not functional."
57SUMMARY:nscd = "Name service cache daemon"
58DESCRIPTION:nscd = "nscd, name service cache daemon, caches name service lookups for the passwd, group and hosts information.  It can damatically improvide performance with remote, such as NIS or NIS+, name services."
59SUMMARY:glibc-extra-nss = "hesiod, NIS and NIS+ nss libraries"
60DESCRIPTION:glibc-extra-nss = "glibc: nis, nisplus and hesiod search services."
61SUMMARY:ldd = "print shared library dependencies"
62DESCRIPTION:ldd = "${bindir}/ldd prints shared library dependencies for each program or shared library specified on the command line."
63SUMMARY:${PN}-utils = "Miscellaneous utilities provided by glibc"
64DESCRIPTION:${PN}-utils = "Miscellaneous utilities including getconf, iconv, locale, gencat, ..."
65DESCRIPTION:libsotruss = "Library to support sotruss which traces calls through PLTs"
66DESCRIPTION:tzcode = "tzcode, timezone zoneinfo utils -- zic, zdump, tzselect"
67
68inherit multilib_header
69
70do_install() {
71	oe_runmake install_root=${D} install
72	install -Dm 0644 ${WORKDIR}/etc/ld.so.conf ${D}/${sysconfdir}/ld.so.conf
73	install -d ${D}${localedir}
74	make -f ${WORKDIR}/generate-supported.mk IN="${S}/localedata/SUPPORTED" OUT="${WORKDIR}/SUPPORTED"
75	# get rid of some broken files...
76	for i in ${GLIBC_BROKEN_LOCALES}; do
77		sed -i "/$i/d" ${WORKDIR}/SUPPORTED
78	done
79	rm -f ${D}${sysconfdir}/rpc
80	rm -rf ${D}${datadir}/zoneinfo
81	rm -rf ${D}${libexecdir}/getconf
82
83	rm -f ${D}${sysconfdir}/localtime
84
85	# remove empty glibc dir
86	if [ -d ${D}${libexecdir} ]; then
87		rmdir --ignore-fail-on-non-empty ${D}${libexecdir}
88	fi
89
90	oe_multilib_header bits/syscall.h bits/long-double.h bits/floatn.h bits/endianness.h bits/struct_rwlock.h
91
92	if [ -f ${D}${bindir}/mtrace ]; then
93		sed -i -e '1s,#!.*perl,#! ${USRBINPATH}/env perl,' -e '2s,exec.*perl,exec ${USRBINPATH}/env perl,' ${D}${bindir}/mtrace
94	fi
95	# Info dir listing isn't interesting at this point so remove it if it exists.
96	if [ -e "${D}${infodir}/dir" ]; then
97		rm -f ${D}${infodir}/dir
98	fi
99
100	install -d ${D}${sysconfdir}/init.d
101	install -d ${D}${localstatedir}/db/nscd
102	install -m 0755 ${S}/nscd/nscd.init ${D}${sysconfdir}/init.d/nscd
103	install -m 0755 ${S}/nscd/nscd.conf ${D}${sysconfdir}/nscd.conf
104	install -m 0755 ${WORKDIR}/makedbs.sh ${D}${localstatedir}/db
105	sed -i "s%daemon%start-stop-daemon --start --exec%g" ${D}${sysconfdir}/init.d/nscd
106	sed -i "s|\(enable-cache\t\+netgroup\t\+\)yes|\1no|" ${D}${sysconfdir}/nscd.conf
107
108	install -d ${D}${systemd_system_unitdir}
109	install -m 0644 ${S}/nscd/nscd.service ${D}${systemd_system_unitdir}/
110
111	# The dynamic loader will have been installed into
112	# ${base_libdir}. However, if that isn't going to end up being
113	# available in the ABI-mandated location, then a symlink must
114	# be created.
115
116	if [ -n "${ARCH_DYNAMIC_LOADER}" -a ! -e "${D}${root_prefix}/lib/${ARCH_DYNAMIC_LOADER}" ]; then
117		install -d ${D}${root_prefix}/lib
118		ln -s ${@oe.path.relative('${root_prefix}/lib', '${base_libdir}')}/${ARCH_DYNAMIC_LOADER} \
119				${D}${root_prefix}/lib/${ARCH_DYNAMIC_LOADER}
120	fi
121        ln -rs ${D}${base_libdir}/libpthread.so.0 ${D}${libdir}/libpthread.so
122        ln -rs ${D}${base_libdir}/librt.so.1 ${D}${libdir}/librt.so
123        if [ -n "${MLPREFIX}" ]; then
124                mv ${D}${bindir}/ld.so ${D}${bindir}/${MLPREFIX}ld.so
125        fi
126}
127
128def get_libc_fpu_setting(bb, d):
129    if d.getVar('TARGET_FPU') in [ 'soft', 'ppc-efd' ]:
130        return "--without-fp"
131    return ""
132
133do_install:append:class-target() {
134	if ${@bb.utils.contains('DISTRO_FEATURES', 'systemd', 'true', 'false', d)}; then
135		install -d ${D}${sysconfdir}/tmpfiles.d
136		echo "d /run/nscd 755 root root -" \
137			> ${D}${sysconfdir}/tmpfiles.d/nscd.conf
138	fi
139
140	if ${@bb.utils.contains('DISTRO_FEATURES', 'sysvinit', 'true', 'false', d)}; then
141		install -d ${D}${sysconfdir}/default/volatiles
142		echo "d root root 0755 /var/run/nscd none" \
143			> ${D}${sysconfdir}/default/volatiles/98_nscd
144	fi
145
146}
147do_install:append:aarch64 () {
148	do_install_armmultilib
149}
150
151do_install:append:arm () {
152	do_install_armmultilib
153}
154
155do_install:append:armeb () {
156	do_install_armmultilib
157}
158
159do_install_armmultilib () {
160	oe_multilib_header bits/endian.h bits/fcntl.h bits/fenv.h bits/fp-fast.h bits/hwcap.h bits/ipc.h bits/link.h
161	oe_multilib_header bits/local_lim.h bits/mman.h bits/msq.h bits/pthreadtypes.h bits/pthreadtypes-arch.h  bits/sem.h  bits/semaphore.h bits/setjmp.h
162	oe_multilib_header bits/shm.h bits/sigstack.h bits/stat.h bits/statfs.h bits/typesizes.h
163	oe_multilib_header bits/procfs-id.h bits/procfs.h bits/shmlba.h
164	oe_multilib_header bits/struct_stat.h bits/pthread_stack_min.h
165	oe_multilib_header bits/dl_find_object.h bits/rseq.h bits/timesize.h
166
167	oe_multilib_header fpu_control.h gnu/lib-names.h gnu/stubs.h ieee754.h
168
169	oe_multilib_header sys/elf.h sys/procfs.h sys/ptrace.h sys/ucontext.h sys/user.h
170}
171
172
173LOCALESTASH = "${WORKDIR}/stashed-locale"
174bashscripts = "mtrace sotruss xtrace"
175
176do_stash_locale () {
177	dest=${LOCALESTASH}
178	install -d $dest${base_libdir} $dest${bindir} $dest${libdir} $dest${datadir}
179	# Hide away the locale data from the deployment
180	if [ -e ${D}${bindir}/localedef ]; then
181		cp -a ${D}${bindir}/localedef $dest${bindir}
182	fi
183	if [ -e ${D}${libdir}/gconv ]; then
184		cp -a ${D}${libdir}/gconv $dest${libdir}
185	fi
186	if [ -e ${D}${datadir}/i18n ]; then
187		cp -a  ${D}${datadir}/i18n $dest${datadir}
188	fi
189
190	# Make a copy of all the libraries into the locale stash
191	cp -fpPR ${D}${libdir}/* $dest${libdir}
192	if [ "${base_libdir}" != "${libdir}" ]; then
193		cp -fpPR ${D}${base_libdir}/* $dest${base_libdir}
194	fi
195	if [ -e ${D}${exec_prefix}/lib ]; then
196		if [ ${exec_prefix}/lib != ${base_libdir} ] && [ ${exec_prefix}/lib != ${libdir} ]; then
197			cp -fpPR ${D}${exec_prefix}/lib $dest${exec_prefix}
198		fi
199	fi
200
201	cp -fpPR ${D}${datadir}/* $dest${datadir}
202	cp -fpPR ${WORKDIR}/SUPPORTED $dest
203
204	target=$dest/scripts
205	mkdir -p $target
206	for i in ${bashscripts}; do
207		if [ -f ${D}${bindir}/$i ]; then
208			cp ${D}${bindir}/$i $target/
209		fi
210	done
211}
212
213addtask do_stash_locale after do_install before do_populate_sysroot do_package
214do_stash_locale[dirs] = "${B}"
215do_stash_locale[cleandirs] = "${LOCALESTASH}"
216SSTATETASKS += "do_stash_locale"
217do_stash_locale[sstate-inputdirs] = "${LOCALESTASH}"
218do_stash_locale[sstate-outputdirs] = "${COMPONENTS_DIR}/${PACKAGE_ARCH}/glibc-stash-locale"
219do_stash_locale[sstate-fixmedir] = "${COMPONENTS_DIR}/${PACKAGE_ARCH}/glibc-stash-locale"
220
221python do_stash_locale_setscene () {
222    sstate_setscene(d)
223}
224addtask do_stash_locale_setscene
225
226PACKAGE_PREPROCESS_FUNCS += "stash_locale_package_cleanup"
227SYSROOT_PREPROCESS_FUNCS += "stash_locale_sysroot_cleanup"
228stash_locale_cleanup () {
229	cleanupdir=$1
230	# Remove all files which do_stash_locale() copies
231	for i in ${bashscripts}; do
232		rm -f $cleanupdir${bindir}/$i
233	done
234	rm -f $cleanupdir${bindir}/localedef
235	rm -rf $cleanupdir${datadir}/i18n
236	rm -rf $cleanupdir${libdir}/gconv
237	rm -rf $cleanupdir${localedir}
238	rm -rf $cleanupdir${datadir}/locale
239	rmdir --ignore-fail-on-non-empty $cleanupdir${datadir}
240
241	if [ "${libdir}" != "${exec_prefix}/lib" ] && [ "${root_prefix}/lib" != "${exec_prefix}/lib" ]; then
242		if [ -d "$cleanupdir${exec_prefix}/lib" ]; then
243			if [ -z "${ARCH_DYNAMIC_LOADER}" -o \
244			     ! -e "$cleanupdir${exec_prefix}/lib/${ARCH_DYNAMIC_LOADER}" ]; then
245				# error out if directory isn't empty
246				# this dir should only contain locale dir
247				# which has been deleted in the previous step
248				rmdir $cleanupdir${exec_prefix}/lib
249			fi
250		fi
251	fi
252}
253
254stash_locale_sysroot_cleanup() {
255	stash_locale_cleanup ${SYSROOT_DESTDIR}
256}
257stash_locale_package_cleanup() {
258	stash_locale_cleanup ${PKGD}
259}
260
261python populate_packages:prepend () {
262    if d.getVar('DEBIAN_NAMES'):
263        pkgs = d.getVar('PACKAGES').split()
264        bpn = d.getVar('BPN')
265        prefix = d.getVar('MLPREFIX') or ""
266        # Set the base package...
267        d.setVar('PKG:' + prefix + bpn, prefix + 'libc6')
268        libcprefix = prefix + bpn + '-'
269        for p in pkgs:
270            # And all the subpackages.
271            if p.startswith(libcprefix):
272                renamed = p.replace(bpn, 'libc6', 1)
273                d.setVar('PKG:' + p, renamed)
274        # For backward compatibility with old -dbg package
275        d.appendVar('RPROVIDES:' + libcprefix + 'dbg', ' ' + prefix + 'libc-dbg')
276        d.appendVar('RCONFLICTS:' + libcprefix + 'dbg', ' ' + prefix + 'libc-dbg')
277        d.appendVar('RREPLACES:' + libcprefix + 'dbg', ' ' + prefix + 'libc-dbg')
278}
279
280pkg_postinst:nscd () {
281	if [ -z "$D" ]; then
282		if command -v systemd-tmpfiles >/dev/null; then
283			systemd-tmpfiles --create ${sysconfdir}/tmpfiles.d/nscd.conf
284		elif [ -e ${sysconfdir}/init.d/populate-volatile.sh ]; then
285			${sysconfdir}/init.d/populate-volatile.sh update
286		fi
287	fi
288}
289CONFFILES:nscd="${sysconfdir}/nscd.conf"
290
291SYSTEMD_PACKAGES = "nscd"
292SYSTEMD_SERVICE:nscd = "nscd.service"
293