xref: /openbmc/openbmc/poky/meta/conf/bitbake.conf (revision 90fd73cb) 
1##################################################################
2# Standard target filesystem paths.
3##################################################################
4#
5# If changing these values, beware that native/cross/nativesdk bbclass
6# files may also need changes to keep in sync.
7#
8
9# Used by multilib code to change the library paths
10baselib = "${BASELIB}"
11baselib[vardepvalue] = "${baselib}"
12BASELIB = "lib"
13BASELIB_libc-glibc_powerpc64 = "lib64"
14BASELIB_libc-glibc_powerpc64le = "lib64"
15
16# Path prefixes
17export base_prefix = ""
18export prefix = "/usr"
19export exec_prefix = "${prefix}"
20
21root_prefix = "${@bb.utils.contains('DISTRO_FEATURES', 'usrmerge', '${exec_prefix}', '${base_prefix}', d)}"
22
23# Base paths
24export base_bindir = "${root_prefix}/bin"
25export base_sbindir = "${root_prefix}/sbin"
26export base_libdir = "${root_prefix}/${baselib}"
27export nonarch_base_libdir = "${root_prefix}/lib"
28
29# Architecture independent paths
30export sysconfdir = "${base_prefix}/etc"
31export servicedir = "${base_prefix}/srv"
32export sharedstatedir = "${base_prefix}/com"
33export localstatedir = "${base_prefix}/var"
34export datadir = "${prefix}/share"
35export infodir = "${datadir}/info"
36export mandir = "${datadir}/man"
37export docdir = "${datadir}/doc"
38export systemd_unitdir = "${nonarch_base_libdir}/systemd"
39export systemd_system_unitdir = "${nonarch_base_libdir}/systemd/system"
40export nonarch_libdir = "${exec_prefix}/lib"
41export systemd_user_unitdir = "${nonarch_libdir}/systemd/user"
42
43# Architecture dependent paths
44export bindir = "${exec_prefix}/bin"
45export sbindir = "${exec_prefix}/sbin"
46export libdir = "${exec_prefix}/${baselib}"
47export libexecdir = "${exec_prefix}/libexec"
48export includedir = "${exec_prefix}/include"
49export oldincludedir = "${exec_prefix}/include"
50localedir = "${libdir}/locale"
51
52# Linkage between native/cross/nativesdk layouts
53base_bindir_native = "/bin"
54base_sbindir_native = "/sbin"
55sysconfdir_native = "/etc"
56prefix_native = "/usr"
57bindir_native = "${prefix_native}/bin"
58sbindir_native = "${prefix_native}/sbin"
59includedir_native = "${prefix_native}/include"
60libdir_native = "${prefix_native}/lib"
61libexecdir_native = "${prefix_native}/libexec"
62base_libdir_native = "/lib"
63datadir_native = "${prefix_native}/share"
64bindir_cross = "/bin"
65bindir_crossscripts = "${bindir}/crossscripts"
66prefix_nativesdk = "/usr"
67bindir_nativesdk = "${prefix_nativesdk}/bin"
68sbindir_nativesdk = "${prefix_nativesdk}/sbin"
69base_bindir_nativesdk = "/bin"
70base_sbindir_nativesdk = "/sbin"
71includedir_nativesdk = "${prefix_nativesdk}/include"
72libdir_nativesdk = "${prefix_nativesdk}/lib"
73base_libdir_nativesdk = "/lib"
74localstatedir_nativesdk = "/var"
75
76#
77# Cross recipes need to know about the target layout
78# := is used carefully here
79#
80target_datadir := "${datadir}"
81# Used to find env/perl/python
82USRBINPATH = "${bindir}"
83USRBINPATH_class-native = "/usr/bin"
84USRBINPATH_class-nativesdk = "/usr/bin"
85
86# Root home directory
87ROOT_HOME ??= "/home/root"
88
89# If set to boolean true ('yes', 'y', 'true', 't', '1'), /var/log links to /var/volatile/log.
90# If set to boolean false ('no', 'n', 'false', 'f', '0'), /var/log is on persistent storage.
91VOLATILE_LOG_DIR ?= "yes"
92
93##################################################################
94# Architecture-dependent build variables.
95##################################################################
96
97# Immediate expansion since there is no point in repeatedly calling
98# os.uname() throughout parsing
99BUILD_ARCH := "${@os.uname()[4]}"
100BUILD_OS := "${@os.uname()[0].lower()}"
101BUILD_VENDOR = ""
102BUILD_SYS = "${BUILD_ARCH}${BUILD_VENDOR}-${BUILD_OS}"
103BUILD_PREFIX = ""
104BUILD_CC_ARCH = ""
105BUILD_LD_ARCH = ""
106BUILD_AS_ARCH = ""
107BUILD_EXEEXT = ""
108
109HOST_ARCH = "${TARGET_ARCH}"
110HOST_OS = "${TARGET_OS}"
111HOST_VENDOR = "${TARGET_VENDOR}"
112HOST_SYS = "${HOST_ARCH}${HOST_VENDOR}-${HOST_OS}"
113HOST_PREFIX = "${TARGET_PREFIX}"
114HOST_CC_ARCH = "${TARGET_CC_ARCH}"
115HOST_LD_ARCH = "${TARGET_LD_ARCH}"
116HOST_AS_ARCH = "${TARGET_AS_ARCH}"
117HOST_EXEEXT = ""
118
119TUNE_ARCH ??= "INVALID"
120TUNE_CCARGS ??= ""
121TUNE_CCARGS[vardepvalue] = "${TUNE_CCARGS}"
122TUNE_LDARGS ??= ""
123TUNE_ASARGS ??= ""
124TUNE_FEATURES ??= "${TUNE_FEATURES_tune-${DEFAULTTUNE}}"
125LIBCEXTENSION ??= ""
126ABIEXTENSION ??= ""
127USE_NLS ??= "yes"
128SDKUSE_NLS ??= "yes"
129
130TARGET_ARCH = "${TUNE_ARCH}"
131TARGET_OS = "linux${LIBCEXTENSION}${ABIEXTENSION}"
132TARGET_VENDOR = "-oe"
133TARGET_SYS = "${TARGET_ARCH}${TARGET_VENDOR}-${TARGET_OS}"
134TARGET_PREFIX = "${TARGET_SYS}-"
135TARGET_CC_ARCH = "${TUNE_CCARGS}"
136TARGET_LD_ARCH = "${TUNE_LDARGS}"
137TARGET_AS_ARCH = "${TUNE_ASARGS}"
138
139SDKMACHINE ??= "${BUILD_ARCH}"
140SDK_OS = "${BUILD_OS}"
141SDK_VENDOR = "-oesdk"
142SDK_SYS = "${SDK_ARCH}${SDK_VENDOR}-${SDK_OS}"
143SDK_PREFIX = "${SDK_SYS}-"
144SDK_CC_ARCH = "${BUILD_CC_ARCH}"
145SDKPKGSUFFIX = "nativesdk"
146SDK_PACKAGE_ARCHS = "all any noarch ${SDK_ARCH}-${SDKPKGSUFFIX}"
147SDK_LD_ARCH = "${BUILD_LD_ARCH}"
148SDK_AS_ARCH = "${BUILD_AS_ARCH}"
149
150TUNE_PKGARCH ??= ""
151PACKAGE_ARCH ??= "${TUNE_PKGARCH}"
152MACHINE_ARCH = "${@[d.getVar('TUNE_PKGARCH'), d.getVar('MACHINE')][bool(d.getVar('MACHINE'))].replace('-', '_')}"
153PACKAGE_EXTRA_ARCHS ??= "${PACKAGE_EXTRA_ARCHS_tune-${DEFAULTTUNE}}"
154PACKAGE_ARCHS = "all any noarch ${PACKAGE_EXTRA_ARCHS} ${MACHINE_ARCH}"
155# MACHINE_ARCH shouldn't be included here as a variable dependency
156# since machine specific packages are handled using multimachine
157PACKAGE_ARCHS[vardepsexclude] = "MACHINE_ARCH"
158
159MULTIMACH_TARGET_SYS = "${PACKAGE_ARCH}${TARGET_VENDOR}-${TARGET_OS}"
160
161##################################################################
162# Date/time variables.
163##################################################################
164
165DATE := "${@time.strftime('%Y%m%d',time.gmtime())}"
166TIME := "${@time.strftime('%H%M%S',time.gmtime())}"
167DATETIME = "${DATE}${TIME}"
168
169##################################################################
170# Openembedded Software Prerequisites.
171##################################################################
172
173# python-native should be here but python relies on building
174# its own in staging
175ASSUME_PROVIDED = "\
176    bzip2-native \
177    chrpath-native \
178    file-native \
179    findutils-native \
180    gawk-native \
181    git-native \
182    grep-native \
183    diffstat-native \
184    patch-native \
185    libgcc-native \
186    hostperl-runtime-native \
187    hostpython-runtime-native \
188    tar-native \
189    virtual/libintl-native \
190    virtual/libiconv-native \
191    virtual/crypt-native \
192    texinfo-native \
193    bash-native \
194    sed-native \
195    wget-native \
196    "
197# gzip-native should be listed above?
198
199##################################################################
200# Package default variables.
201##################################################################
202
203PN = "${@bb.parse.vars_from_file(d.getVar('FILE', False),d)[0] or 'defaultpkgname'}"
204PV = "${@bb.parse.vars_from_file(d.getVar('FILE', False),d)[1] or '1.0'}"
205PR = "${@bb.parse.vars_from_file(d.getVar('FILE', False),d)[2] or 'r0'}"
206PE = ""
207PF = "${PN}-${EXTENDPE}${PV}-${PR}"
208EXTENDPE = "${@['','${PE}_'][int(d.getVar('PE') or 0) > 0]}"
209P = "${PN}-${PV}"
210
211PRSERV_PV_AUTOINC = "AUTOINC"
212PRAUTO = ""
213EXTENDPRAUTO = "${@['.${PRAUTO}', ''][not d.getVar('PRAUTO')]}"
214PRAUTOINX = "${PF}"
215
216PKGV ?= "${PV}"
217PKGR ?= "${PR}${EXTENDPRAUTO}"
218PKGE ?= "${@['','${PE}'][int(d.getVar('PE') or 0) > 0]}"
219EXTENDPKGEVER = "${@['','${PKGE}:'][d.getVar('PKGE').strip() != '']}"
220EXTENDPKGV ?= "${EXTENDPKGEVER}${PKGV}-${PKGR}"
221
222# Base package name
223# Automatically derives "foo" from "foo-native", "foo-cross" or "foo-initial"
224# otherwise it is the same as PN and P
225SPECIAL_PKGSUFFIX = "-native -cross -initial -intermediate -crosssdk -cross-canadian"
226BPN = "${@oe.utils.prune_suffix(d.getVar('PN'), d.getVar('SPECIAL_PKGSUFFIX').split(), d)}"
227BP = "${BPN}-${PV}"
228
229# Package info.
230
231SECTION = "base"
232PRIORITY = "optional"
233SUMMARY ?= "${PN} version ${PV}-${PR}"
234DESCRIPTION ?= "${SUMMARY}."
235
236# The following two are commented out because they result in a recursive
237# definition of the variable in some corner cases.  These are left in
238# to illustrate the intended behavior.
239#SUMMARY_${PN} ?= "${SUMMARY}"
240#DESCRIPTION_${PN} ?= "${DESCRIPTION}"
241
242SUMMARY_${PN}-src ?= "${SUMMARY} - Source files"
243DESCRIPTION_${PN}-src ?= "${DESCRIPTION}  \
244This package contains sources for debugging purposes."
245
246SUMMARY_${PN}-dbg ?= "${SUMMARY} - Debugging files"
247DESCRIPTION_${PN}-dbg ?= "${DESCRIPTION}  \
248This package contains ELF symbols and related sources for debugging purposes."
249
250SUMMARY_${PN}-dev ?= "${SUMMARY} - Development files"
251DESCRIPTION_${PN}-dev ?= "${DESCRIPTION}  \
252This package contains symbolic links, header files, and \
253related items necessary for software development."
254
255SUMMARY_${PN}-staticdev ?= "${SUMMARY} - Development files (Static Libraries)"
256DESCRIPTION_${PN}-staticdev ?= "${DESCRIPTION}  \
257This package contains static libraries for software development."
258
259SUMMARY_${PN}-doc ?= "${SUMMARY} - Documentation files"
260DESCRIPTION_${PN}-doc ?= "${DESCRIPTION}  \
261This package contains documentation."
262
263LICENSE ??= "INVALID"
264MAINTAINER = "OE-Core Developers <openembedded-core@lists.openembedded.org>"
265HOMEPAGE = ""
266
267# Package dependencies and provides.
268
269# Ensure that -dev packages recommend the corresponding -dev packages of their
270# deps, and the same for -dbg.
271DEPCHAIN_PRE = ""
272DEPCHAIN_POST = "-dev -dbg"
273
274DEPENDS = ""
275PROVIDES = ""
276PROVIDES_prepend = "${PN} "
277
278MULTI_PROVIDER_WHITELIST = "virtual/libintl virtual/libintl-native virtual/nativesdk-libintl virtual/xserver virtual/update-alternatives-native virtual/update-alternatives"
279
280SOLIBS = ".so.*"
281SOLIBS_darwin = ".dylib"
282
283SOLIBSDEV = ".so"
284# Due to the ordering of PACKAGES and the naming of the dev symlinks on darwin,
285# we can't make the symlinks end up in the -dev packages easily at this point. This hack
286# at least means builds aren't completely broken and symlinks don't take up much space.
287SOLIBSDEV_darwin = ".dylibbroken"
288
289PACKAGE_DEBUG_SPLIT_STYLE ?= "debug-with-srcpkg"
290
291PACKAGE_BEFORE_PN ?= ""
292PACKAGES = "${PN}-src ${PN}-dbg ${PN}-staticdev ${PN}-dev ${PN}-doc ${PN}-locale ${PACKAGE_BEFORE_PN} ${PN}"
293PACKAGES_DYNAMIC = "^${PN}-locale-.*"
294FILES = ""
295
296FILES_${PN} = "${bindir}/* ${sbindir}/* ${libexecdir}/* ${libdir}/lib*${SOLIBS} \
297            ${sysconfdir} ${sharedstatedir} ${localstatedir} \
298            ${base_bindir}/* ${base_sbindir}/* \
299            ${base_libdir}/*${SOLIBS} \
300            ${base_prefix}/lib/udev ${prefix}/lib/udev \
301            ${base_libdir}/udev ${libdir}/udev \
302            ${datadir}/${BPN} ${libdir}/${BPN}/* \
303            ${datadir}/pixmaps ${datadir}/applications \
304            ${datadir}/idl ${datadir}/omf ${datadir}/sounds \
305            ${libdir}/bonobo/servers"
306
307FILES_${PN}-bin = "${bindir}/* ${sbindir}/*"
308
309FILES_${PN}-doc = "${docdir} ${mandir} ${infodir} ${datadir}/gtk-doc \
310            ${datadir}/gnome/help"
311SECTION_${PN}-doc = "doc"
312
313FILES_SOLIBSDEV ?= "${base_libdir}/lib*${SOLIBSDEV} ${libdir}/lib*${SOLIBSDEV}"
314FILES_${PN}-dev = "${includedir} ${FILES_SOLIBSDEV} ${libdir}/*.la \
315                ${libdir}/*.o ${libdir}/pkgconfig ${datadir}/pkgconfig \
316                ${datadir}/aclocal ${base_libdir}/*.o \
317                ${libdir}/${BPN}/*.la ${base_libdir}/*.la \
318                ${libdir}/cmake ${datadir}/cmake"
319SECTION_${PN}-dev = "devel"
320ALLOW_EMPTY_${PN}-dev = "1"
321RDEPENDS_${PN}-dev = "${PN} (= ${EXTENDPKGV})"
322
323FILES_${PN}-staticdev = "${libdir}/*.a ${base_libdir}/*.a ${libdir}/${BPN}/*.a"
324SECTION_${PN}-staticdev = "devel"
325RDEPENDS_${PN}-staticdev = "${PN}-dev (= ${EXTENDPKGV})"
326
327FILES_${PN}-dbg = "/usr/lib/debug /usr/lib/debug-static /usr/src/debug"
328SECTION_${PN}-dbg = "devel"
329ALLOW_EMPTY_${PN}-dbg = "1"
330
331# The files list for source packages are dynamically set based on
332# PACKAGE_DEBUG_SPLIT_STYLE
333FILES_${PN}-src = ""
334SECTION_${PN}-src = "devel"
335
336FILES_${PN}-locale = "${datadir}/locale"
337
338# File manifest
339
340FILE_DIRNAME = "${@os.path.dirname(d.getVar('FILE', False))}"
341# FILESPATH is set in base.bbclass
342#FILESPATH = "${FILE_DIRNAME}/${PF}:${FILE_DIRNAME}/${P}:${FILE_DIRNAME}/${PN}:${FILE_DIRNAME}/${BP}:${FILE_DIRNAME}/${BPN}:${FILE_DIRNAME}/files:${FILE_DIRNAME}"
343# This default was only used for checking
344FILESEXTRAPATHS ?= "__default:"
345
346# The default list of fs-perms files to process.  If the list is empty only
347# the builtin definitions will be used.  Builtin definitions included:
348#  base_prefix, prefix, exec_prefix, base_bindir, base_sbindir, base_libdir,
349#  datadir, sysconfdir, servicedir, sharedstatedir, localstatedir, infodir,
350#  mandir, docdir, bindir, sbindir, libexecdir, libdir, includedir and
351#  oldincludedir
352FILESYSTEM_PERMS_TABLES ?= "${@'files/fs-perms.txt' if oe.types.boolean(d.getVar('VOLATILE_LOG_DIR')) else 'files/fs-perms-persistent-log.txt'}"
353
354##################################################################
355# General work and output directories for the build system.
356##################################################################
357
358TCMODE ?= "default"
359TCLIBC ?= "glibc"
360TMPDIR ?= "${TOPDIR}/tmp"
361
362CACHE = "${TMPDIR}/cache/${TCMODE}-${TCLIBC}${@['', '/' + str(d.getVar('MACHINE'))][bool(d.getVar('MACHINE'))]}${@['', '/' + str(d.getVar('SDKMACHINE'))][bool(d.getVar('SDKMACHINE'))]}"
363# The persistent cache should be shared by all builds
364PERSISTENT_DIR = "${TOPDIR}/cache"
365LOG_DIR = "${TMPDIR}/log"
366
367STAMPS_DIR ?= "${TMPDIR}/stamps"
368STAMP = "${STAMPS_DIR}/${MULTIMACH_TARGET_SYS}/${PN}/${EXTENDPE}${PV}-${PR}"
369STAMPCLEAN = "${STAMPS_DIR}/${MULTIMACH_TARGET_SYS}/${PN}/*-*"
370BASE_WORKDIR ?= "${TMPDIR}/work"
371WORKDIR = "${BASE_WORKDIR}/${MULTIMACH_TARGET_SYS}/${PN}/${EXTENDPE}${PV}-${PR}"
372T = "${WORKDIR}/temp"
373D = "${WORKDIR}/image"
374S = "${WORKDIR}/${BP}"
375B = "${S}"
376
377STAGING_DIR = "${TMPDIR}/sysroots"
378COMPONENTS_DIR = "${STAGING_DIR}-components"
379RECIPE_SYSROOT = "${WORKDIR}/recipe-sysroot"
380RECIPE_SYSROOT_NATIVE = "${WORKDIR}/recipe-sysroot-native"
381
382STAGING_DIR_NATIVE = "${RECIPE_SYSROOT_NATIVE}"
383STAGING_BINDIR_NATIVE = "${STAGING_DIR_NATIVE}${bindir_native}"
384STAGING_BINDIR_CROSS = "${STAGING_BINDIR}/crossscripts"
385STAGING_BINDIR_TOOLCHAIN = "${STAGING_DIR_NATIVE}${bindir_native}/${TARGET_ARCH}${TARGET_VENDOR}-${TARGET_OS}"
386STAGING_LIBDIR_NATIVE = "${STAGING_DIR_NATIVE}${libdir_native}"
387STAGING_LIBEXECDIR_NATIVE = "${STAGING_DIR_NATIVE}${libexecdir_native}"
388STAGING_BASE_LIBDIR_NATIVE = "${STAGING_DIR_NATIVE}${base_libdir_native}"
389STAGING_SBINDIR_NATIVE = "${STAGING_DIR_NATIVE}${sbindir_native}"
390STAGING_INCDIR_NATIVE = "${STAGING_DIR_NATIVE}${includedir_native}"
391STAGING_ETCDIR_NATIVE = "${STAGING_DIR_NATIVE}${sysconfdir_native}"
392STAGING_DATADIR_NATIVE = "${STAGING_DIR_NATIVE}${datadir_native}"
393
394STAGING_DIR_HOST = "${RECIPE_SYSROOT}"
395STAGING_BINDIR = "${STAGING_DIR_HOST}${bindir}"
396STAGING_LIBDIR = "${STAGING_DIR_HOST}${libdir}"
397STAGING_LIBEXECDIR = "${STAGING_DIR_HOST}${libexecdir}"
398STAGING_BASELIBDIR = "${STAGING_DIR_HOST}${base_libdir}"
399STAGING_INCDIR = "${STAGING_DIR_HOST}${includedir}"
400STAGING_DATADIR = "${STAGING_DIR_HOST}${datadir}"
401STAGING_EXECPREFIXDIR = "${STAGING_DIR_HOST}${exec_prefix}"
402STAGING_LOADER_DIR = "${STAGING_DIR_HOST}/loader"
403STAGING_FIRMWARE_DIR = "${STAGING_DIR_HOST}/firmware"
404
405STAGING_DIR_TARGET = "${RECIPE_SYSROOT}"
406
407# Setting DEPLOY_DIR outside of TMPDIR is helpful, when you are using
408# packaged staging and/or multimachine.
409DEPLOY_DIR ?= "${TMPDIR}/deploy"
410DEPLOY_DIR_TAR = "${DEPLOY_DIR}/tar"
411DEPLOY_DIR_IPK = "${DEPLOY_DIR}/ipk"
412DEPLOY_DIR_RPM = "${DEPLOY_DIR}/rpm"
413DEPLOY_DIR_DEB = "${DEPLOY_DIR}/deb"
414DEPLOY_DIR_IMAGE ?= "${DEPLOY_DIR}/images/${MACHINE}"
415DEPLOY_DIR_TOOLS = "${DEPLOY_DIR}/tools"
416
417PKGDATA_DIR = "${TMPDIR}/pkgdata/${MACHINE}"
418
419##################################################################
420# SDK variables.
421##################################################################
422
423SDK_NAME_PREFIX ?= "oecore"
424SDK_NAME = "${SDK_NAME_PREFIX}-${SDK_ARCH}-${TUNE_PKGARCH}"
425SDKPATH = "/usr/local/${SDK_NAME_PREFIX}-${SDK_ARCH}"
426SDKPATHNATIVE = "${SDKPATH}/sysroots/${SDK_SYS}"
427
428##################################################################
429# Kernel info.
430##################################################################
431
432OLDEST_KERNEL = "3.2.0"
433OLDEST_KERNEL_aarch64 = "3.14"
434OLDEST_KERNEL_nios2 = "3.19"
435OLDEST_KERNEL_powerpc64le = "3.10.0"
436OLDEST_KERNEL_riscv32 = "5.4"
437OLDEST_KERNEL_riscv64 = "4.15"
438
439# SDK_OLDEST_KERNEL can't be set using overrides since there are
440# none for the SDK architecture. Best to set it from a machine-sdk
441# include file if you need an SDK arch-specific value
442SDK_OLDEST_KERNEL = "3.2.0"
443
444# Define where the kernel headers are installed on the target as well as where
445# they are staged.
446KERNEL_SRC_PATH = "/usr/src/kernel"
447
448STAGING_KERNEL_DIR = "${TMPDIR}/work-shared/${MACHINE}/kernel-source"
449STAGING_KERNEL_BUILDDIR = "${TMPDIR}/work-shared/${MACHINE}/kernel-build-artifacts"
450
451##################################################################
452# Specific image creation and rootfs population info.
453##################################################################
454
455IMAGE_ROOTFS = "${WORKDIR}/rootfs"
456
457# This option allows for a percentage overage of the actual image size rather than a
458# fixed extra space, this is space needed for initial startup and basic operations.
459IMAGE_OVERHEAD_FACTOR ?= "1.3"
460# This option allows for adding additional space in K above and beyond what the
461# IMAGE_OVERHEAD_FACTOR might add. This space is for additional packages, user data, ...
462# To set a fixed size then overriding IMAGE_ROOTFS_SIZE with the max size one wants
463# should do the trick
464IMAGE_ROOTFS_EXTRA_SPACE ?= "0"
465
466EXTRA_IMAGEDEPENDS = ""
467
468##################################################################
469# Toolchain info.
470##################################################################
471
472PATH_prepend = "${COREBASE}/scripts:${STAGING_BINDIR_TOOLCHAIN}:${STAGING_BINDIR_CROSS}:${STAGING_DIR_NATIVE}${sbindir_native}:${STAGING_BINDIR_NATIVE}:${STAGING_DIR_NATIVE}${base_sbindir_native}:${STAGING_DIR_NATIVE}${base_bindir_native}:"
473export PATH
474
475##################################################################
476# Build utility info.
477##################################################################
478
479# Directory where host tools are copied
480HOSTTOOLS_DIR = "${TMPDIR}/hosttools"
481
482# Tools needed to run builds with OE-Core
483HOSTTOOLS += " \
484    [ ar as awk basename bash bzip2 cat chgrp chmod chown chrpath cmp comm cp cpio \
485    cpp cut date dd diff diffstat dirname du echo egrep env expand expr false \
486    fgrep file find flock g++ gawk gcc getconf getopt git grep gunzip gzip \
487    head hostname iconv id install ld ldd ln ls make md5sum mkdir mkfifo mknod \
488    mktemp mv nm objcopy objdump od patch perl pr printf pwd \
489    python3 ranlib readelf readlink realpath rm rmdir rpcgen sed seq sh \
490    sha1sum sha224sum sha256sum sha384sum sha512sum \
491    sleep sort split stat strings strip tail tar tee test touch tr true uname \
492    uniq wc wget which xargs \
493"
494
495# Tools needed to run testimage runtime image testing
496HOSTTOOLS += "${@'ip ping ps scp ssh stty' if (bb.utils.contains_any('IMAGE_CLASSES', 'testimage testsdk', True, False, d) or any(x in (d.getVar("BBINCLUDED") or "") for x in ["testimage.bbclass", "testsdk.bbclass"])) else ''}"
497
498# Link to these if present
499HOSTTOOLS_NONFATAL += "aws gcc-ar gpg ld.bfd ld.gold nc pigz sftp socat ssh sudo"
500
501# Temporary add few more detected in bitbake world
502HOSTTOOLS_NONFATAL += "join nl size yes zcat"
503
504# Used by bzr fetcher
505HOSTTOOLS_NONFATAL += "bzr"
506
507# Used by ssh fetcher
508HOSTTOOLS_NONFATAL += "scp"
509
510# Link to git-lfs if present
511HOSTTOOLS_NONFATAL += "git-lfs"
512
513CCACHE ??= ""
514
515TOOLCHAIN_OPTIONS = " --sysroot=${STAGING_DIR_TARGET}"
516
517export CC = "${CCACHE}${HOST_PREFIX}gcc ${HOST_CC_ARCH}${TOOLCHAIN_OPTIONS}"
518export CXX = "${CCACHE}${HOST_PREFIX}g++ ${HOST_CC_ARCH}${TOOLCHAIN_OPTIONS}"
519export FC = "${CCACHE}${HOST_PREFIX}gfortran ${HOST_CC_ARCH}${TOOLCHAIN_OPTIONS}"
520export CPP = "${HOST_PREFIX}gcc -E${TOOLCHAIN_OPTIONS} ${HOST_CC_ARCH}"
521export LD = "${HOST_PREFIX}ld${TOOLCHAIN_OPTIONS} ${HOST_LD_ARCH}"
522export CCLD = "${CC}"
523export AR = "${HOST_PREFIX}gcc-ar"
524export AS = "${HOST_PREFIX}as ${HOST_AS_ARCH}"
525export RANLIB = "${HOST_PREFIX}gcc-ranlib"
526export STRIP = "${HOST_PREFIX}strip"
527export OBJCOPY = "${HOST_PREFIX}objcopy"
528export OBJDUMP = "${HOST_PREFIX}objdump"
529export STRINGS = "${HOST_PREFIX}strings"
530export NM = "${HOST_PREFIX}nm"
531export READELF = "${HOST_PREFIX}readelf"
532PYTHON = "${@sys.executable}"
533
534export BUILD_CC = "${CCACHE}${BUILD_PREFIX}gcc ${BUILD_CC_ARCH}"
535export BUILD_CXX = "${CCACHE}${BUILD_PREFIX}g++ ${BUILD_CC_ARCH}"
536export BUILD_FC = "${CCACHE}${BUILD_PREFIX}gfortran ${BUILD_CC_ARCH}"
537export BUILD_CPP = "${BUILD_PREFIX}gcc ${BUILD_CC_ARCH} -E"
538export BUILD_LD = "${BUILD_PREFIX}ld ${BUILD_LD_ARCH}"
539export BUILD_CCLD = "${BUILD_PREFIX}gcc ${BUILD_CC_ARCH}"
540export BUILD_AR = "${BUILD_PREFIX}ar"
541export BUILD_AS = "${BUILD_PREFIX}as ${BUILD_AS_ARCH}"
542export BUILD_RANLIB = "${BUILD_PREFIX}ranlib"
543export BUILD_STRIP = "${BUILD_PREFIX}strip"
544export BUILD_NM = "${BUILD_PREFIX}nm"
545
546export MAKE = "make"
547EXTRA_OEMAKE = ""
548EXTRA_OECONF = ""
549export LC_ALL = "en_US.UTF-8"
550export TZ = 'UTC'
551
552##################################################################
553# Patch handling.
554##################################################################
555PATCHTOOL = "quilt"
556PATCHRESOLVE = "noop"
557
558##################################################################
559# Build flags and options.
560##################################################################
561
562export BUILD_CPPFLAGS = "-isystem${STAGING_INCDIR_NATIVE}"
563BUILDSDK_CPPFLAGS = ""
564export CPPFLAGS = "${TARGET_CPPFLAGS}"
565TARGET_CPPFLAGS = ""
566
567export BUILD_CFLAGS = "${BUILD_CPPFLAGS} ${BUILD_OPTIMIZATION}"
568BUILDSDK_CFLAGS = "${BUILDSDK_CPPFLAGS} ${BUILD_OPTIMIZATION} ${DEBUG_PREFIX_MAP}"
569export CFLAGS = "${TARGET_CFLAGS}"
570TARGET_CFLAGS = "${TARGET_CPPFLAGS} ${SELECTED_OPTIMIZATION}"
571
572export BUILD_CXXFLAGS = "${BUILD_CFLAGS}"
573BUILDSDK_CXXFLAGS = "${BUILDSDK_CFLAGS}"
574export CXXFLAGS = "${TARGET_CXXFLAGS}"
575TARGET_CXXFLAGS = "${TARGET_CFLAGS}"
576
577export BUILD_LDFLAGS = "-L${STAGING_LIBDIR_NATIVE} \
578                        -L${STAGING_BASE_LIBDIR_NATIVE} \
579                        -Wl,--enable-new-dtags \
580                        -Wl,-rpath-link,${STAGING_LIBDIR_NATIVE} \
581                        -Wl,-rpath-link,${STAGING_BASE_LIBDIR_NATIVE} \
582                        -Wl,-rpath,${STAGING_LIBDIR_NATIVE} \
583                        -Wl,-rpath,${STAGING_BASE_LIBDIR_NATIVE} \
584                        -Wl,-O1"
585
586BUILDSDK_LDFLAGS = "-Wl,-O1"
587
588LINKER_HASH_STYLE ??= "gnu"
589
590TARGET_LINK_HASH_STYLE ?= "${@['-Wl,--hash-style=gnu',''][d.getVar('LINKER_HASH_STYLE') != 'gnu']}"
591
592ASNEEDED ?= "-Wl,--as-needed"
593
594export LDFLAGS = "${TARGET_LDFLAGS}"
595TARGET_LDFLAGS = "-Wl,-O1 ${TARGET_LINK_HASH_STYLE} ${ASNEEDED}"
596# mips does not support GNU hash style therefore we override
597LINKER_HASH_STYLE_mipsarch_libc-musl = "sysv"
598
599# Pass parallel make options to the compile task
600EXTRA_OEMAKE_prepend_task-compile = "${PARALLEL_MAKE} "
601PARALLEL_MAKEINST ??= "${PARALLEL_MAKE}"
602# Pass parallel make options to the install task
603EXTRA_OEMAKE_prepend_task-install = "${PARALLEL_MAKEINST} "
604
605##################################################################
606# Optimization flags.
607##################################################################
608# Beware: applied last to first
609DEBUG_PREFIX_MAP ?= "-fmacro-prefix-map=${WORKDIR}=/usr/src/debug/${PN}/${EXTENDPE}${PV}-${PR} \
610                     -fdebug-prefix-map=${WORKDIR}=/usr/src/debug/${PN}/${EXTENDPE}${PV}-${PR} \
611                     -fdebug-prefix-map=${STAGING_DIR_HOST}= \
612                     -fdebug-prefix-map=${STAGING_DIR_NATIVE}= \
613"
614DEBUG_FLAGS ?= "-g -feliminate-unused-debug-types ${DEBUG_PREFIX_MAP}"
615
616# Disabled until the option works properly -feliminate-dwarf2-dups
617FULL_OPTIMIZATION = "-O2 -pipe ${DEBUG_FLAGS}"
618DEBUG_OPTIMIZATION = "-Og ${DEBUG_FLAGS} -pipe"
619SELECTED_OPTIMIZATION = "${@d.getVar(oe.utils.vartrue('DEBUG_BUILD', 'DEBUG_OPTIMIZATION', 'FULL_OPTIMIZATION', d))}"
620SELECTED_OPTIMIZATION[vardeps] += "FULL_OPTIMIZATION DEBUG_OPTIMIZATION DEBUG_BUILD"
621BUILD_OPTIMIZATION = "${@oe.utils.vartrue('DEBUG_BUILD', '-Og -g -feliminate-unused-debug-types', '-O2', d)} -pipe"
622BUILD_OPTIMIZATION[vardeps] += "DEBUG_BUILD"
623
624##################################################################
625# Settings used by bitbake-layers.
626##################################################################
627BBLAYERS_LAYERINDEX_URL ??= "https://layers.openembedded.org/layerindex/"
628BBLAYERS_FETCH_DIR ??= "${COREBASE}"
629
630##################################################################
631# Download locations and utilities.
632##################################################################
633
634APACHE_MIRROR = "https://archive.apache.org/dist"
635DEBIAN_MIRROR = "http://ftp.debian.org/debian/pool"
636GENTOO_MIRROR = "http://distfiles.gentoo.org/distfiles"
637GNOME_GIT = "git://gitlab.gnome.org/GNOME"
638GNOME_MIRROR = "https://ftp.gnome.org/pub/GNOME/sources"
639GNU_MIRROR = "https://ftp.gnu.org/gnu"
640GNUPG_MIRROR = "https://www.gnupg.org/ftp/gcrypt"
641GPE_MIRROR = "http://gpe.linuxtogo.org/download/source"
642KERNELORG_MIRROR = "https://cdn.kernel.org/pub"
643SOURCEFORGE_MIRROR = "https://downloads.sourceforge.net"
644XLIBS_MIRROR = "https://xlibs.freedesktop.org/release"
645XORG_MIRROR = "https://www.x.org/releases/"
646SAVANNAH_GNU_MIRROR = "https://download.savannah.gnu.org/releases"
647SAVANNAH_NONGNU_MIRROR = "https://download.savannah.nongnu.org/releases"
648CPAN_MIRROR = "https://search.cpan.org/CPAN"
649
650SRC_URI[vardepsexclude] += "\
651    APACHE_MIRROR \
652    CPAN_MIRROR \
653    DEBIAN_MIRROR \
654    GENTOO_MIRROR \
655    GNOME_GIT \
656    GNOME_MIRROR \
657    GNU_MIRROR \
658    GNUPG_MIRROR \
659    GPE_MIRROR \
660    KERNELORG_MIRROR \
661    SAVANNAH_GNU_MIRROR \
662    SAVANNAH_NONGNU_MIRROR \
663    SOURCEFORGE_MIRROR \
664    XLIBS_MIRROR \
665    XORG_MIRROR \
666"
667
668# You can use the mirror of your country to get faster downloads by putting
669#  export DEBIAN_MIRROR = "http://ftp.de.debian.org/debian/pool"
670#     into your local.conf
671
672SRCDATE = "${DATE}"
673SRCREV ??= "INVALID"
674AUTOREV = "${@bb.fetch2.get_autorev(d)}"
675AUTOREV[vardepvalue] = "${SRCPV}"
676# Set Dynamically in base.bbclass
677# SRCPV = "${@bb.fetch2.get_srcrev(d)}"
678SRCPV[vardepvalue] = "${SRCPV}"
679
680SRC_URI = ""
681
682# Use pseudo as the fakeroot implementation
683PSEUDO_LOCALSTATEDIR ?= "${WORKDIR}/pseudo/"
684PSEUDO_PASSWD ?= "${STAGING_DIR_TARGET}:${PSEUDO_SYSROOT}"
685PSEUDO_SYSROOT = "${COMPONENTS_DIR}/${BUILD_ARCH}/pseudo-native"
686PSEUDO_IGNORE_PATHS = "/usr/,/etc/,/lib,/dev/,/run/,${T},${WORKDIR}/recipe-sysroot,${SSTATE_DIR},${STAMPS_DIR}"
687PSEUDO_IGNORE_PATHS .= ",${TMPDIR}/sstate-control,${TMPDIR}/buildstats,${TMPDIR}/sysroots-components,${TMPDIR}/pkgdata"
688PSEUDO_IGNORE_PATHS .= ",${WORKDIR}/deploy-,${WORKDIR}/sstate-build-package_,${WORKDIR}/sstate-install-package_,${WORKDIR}/pkgdata-sysroot"
689PSEUDO_IGNORE_PATHS .= ",${DEPLOY_DIR},${BUILDHISTORY_DIR},${TOPDIR}/cache,${COREBASE}/scripts,${CCACHE_DIR}"
690
691export PSEUDO_DISABLED = "1"
692#export PSEUDO_PREFIX = "${STAGING_DIR_NATIVE}${prefix_native}"
693#export PSEUDO_BINDIR = "${STAGING_DIR_NATIVE}${bindir_native}"
694#export PSEUDO_LIBDIR = "${STAGING_DIR_NATIVE}$PSEUDOBINDIR/../lib/pseudo/lib
695FAKEROOTBASEENV = "PSEUDO_BINDIR=${PSEUDO_SYSROOT}${bindir_native} PSEUDO_LIBDIR=${PSEUDO_SYSROOT}${prefix_native}/lib/pseudo/lib PSEUDO_PREFIX=${PSEUDO_SYSROOT}${prefix_native} PSEUDO_IGNORE_PATHS=${@oe.path.canonicalize(d.getVar('PSEUDO_IGNORE_PATHS'))} PSEUDO_DISABLED=1 PYTHONDONTWRITEBYTECODE=1"
696FAKEROOTCMD = "${PSEUDO_SYSROOT}${bindir_native}/pseudo"
697FAKEROOTENV = "PSEUDO_PREFIX=${PSEUDO_SYSROOT}${prefix_native} PSEUDO_LOCALSTATEDIR=${PSEUDO_LOCALSTATEDIR} PSEUDO_PASSWD=${PSEUDO_PASSWD} PSEUDO_NOSYMLINKEXP=1 PSEUDO_IGNORE_PATHS=${@oe.path.canonicalize(d.getVar('PSEUDO_IGNORE_PATHS'))} PSEUDO_DISABLED=0"
698FAKEROOTNOENV = "PSEUDO_UNLOAD=1"
699FAKEROOTDIRS = "${PSEUDO_LOCALSTATEDIR}"
700FAKEROOTLOGS = "${WORKDIR}/pseudo/pseudo.log"
701PREFERRED_PROVIDER_virtual/fakeroot-native ?= "pseudo-native"
702
703##################################################################
704# Not sure about the rest of this yet.
705##################################################################
706
707# Pre-build configuration output
708BUILDCFG_HEADER = "Build Configuration${@" (mc:${BB_CURRENT_MC})" if d.getVar("BBMULTICONFIG") else ""}:"
709BUILDCFG_VARS = "BB_VERSION BUILD_SYS NATIVELSBSTRING TARGET_SYS MACHINE DISTRO DISTRO_VERSION TUNE_FEATURES TARGET_FPU"
710BUILDCFG_VARS[type] = "list"
711BUILDCFG_NEEDEDVARS = "TARGET_ARCH TARGET_OS"
712BUILDCFG_NEEDEDVARS[type] = "list"
713
714# Other
715
716export PKG_CONFIG_DIR = "${STAGING_DIR_HOST}${libdir}/pkgconfig"
717export PKG_CONFIG_PATH = "${PKG_CONFIG_DIR}:${STAGING_DATADIR}/pkgconfig"
718export PKG_CONFIG_LIBDIR = "${PKG_CONFIG_DIR}"
719export PKG_CONFIG_SYSROOT_DIR = "${STAGING_DIR_HOST}"
720export PKG_CONFIG_DISABLE_UNINSTALLED = "yes"
721export PKG_CONFIG_SYSTEM_LIBRARY_PATH = "${base_libdir}:${libdir}"
722export PKG_CONFIG_SYSTEM_INCLUDE_PATH = "${includedir}"
723
724# Don't allow git to chdir up past WORKDIR so that it doesn't detect the OE
725# repository when building a recipe
726export GIT_CEILING_DIRECTORIES = "${WORKDIR}"
727
728###
729### Config file processing
730###
731
732# An empty distro leads to :: entries in OVERRIDES and FILEOVERRIDES which
733# is a bad idea. Setting a dummy value is better than a ton of anonymous python.
734DISTRO ??= "nodistro"
735DISTRO_NAME ??= "OpenEmbedded"
736
737# Overrides are processed left to right, so the ones that are named later take precedence.
738# You generally want them to go from least to most specific. This means that:
739# A variable '<foo>_arm' overrides a variable '<foo>' when ${TARGET_ARCH} is arm.
740# A variable '<foo>_qemuarm' overrides '<foo>' and overrides '<foo>_arm' when ${MACHINE} is 'qemuarm'.
741# If you use combination ie '<foo>_qemuarm_arm', then '<foo>_qemuarm_arm' will override
742# '<foo>_qemuarm' and then '<foo>' will be overriden with that value from '<foo>_qemuarm'.
743# And finally '<foo>_forcevariable' overrides any standard variable, with the highest priority.
744# This works for functions as well, they are really just variables.
745#
746OVERRIDES = "${TARGET_OS}:${TRANSLATED_TARGET_ARCH}:pn-${PN}:${MACHINEOVERRIDES}:${DISTROOVERRIDES}:${CLASSOVERRIDE}${LIBCOVERRIDE}:forcevariable"
747LIBCOVERRIDE ?= ""
748CLASSOVERRIDE ?= "class-target"
749DISTROOVERRIDES ?= "${@d.getVar('DISTRO') or ''}"
750MACHINEOVERRIDES ?= "${MACHINE}"
751
752FILESOVERRIDES = "${TRANSLATED_TARGET_ARCH}:${MACHINEOVERRIDES}:${DISTROOVERRIDES}"
753
754##################################################################
755# Include the rest of the config files.
756##################################################################
757
758require conf/abi_version.conf
759include conf/site.conf
760include conf/auto.conf
761include conf/local.conf
762require conf/multiconfig/${BB_CURRENT_MC}.conf
763include conf/machine/${MACHINE}.conf
764include conf/machine-sdk/${SDKMACHINE}.conf
765include conf/distro/${DISTRO}.conf
766include conf/distro/defaultsetup.conf
767include conf/documentation.conf
768include conf/licenses.conf
769require conf/sanity.conf
770
771##################################################################
772# Weak variables (usually to retain backwards compatibility)
773##################################################################
774
775DL_DIR ?= "${TOPDIR}/downloads"
776SSTATE_DIR ?= "${TOPDIR}/sstate-cache"
777IMAGE_FSTYPES ?= "tar.gz"
778IMAGE_FSTYPES_DEBUGFS ?= "tar.gz"
779
780INITRAMFS_FSTYPES ?= "cpio.gz"
781# The maximum size in Kbytes for the generated initramfs image size.
782# Usually, it should be less than 1/2 of ram size, or you may fail to
783# boot it.
784INITRAMFS_MAXSIZE ??= "131072"
785
786DEFAULT_TASK_PROVIDER ?= "packagegroup-base"
787MACHINE_TASK_PROVIDER ?= "${DEFAULT_TASK_PROVIDER}"
788
789# The size in Kbytes for the generated image if it is larger than
790# the required size (du -ks IMAGE_ROOTFS * IMAGE_OVERHEAD_FACTOR),
791# and no effect if less than it.
792IMAGE_ROOTFS_SIZE ??= "65536"
793
794# Forcefully set CACHE now so future changes to things like
795# MACHINE don't change the path to the cache
796CACHE := "${CACHE}"
797
798# Default to setting automatically based on cpu count
799BB_NUMBER_THREADS ?= "${@oe.utils.cpu_count()}"
800
801# Default to setting automatically based on cpu count
802PARALLEL_MAKE ?= "-j ${@oe.utils.cpu_count()}"
803
804# Default parallelism and resource usage for xz
805XZ_MEMLIMIT ?= "50%"
806XZ_THREADS ?= "${@oe.utils.cpu_count(at_least=2)}"
807XZ_DEFAULTS ?= "--memlimit=${XZ_MEMLIMIT} --threads=${XZ_THREADS}"
808XZ_DEFAULTS[vardepsexclude] += "XZ_MEMLIMIT XZ_THREADS"
809
810##################################################################
811# Magic Cookie for SANITY CHECK
812##################################################################
813OES_BITBAKE_CONF = "1"
814
815##################################################################
816# Machine properties and packagegroup-base stuff
817##################################################################
818
819MACHINE_FEATURES ?= ""
820DISTRO_FEATURES ?= ""
821
822DISTRO_EXTRA_RDEPENDS ?= ""
823DISTRO_EXTRA_RRECOMMENDS ?= ""
824MACHINE_EXTRA_RDEPENDS ?= ""
825MACHINE_EXTRA_RRECOMMENDS ?= ""
826MACHINE_ESSENTIAL_EXTRA_RDEPENDS ?= ""
827MACHINE_ESSENTIAL_EXTRA_RRECOMMENDS ?= ""
828
829EXTRA_IMAGE_FEATURES ??= ""
830IMAGE_FEATURES += "${EXTRA_IMAGE_FEATURES}"
831
832# Native distro features (will always be used for -native, even if they
833# are not enabled for target)
834DISTRO_FEATURES_NATIVE ?= "x11 ipv6 xattr"
835DISTRO_FEATURES_NATIVESDK ?= "x11"
836
837# Normally target distro features will not be applied to native builds:
838# Native distro features on this list will use the target feature value
839DISTRO_FEATURES_FILTER_NATIVE ?= "api-documentation opengl"
840DISTRO_FEATURES_FILTER_NATIVESDK ?= "api-documentation opengl"
841
842DISTRO_FEATURES_BACKFILL = "pulseaudio sysvinit gobject-introspection-data ldconfig"
843MACHINE_FEATURES_BACKFILL = "rtc qemu-usermode"
844
845COMBINED_FEATURES = "${@oe.utils.set_intersect('DISTRO_FEATURES', 'MACHINE_FEATURES', d)}"
846COMBINED_FEATURES[vardeps] += "DISTRO_FEATURES MACHINE_FEATURES"
847
848SERIAL_CONSOLE ??= ""
849SERIAL_CONSOLES ??= "${@d.getVar('SERIAL_CONSOLE').replace(' ', ';')}"
850
851NO_RECOMMENDATIONS ??= ""
852BAD_RECOMMENDATIONS ?= ""
853
854# Make sure MACHINE isn't exported
855# (breaks binutils at least)
856MACHINE[unexport] = "1"
857
858# Make sure TARGET_ARCH isn't exported
859# (breaks Makefiles using implicit rules, e.g. quilt, as GNU make has this
860# in them, undocumented)
861TARGET_ARCH[unexport] = "1"
862
863# Make sure DISTRO isn't exported
864# (breaks sysvinit at least)
865DISTRO[unexport] = "1"
866
867# Make sure SHELL isn't exported
868# (can break any number of things if the user's shell isn't POSIX-compliant,
869# including the flock command). The user's shell shouldn't affect our builds.
870SHELL[unexport] = "1"
871
872# Used by canadian-cross to handle string conversions on TARGET_ARCH where needed
873TRANSLATED_TARGET_ARCH ??= "${@d.getVar('TARGET_ARCH').replace("_", "-")}"
874
875# Set a default umask to use for tasks for determinism
876BB_DEFAULT_UMASK = "022"
877
878# Complete output from bitbake
879BB_CONSOLELOG ?= "${LOG_DIR}/cooker/${MACHINE}/${DATETIME}.log"
880
881# Setup our default hash policy
882BB_SIGNATURE_HANDLER ?= "OEBasicHash"
883BB_HASHEXCLUDE_COMMON ?= "TMPDIR FILE PATH PWD BB_TASKHASH BBPATH BBSERVER DL_DIR \
884    THISDIR FILESEXTRAPATHS FILE_DIRNAME HOME LOGNAME SHELL \
885    USER FILESPATH STAGING_DIR_HOST STAGING_DIR_TARGET COREBASE PRSERV_HOST \
886    STAMPS_DIR PRSERV_DUMPDIR PRSERV_DUMPFILE PRSERV_LOCKDOWN PARALLEL_MAKE \
887    CCACHE_DIR EXTERNAL_TOOLCHAIN CCACHE CCACHE_NOHASHDIR LICENSE_PATH SDKPKGSUFFIX \
888    WARN_QA ERROR_QA WORKDIR STAMPCLEAN PKGDATA_DIR BUILD_ARCH SSTATE_PKGARCH \
889    BB_WORKERCONTEXT BB_LIMITEDDEPS BB_UNIHASH extend_recipe_sysroot DEPLOY_DIR \
890    SSTATE_HASHEQUIV_METHOD SSTATE_HASHEQUIV_REPORT_TASKDATA \
891    SSTATE_HASHEQUIV_OWNER CCACHE_TOP_DIR BB_HASHSERVE GIT_CEILING_DIRECTORIES"
892BB_HASHBASE_WHITELIST ?= "${BB_HASHEXCLUDE_COMMON} PSEUDO_IGNORE_PATHS BUILDHISTORY_DIR SSTATE_DIR "
893BB_HASHCONFIG_WHITELIST ?= "${BB_HASHEXCLUDE_COMMON} DATE TIME SSH_AGENT_PID \
894    SSH_AUTH_SOCK PSEUDO_BUILD BB_ENV_EXTRAWHITE DISABLE_SANITY_CHECKS \
895    PARALLEL_MAKE BB_NUMBER_THREADS BB_ORIGENV BB_INVALIDCONF BBINCLUDED \
896    GIT_PROXY_COMMAND ALL_PROXY all_proxy NO_PROXY no_proxy FTP_PROXY ftp_proxy \
897    HTTP_PROXY http_proxy HTTPS_PROXY https_proxy SOCKS5_USER SOCKS5_PASSWD \
898    BB_SETSCENE_ENFORCE BB_CMDLINE BB_SERVER_TIMEOUT"
899BB_SIGNATURE_EXCLUDE_FLAGS ?= "doc deps depends \
900    lockfiles type vardepsexclude vardeps vardepvalue vardepvalueexclude \
901    file-checksums python func task export unexport noexec nostamp dirs cleandirs \
902    sstate-lockfile-shared prefuncs postfuncs export_func deptask rdeptask \
903    recrdeptask nodeprrecs stamp-extra-info sstate-outputdirs filename lineno \
904    progress mcdepends number_threads"
905
906MLPREFIX ??= ""
907MULTILIB_VARIANTS ??= ""
908
909# Older versions of bitbake (< 1.42) don't set BB_UNIHASH. For compatibility with these
910# versions, set BB_UNIHASH equivalent to BB_TASKHASH if unspecified, which is
911# what it would be anyway if the signature generator (e.g. OEEquivHash) doesn't
912# support unihashes.
913BB_UNIHASH ?= "${BB_TASKHASH}"
914