xref: /openbmc/openbmc/poky/meta/conf/bitbake.conf (revision 7e0e3c0c) 
1##################################################################
2# Standard target filesystem paths.
3##################################################################
4#
5# If changing these values, beware that native/cross/nativesdk bbclass
6# files may also need changes to keep in sync.
7#
8
9# Used by multilib code to change the library paths
10baselib = "${BASELIB}"
11baselib[vardepvalue] = "${baselib}"
12BASELIB = "lib"
13BASELIB:libc-glibc:powerpc64 = "lib64"
14BASELIB:libc-glibc:powerpc64le = "lib64"
15
16# Path prefixes
17export base_prefix = ""
18export prefix = "/usr"
19export exec_prefix = "${prefix}"
20
21root_prefix = "${@bb.utils.contains('DISTRO_FEATURES', 'usrmerge', '${exec_prefix}', '${base_prefix}', d)}"
22
23# Base paths
24export base_bindir = "${root_prefix}/bin"
25export base_sbindir = "${root_prefix}/sbin"
26export base_libdir = "${root_prefix}/${baselib}"
27export nonarch_base_libdir = "${root_prefix}/lib"
28
29# Architecture independent paths
30export sysconfdir = "${base_prefix}/etc"
31export servicedir = "${base_prefix}/srv"
32export sharedstatedir = "${base_prefix}/com"
33export localstatedir = "${base_prefix}/var"
34export datadir = "${prefix}/share"
35export infodir = "${datadir}/info"
36export mandir = "${datadir}/man"
37export docdir = "${datadir}/doc"
38export systemd_unitdir = "${nonarch_base_libdir}/systemd"
39export systemd_system_unitdir = "${nonarch_base_libdir}/systemd/system"
40export nonarch_libdir = "${exec_prefix}/lib"
41export systemd_user_unitdir = "${nonarch_libdir}/systemd/user"
42
43# Architecture dependent paths
44export bindir = "${exec_prefix}/bin"
45export sbindir = "${exec_prefix}/sbin"
46export libdir = "${exec_prefix}/${baselib}"
47export libexecdir = "${exec_prefix}/libexec"
48export includedir = "${exec_prefix}/include"
49export oldincludedir = "${exec_prefix}/include"
50localedir = "${libdir}/locale"
51
52# Linkage between native/cross/nativesdk layouts
53base_bindir_native = "/bin"
54base_sbindir_native = "/sbin"
55sysconfdir_native = "/etc"
56prefix_native = "/usr"
57bindir_native = "${prefix_native}/bin"
58sbindir_native = "${prefix_native}/sbin"
59includedir_native = "${prefix_native}/include"
60libdir_native = "${prefix_native}/lib"
61libexecdir_native = "${prefix_native}/libexec"
62base_libdir_native = "/lib"
63datadir_native = "${prefix_native}/share"
64bindir_cross = "/bin"
65bindir_crossscripts = "${bindir}/crossscripts"
66prefix_nativesdk = "/usr"
67bindir_nativesdk = "${prefix_nativesdk}/bin"
68sbindir_nativesdk = "${prefix_nativesdk}/sbin"
69base_bindir_nativesdk = "/bin"
70base_sbindir_nativesdk = "/sbin"
71includedir_nativesdk = "${prefix_nativesdk}/include"
72libdir_nativesdk = "${prefix_nativesdk}/lib"
73base_libdir_nativesdk = "/lib"
74localstatedir_nativesdk = "/var"
75
76#
77# Cross recipes need to know about the target layout
78# := is used carefully here
79#
80target_datadir := "${datadir}"
81# Used to find env/perl/python
82USRBINPATH = "${bindir}"
83USRBINPATH:class-native = "/usr/bin"
84USRBINPATH:class-nativesdk = "/usr/bin"
85
86# Root home directory
87ROOT_HOME ??= "/home/root"
88
89# If set to boolean true ('yes', 'y', 'true', 't', '1'), /var/log links to /var/volatile/log.
90# If set to boolean false ('no', 'n', 'false', 'f', '0'), /var/log is on persistent storage.
91VOLATILE_LOG_DIR ?= "yes"
92
93BB_RENAMED_VARIABLES[PNBLACKLIST] = "SKIP_RECIPE"
94BB_RENAMED_VARIABLES[CVE_CHECK_PN_WHITELIST] = "CVE_CHECK_SKIP_RECIPE"
95BB_RENAMED_VARIABLES[CVE_CHECK_WHITELIST] = "CVE_CHECK_IGNORE"
96BB_RENAMED_VARIABLES[MULTI_PROVIDER_WHITELIST] = "BB_MULTI_PROVIDER_ALLOWED"
97BB_RENAMED_VARIABLES[PNBLACKLIST] = "SKIP_RECIPE"
98BB_RENAMED_VARIABLES[SDK_LOCAL_CONF_BLACKLIST] = "ESDK_LOCALCONF_REMOVE"
99BB_RENAMED_VARIABLES[SDK_LOCAL_CONF_WHITELIST] = "ESDK_LOCALCONF_ALLOW"
100BB_RENAMED_VARIABLES[SDK_INHERIT_BLACKLIST] = "ESDK_CLASS_INHERIT_DISABLE"
101BB_RENAMED_VARIABLES[SSTATE_DUPWHITELIST] = "SSTATE_ALLOW_OVERLAP_FILES"
102BB_RENAMED_VARIABLES[SYSROOT_DIRS_BLACKLIST] = "SYSROOT_DIRS_IGNORE"
103BB_RENAMED_VARIABLES[UNKNOWN_CONFIGURE_WHITELIST] = "UNKNOWN_CONFIGURE_OPT_IGNORE"
104BB_RENAMED_VARIABLES[ICECC_USER_CLASS_BL] = "ICECC_CLASS_DISABLE"
105BB_RENAMED_VARIABLES[ICECC_SYSTEM_CLASS_BL] = "ICECC_CLASS_DISABLE"
106BB_RENAMED_VARIABLES[ICECC_USER_PACKAGE_WL] = "ICECC_RECIPE_ENABLE"
107BB_RENAMED_VARIABLES[ICECC_USER_PACKAGE_BL] = "ICECC_RECIPE_DISABLE"
108BB_RENAMED_VARIABLES[ICECC_SYSTEM_PACKAGE_BL] = "ICECC_RECIPE_DISABLE"
109BB_RENAMED_VARIABLES[INHERIT_BLACKLIST] = "is a deprecated variable and no longer needed"
110BB_RENAMED_VARIABLES[TUNEABI_WHITELIST] = "is a deprecated variable and support has been removed"
111BB_RENAMED_VARIABLES[LICENSE_FLAGS_WHITELIST] = "LICENSE_FLAGS_ACCEPTED"
112
113##################################################################
114# Architecture-dependent build variables.
115##################################################################
116
117# Immediate expansion since there is no point in repeatedly calling
118# os.uname() throughout parsing
119BUILD_ARCH := "${@os.uname()[4]}"
120BUILD_OS := "${@os.uname()[0].lower()}"
121BUILD_VENDOR = ""
122BUILD_SYS = "${BUILD_ARCH}${BUILD_VENDOR}-${BUILD_OS}"
123BUILD_PREFIX = ""
124BUILD_CC_ARCH = ""
125BUILD_LD_ARCH = ""
126BUILD_AS_ARCH = ""
127BUILD_EXEEXT = ""
128
129HOST_ARCH = "${TARGET_ARCH}"
130HOST_OS = "${TARGET_OS}"
131HOST_VENDOR = "${TARGET_VENDOR}"
132HOST_SYS = "${HOST_ARCH}${HOST_VENDOR}-${HOST_OS}"
133HOST_PREFIX = "${TARGET_PREFIX}"
134HOST_CC_ARCH = "${TARGET_CC_ARCH}"
135HOST_LD_ARCH = "${TARGET_LD_ARCH}"
136HOST_AS_ARCH = "${TARGET_AS_ARCH}"
137HOST_EXEEXT = ""
138
139TUNE_ARCH ??= "INVALID"
140TUNE_CCARGS ??= ""
141TUNE_CCARGS[vardepvalue] = "${TUNE_CCARGS}"
142TUNE_LDARGS ??= ""
143TUNE_ASARGS ??= ""
144TUNE_FEATURES ??= "${TUNE_FEATURES:tune-${DEFAULTTUNE}}"
145LIBCEXTENSION ??= ""
146ABIEXTENSION ??= ""
147USE_NLS ??= "yes"
148SDKUSE_NLS ??= "yes"
149
150TARGET_ARCH = "${TUNE_ARCH}"
151TARGET_OS = "linux${LIBCEXTENSION}${ABIEXTENSION}"
152TARGET_VENDOR = "-oe"
153TARGET_SYS = "${TARGET_ARCH}${TARGET_VENDOR}-${TARGET_OS}"
154TARGET_PREFIX = "${TARGET_SYS}-"
155TARGET_CC_ARCH = "${TUNE_CCARGS}"
156TARGET_LD_ARCH = "${TUNE_LDARGS}"
157TARGET_AS_ARCH = "${TUNE_ASARGS}"
158
159SDKMACHINE ??= "${BUILD_ARCH}"
160SDK_OS = "${BUILD_OS}"
161SDK_VENDOR = "-oesdk"
162SDK_SYS = "${SDK_ARCH}${SDK_VENDOR}-${SDK_OS}"
163SDK_PREFIX = "${SDK_SYS}-"
164SDK_CC_ARCH = "${BUILD_CC_ARCH}"
165SDKPKGSUFFIX = "nativesdk"
166SDK_PACKAGE_ARCHS = "all any noarch ${SDK_ARCH}-${SDKPKGSUFFIX}"
167SDK_LD_ARCH = "${BUILD_LD_ARCH}"
168SDK_AS_ARCH = "${BUILD_AS_ARCH}"
169
170TUNE_PKGARCH ??= ""
171PACKAGE_ARCH ??= "${TUNE_PKGARCH}"
172MACHINE_ARCH = "${@[d.getVar('TUNE_PKGARCH'), d.getVar('MACHINE')][bool(d.getVar('MACHINE'))].replace('-', '_')}"
173PACKAGE_EXTRA_ARCHS ??= "${PACKAGE_EXTRA_ARCHS:tune-${DEFAULTTUNE}}"
174PACKAGE_ARCHS = "all any noarch ${PACKAGE_EXTRA_ARCHS} ${MACHINE_ARCH}"
175# MACHINE_ARCH shouldn't be included here as a variable dependency
176# since machine specific packages are handled using multimachine
177PACKAGE_ARCHS[vardepsexclude] = "MACHINE_ARCH"
178
179MULTIMACH_TARGET_SYS = "${PACKAGE_ARCH}${TARGET_VENDOR}-${TARGET_OS}"
180
181##################################################################
182# Date/time variables.
183##################################################################
184
185DATE := "${@time.strftime('%Y%m%d',time.gmtime())}"
186TIME := "${@time.strftime('%H%M%S',time.gmtime())}"
187DATETIME = "${DATE}${TIME}"
188
189##################################################################
190# Openembedded Software Prerequisites.
191##################################################################
192
193# python-native should be here but python relies on building
194# its own in staging
195ASSUME_PROVIDED = "\
196    bash-native \
197    bzip2-native \
198    chrpath-native \
199    diffstat-native \
200    file-native \
201    findutils-native \
202    gawk-native \
203    git-native \
204    grep-native \
205    hostperl-runtime-native \
206    hostpython-runtime-native \
207    libgcc-native \
208    patch-native \
209    sed-native \
210    tar-native \
211    texinfo-native \
212    virtual/crypt-native \
213    virtual/libiconv-native \
214    virtual/libintl-native \
215    wget-native \
216    "
217# gzip-native should be listed above?
218
219##################################################################
220# Package default variables.
221##################################################################
222
223PN = "${@bb.parse.vars_from_file(d.getVar('FILE', False),d)[0] or 'defaultpkgname'}"
224PV = "${@bb.parse.vars_from_file(d.getVar('FILE', False),d)[1] or '1.0'}"
225PR = "${@bb.parse.vars_from_file(d.getVar('FILE', False),d)[2] or 'r0'}"
226PE = ""
227PF = "${PN}-${EXTENDPE}${PV}-${PR}"
228EXTENDPE = "${@['','${PE}_'][int(d.getVar('PE') or 0) > 0]}"
229P = "${PN}-${PV}"
230
231PRSERV_PV_AUTOINC = "AUTOINC"
232PRAUTO = ""
233EXTENDPRAUTO = "${@['.${PRAUTO}', ''][not d.getVar('PRAUTO')]}"
234PRAUTOINX = "${PF}"
235
236PKGV ?= "${PV}"
237PKGR ?= "${PR}${EXTENDPRAUTO}"
238PKGE ?= "${@['','${PE}'][int(d.getVar('PE') or 0) > 0]}"
239EXTENDPKGEVER = "${@['','${PKGE}:'][d.getVar('PKGE').strip() != '']}"
240EXTENDPKGV ?= "${EXTENDPKGEVER}${PKGV}-${PKGR}"
241
242# Base package name
243# Automatically derives "foo" from "foo-native", "foo-cross" or "foo-initial"
244# otherwise it is the same as PN and P
245SPECIAL_PKGSUFFIX = "-native -cross -initial -intermediate -crosssdk -cross-canadian"
246BPN = "${@oe.utils.prune_suffix(d.getVar('PN'), d.getVar('SPECIAL_PKGSUFFIX').split(), d)}"
247BP = "${BPN}-${PV}"
248
249# Package info.
250
251SECTION = "base"
252PRIORITY = "optional"
253SUMMARY ?= "${PN} version ${PV}-${PR}"
254DESCRIPTION ?= "${SUMMARY}."
255
256# The following two are commented out because they result in a recursive
257# definition of the variable in some corner cases.  These are left in
258# to illustrate the intended behavior.
259#SUMMARY:${PN} ?= "${SUMMARY}"
260#DESCRIPTION:${PN} ?= "${DESCRIPTION}"
261
262SUMMARY:${PN}-src ?= "${SUMMARY} - Source files"
263DESCRIPTION:${PN}-src ?= "${DESCRIPTION}  \
264This package contains sources for debugging purposes."
265
266SUMMARY:${PN}-dbg ?= "${SUMMARY} - Debugging files"
267DESCRIPTION:${PN}-dbg ?= "${DESCRIPTION}  \
268This package contains ELF symbols and related sources for debugging purposes."
269
270SUMMARY:${PN}-dev ?= "${SUMMARY} - Development files"
271DESCRIPTION:${PN}-dev ?= "${DESCRIPTION}  \
272This package contains symbolic links, header files, and \
273related items necessary for software development."
274
275SUMMARY:${PN}-staticdev ?= "${SUMMARY} - Development files (Static Libraries)"
276DESCRIPTION:${PN}-staticdev ?= "${DESCRIPTION}  \
277This package contains static libraries for software development."
278
279SUMMARY:${PN}-doc ?= "${SUMMARY} - Documentation files"
280DESCRIPTION:${PN}-doc ?= "${DESCRIPTION}  \
281This package contains documentation."
282
283LICENSE ??= "INVALID"
284MAINTAINER = "OE-Core Developers <openembedded-core@lists.openembedded.org>"
285HOMEPAGE = ""
286
287# Package dependencies and provides.
288
289# Ensure that -dev packages recommend the corresponding -dev packages of their
290# deps, and the same for -dbg.
291DEPCHAIN_PRE = ""
292DEPCHAIN_POST = "-dev -dbg"
293
294DEPENDS = ""
295PROVIDES = ""
296PROVIDES:prepend = "${PN} "
297
298BB_MULTI_PROVIDER_ALLOWED = "virtual/libintl virtual/libintl-native virtual/nativesdk-libintl virtual/xserver virtual/update-alternatives-native virtual/update-alternatives"
299
300SOLIBS = ".so.*"
301SOLIBS:darwin = ".dylib"
302
303SOLIBSDEV = ".so"
304# Due to the ordering of PACKAGES and the naming of the dev symlinks on darwin,
305# we can't make the symlinks end up in the -dev packages easily at this point. This hack
306# at least means builds aren't completely broken and symlinks don't take up much space.
307SOLIBSDEV:darwin = ".dylibbroken"
308
309PACKAGE_DEBUG_SPLIT_STYLE ?= "debug-with-srcpkg"
310
311PACKAGE_BEFORE_PN ?= ""
312PACKAGES = "${PN}-src ${PN}-dbg ${PN}-staticdev ${PN}-dev ${PN}-doc ${PN}-locale ${PACKAGE_BEFORE_PN} ${PN}"
313PACKAGES_DYNAMIC = "^${PN}-locale-.*"
314FILES = ""
315
316FILES:${PN} = "${bindir}/* ${sbindir}/* ${libexecdir}/* ${libdir}/lib*${SOLIBS} \
317            ${sysconfdir} ${sharedstatedir} ${localstatedir} \
318            ${base_bindir}/* ${base_sbindir}/* \
319            ${base_libdir}/*${SOLIBS} \
320            ${base_prefix}/lib/udev ${prefix}/lib/udev \
321            ${base_libdir}/udev ${libdir}/udev \
322            ${datadir}/${BPN} ${libdir}/${BPN}/* \
323            ${datadir}/pixmaps ${datadir}/applications \
324            ${datadir}/idl ${datadir}/omf ${datadir}/sounds \
325            ${libdir}/bonobo/servers"
326
327FILES:${PN}-bin = "${bindir}/* ${sbindir}/*"
328
329FILES:${PN}-doc = "${docdir} ${mandir} ${infodir} ${datadir}/gtk-doc \
330            ${datadir}/gnome/help"
331SECTION:${PN}-doc = "doc"
332
333FILES_SOLIBSDEV ?= "${base_libdir}/lib*${SOLIBSDEV} ${libdir}/lib*${SOLIBSDEV}"
334FILES:${PN}-dev = "${includedir} ${FILES_SOLIBSDEV} ${libdir}/*.la \
335                ${libdir}/*.o ${libdir}/pkgconfig ${datadir}/pkgconfig \
336                ${datadir}/aclocal ${base_libdir}/*.o \
337                ${libdir}/${BPN}/*.la ${base_libdir}/*.la \
338                ${libdir}/cmake ${datadir}/cmake"
339SECTION:${PN}-dev = "devel"
340ALLOW_EMPTY:${PN}-dev = "1"
341RDEPENDS:${PN}-dev = "${PN} (= ${EXTENDPKGV})"
342
343FILES:${PN}-staticdev = "${libdir}/*.a ${base_libdir}/*.a ${libdir}/${BPN}/*.a"
344SECTION:${PN}-staticdev = "devel"
345RDEPENDS:${PN}-staticdev = "${PN}-dev (= ${EXTENDPKGV})"
346
347FILES:${PN}-dbg = "/usr/lib/debug /usr/lib/debug-static /usr/src/debug"
348SECTION:${PN}-dbg = "devel"
349ALLOW_EMPTY:${PN}-dbg = "1"
350
351# The files list for source packages are dynamically set based on
352# PACKAGE_DEBUG_SPLIT_STYLE
353FILES:${PN}-src = ""
354SECTION:${PN}-src = "devel"
355
356FILES:${PN}-locale = "${datadir}/locale"
357
358# File manifest
359
360FILE_DIRNAME = "${@os.path.dirname(d.getVar('FILE', False))}"
361# FILESPATH is set in base.bbclass
362#FILESPATH = "${FILE_DIRNAME}/${PF}:${FILE_DIRNAME}/${P}:${FILE_DIRNAME}/${PN}:${FILE_DIRNAME}/${BP}:${FILE_DIRNAME}/${BPN}:${FILE_DIRNAME}/files:${FILE_DIRNAME}"
363# This default was only used for checking
364FILESEXTRAPATHS ?= "__default:"
365
366# The default list of fs-perms files to process.  If the list is empty only
367# the builtin definitions will be used.  Builtin definitions included:
368#  base_prefix, prefix, exec_prefix, base_bindir, base_sbindir, base_libdir,
369#  datadir, sysconfdir, servicedir, sharedstatedir, localstatedir, infodir,
370#  mandir, docdir, bindir, sbindir, libexecdir, libdir, includedir and
371#  oldincludedir
372FILESYSTEM_PERMS_TABLES ?= "${@'files/fs-perms.txt' if oe.types.boolean(d.getVar('VOLATILE_LOG_DIR')) else 'files/fs-perms-persistent-log.txt'}"
373
374##################################################################
375# General work and output directories for the build system.
376##################################################################
377
378TCMODE ?= "default"
379TCLIBC ?= "glibc"
380TMPDIR ?= "${TOPDIR}/tmp"
381
382CACHE = "${TMPDIR}/cache/${TCMODE}-${TCLIBC}${@['', '/' + str(d.getVar('MACHINE'))][bool(d.getVar('MACHINE'))]}${@['', '/' + str(d.getVar('SDKMACHINE'))][bool(d.getVar('SDKMACHINE'))]}"
383# The persistent cache should be shared by all builds
384PERSISTENT_DIR = "${TOPDIR}/cache"
385LOG_DIR = "${TMPDIR}/log"
386
387STAMPS_DIR ?= "${TMPDIR}/stamps"
388STAMP = "${STAMPS_DIR}/${MULTIMACH_TARGET_SYS}/${PN}/${EXTENDPE}${PV}-${PR}"
389STAMPCLEAN = "${STAMPS_DIR}/${MULTIMACH_TARGET_SYS}/${PN}/*-*"
390BASE_WORKDIR ?= "${TMPDIR}/work"
391WORKDIR = "${BASE_WORKDIR}/${MULTIMACH_TARGET_SYS}/${PN}/${EXTENDPE}${PV}-${PR}"
392T = "${WORKDIR}/temp"
393D = "${WORKDIR}/image"
394S = "${WORKDIR}/${BP}"
395B = "${S}"
396
397STAGING_DIR = "${TMPDIR}/sysroots"
398COMPONENTS_DIR = "${STAGING_DIR}-components"
399RECIPE_SYSROOT = "${WORKDIR}/recipe-sysroot"
400RECIPE_SYSROOT_NATIVE = "${WORKDIR}/recipe-sysroot-native"
401
402STAGING_DIR_NATIVE = "${RECIPE_SYSROOT_NATIVE}"
403STAGING_BINDIR_NATIVE = "${STAGING_DIR_NATIVE}${bindir_native}"
404STAGING_BINDIR_CROSS = "${STAGING_BINDIR}/crossscripts"
405STAGING_BINDIR_TOOLCHAIN = "${STAGING_DIR_NATIVE}${bindir_native}/${TARGET_ARCH}${TARGET_VENDOR}-${TARGET_OS}"
406STAGING_LIBDIR_NATIVE = "${STAGING_DIR_NATIVE}${libdir_native}"
407STAGING_LIBEXECDIR_NATIVE = "${STAGING_DIR_NATIVE}${libexecdir_native}"
408STAGING_BASE_LIBDIR_NATIVE = "${STAGING_DIR_NATIVE}${base_libdir_native}"
409STAGING_SBINDIR_NATIVE = "${STAGING_DIR_NATIVE}${sbindir_native}"
410STAGING_INCDIR_NATIVE = "${STAGING_DIR_NATIVE}${includedir_native}"
411STAGING_ETCDIR_NATIVE = "${STAGING_DIR_NATIVE}${sysconfdir_native}"
412STAGING_DATADIR_NATIVE = "${STAGING_DIR_NATIVE}${datadir_native}"
413
414STAGING_DIR_HOST = "${RECIPE_SYSROOT}"
415STAGING_BINDIR = "${STAGING_DIR_HOST}${bindir}"
416STAGING_LIBDIR = "${STAGING_DIR_HOST}${libdir}"
417STAGING_LIBEXECDIR = "${STAGING_DIR_HOST}${libexecdir}"
418STAGING_BASELIBDIR = "${STAGING_DIR_HOST}${base_libdir}"
419STAGING_INCDIR = "${STAGING_DIR_HOST}${includedir}"
420STAGING_DATADIR = "${STAGING_DIR_HOST}${datadir}"
421STAGING_EXECPREFIXDIR = "${STAGING_DIR_HOST}${exec_prefix}"
422STAGING_LOADER_DIR = "${STAGING_DIR_HOST}/loader"
423STAGING_FIRMWARE_DIR = "${STAGING_DIR_HOST}/firmware"
424
425STAGING_DIR_TARGET = "${RECIPE_SYSROOT}"
426
427# Setting DEPLOY_DIR outside of TMPDIR is helpful, when you are using
428# packaged staging and/or multimachine.
429DEPLOY_DIR ?= "${TMPDIR}/deploy"
430DEPLOY_DIR_TAR = "${DEPLOY_DIR}/tar"
431DEPLOY_DIR_IPK = "${DEPLOY_DIR}/ipk"
432DEPLOY_DIR_RPM = "${DEPLOY_DIR}/rpm"
433DEPLOY_DIR_DEB = "${DEPLOY_DIR}/deb"
434DEPLOY_DIR_IMAGE ?= "${DEPLOY_DIR}/images/${MACHINE}"
435DEPLOY_DIR_TOOLS = "${DEPLOY_DIR}/tools"
436
437PKGDATA_DIR = "${TMPDIR}/pkgdata/${MACHINE}"
438PKGDATA_DIR_SDK = "${TMPDIR}/pkgdata/${SDK_SYS}"
439
440##################################################################
441# SDK variables.
442##################################################################
443
444SDK_NAME_PREFIX ?= "oecore"
445SDK_NAME = "${SDK_NAME_PREFIX}-${SDK_ARCH}-${TUNE_PKGARCH}"
446SDKPATH = "/usr/local/oe-sdk-hardcoded-buildpath"
447SDKPATHNATIVE = "${SDKPATH}/sysroots/${SDK_SYS}"
448# The path to default to installing the SDK to
449SDKPATHINSTALL = "/usr/local/${SDK_NAME_PREFIX}-${SDK_ARCH}"
450
451##################################################################
452# Kernel info.
453##################################################################
454
455OLDEST_KERNEL = "3.2.0"
456OLDEST_KERNEL:aarch64 = "3.14"
457OLDEST_KERNEL:nios2 = "3.19"
458OLDEST_KERNEL:powerpc64le = "3.10.0"
459OLDEST_KERNEL:riscv32 = "5.4"
460OLDEST_KERNEL:riscv64 = "4.15"
461
462# SDK_OLDEST_KERNEL can't be set using overrides since there are
463# none for the SDK architecture. Best to set it from a machine-sdk
464# include file if you need an SDK arch-specific value
465SDK_OLDEST_KERNEL = "3.2.0"
466
467# Define where the kernel headers are installed on the target as well as where
468# they are staged.
469KERNEL_SRC_PATH = "/usr/src/kernel"
470
471STAGING_KERNEL_DIR = "${TMPDIR}/work-shared/${MACHINE}/kernel-source"
472STAGING_KERNEL_BUILDDIR = "${TMPDIR}/work-shared/${MACHINE}/kernel-build-artifacts"
473
474##################################################################
475# Specific image creation and rootfs population info.
476##################################################################
477
478IMAGE_ROOTFS = "${WORKDIR}/rootfs"
479
480# This option allows for a percentage overage of the actual image size rather than a
481# fixed extra space, this is space needed for initial startup and basic operations.
482IMAGE_OVERHEAD_FACTOR ?= "1.3"
483# This option allows for adding additional space in K above and beyond what the
484# IMAGE_OVERHEAD_FACTOR might add. This space is for additional packages, user data, ...
485# To set a fixed size then overriding IMAGE_ROOTFS_SIZE with the max size one wants
486# should do the trick
487IMAGE_ROOTFS_EXTRA_SPACE ?= "0"
488
489EXTRA_IMAGEDEPENDS = ""
490
491##################################################################
492# Toolchain info.
493##################################################################
494
495PATH:prepend = "${COREBASE}/scripts:${STAGING_BINDIR_TOOLCHAIN}:${STAGING_BINDIR_CROSS}:${STAGING_DIR_NATIVE}${sbindir_native}:${STAGING_BINDIR_NATIVE}:${STAGING_DIR_NATIVE}${base_sbindir_native}:${STAGING_DIR_NATIVE}${base_bindir_native}:"
496export PATH
497
498##################################################################
499# Build utility info.
500##################################################################
501
502# Directory with symlinks to host tools used by build
503HOSTTOOLS_DIR = "${TMPDIR}/hosttools"
504
505# Tools needed to run builds with OE-Core
506HOSTTOOLS += " \
507    [ ar as awk basename bash bzip2 cat chgrp chmod chown chrpath cmp comm cp cpio \
508    cpp cut date dd diff diffstat dirname du echo egrep env expand expr false \
509    fgrep file find flock g++ gawk gcc getconf getopt git grep gunzip gzip \
510    head hostname iconv id install ld ldd ln ls lz4c make md5sum mkdir mkfifo mknod \
511    mktemp mv nm objcopy objdump od patch perl pr printf pwd \
512    python3 pzstd ranlib readelf readlink realpath rm rmdir rpcgen sed seq sh \
513    sha1sum sha224sum sha256sum sha384sum sha512sum \
514    sleep sort split stat strings strip tail tar tee test touch tr true uname \
515    uniq wc wget which xargs zstd \
516"
517
518# Tools needed to run testimage runtime image testing
519HOSTTOOLS += "${@'ip ping ps scp ssh stty' if (bb.utils.contains_any('IMAGE_CLASSES', 'testimage testsdk', True, False, d) or any(x in (d.getVar("BBINCLUDED") or "") for x in ["testimage.bbclass", "testsdk.bbclass"])) else ''}"
520
521# Link to these if present
522HOSTTOOLS_NONFATAL += "aws gcc-ar gpg gpg-agent ld.bfd ld.gold nc pigz sftp socat ssh sudo"
523
524# Temporary add few more detected in bitbake world
525HOSTTOOLS_NONFATAL += "join nl size yes zcat"
526
527# Used by bzr fetcher
528HOSTTOOLS_NONFATAL += "bzr"
529
530# Used by ssh fetcher
531HOSTTOOLS_NONFATAL += "scp"
532
533# Link to git-lfs if present
534HOSTTOOLS_NONFATAL += "git-lfs"
535
536CCACHE ??= ""
537
538TOOLCHAIN_OPTIONS = " --sysroot=${STAGING_DIR_TARGET}"
539
540export CC = "${CCACHE}${HOST_PREFIX}gcc ${HOST_CC_ARCH}${TOOLCHAIN_OPTIONS}"
541export CXX = "${CCACHE}${HOST_PREFIX}g++ ${HOST_CC_ARCH}${TOOLCHAIN_OPTIONS}"
542export FC = "${CCACHE}${HOST_PREFIX}gfortran ${HOST_CC_ARCH}${TOOLCHAIN_OPTIONS}"
543export CPP = "${HOST_PREFIX}gcc -E${TOOLCHAIN_OPTIONS} ${HOST_CC_ARCH}"
544export LD = "${HOST_PREFIX}ld${TOOLCHAIN_OPTIONS} ${HOST_LD_ARCH}"
545export CCLD = "${CC}"
546export AR = "${HOST_PREFIX}gcc-ar"
547export AS = "${HOST_PREFIX}as ${HOST_AS_ARCH}"
548export RANLIB = "${HOST_PREFIX}gcc-ranlib"
549export STRIP = "${HOST_PREFIX}strip"
550export OBJCOPY = "${HOST_PREFIX}objcopy"
551export OBJDUMP = "${HOST_PREFIX}objdump"
552export STRINGS = "${HOST_PREFIX}strings"
553export NM = "${HOST_PREFIX}gcc-nm"
554export READELF = "${HOST_PREFIX}readelf"
555PYTHON = "${@sys.executable}"
556
557export BUILD_CC = "${CCACHE}${BUILD_PREFIX}gcc ${BUILD_CC_ARCH}"
558export BUILD_CXX = "${CCACHE}${BUILD_PREFIX}g++ ${BUILD_CC_ARCH}"
559export BUILD_FC = "${CCACHE}${BUILD_PREFIX}gfortran ${BUILD_CC_ARCH}"
560export BUILD_CPP = "${BUILD_PREFIX}gcc ${BUILD_CC_ARCH} -E"
561export BUILD_LD = "${BUILD_PREFIX}ld ${BUILD_LD_ARCH}"
562export BUILD_CCLD = "${BUILD_PREFIX}gcc ${BUILD_CC_ARCH}"
563export BUILD_AR = "${BUILD_PREFIX}ar"
564export BUILD_AS = "${BUILD_PREFIX}as ${BUILD_AS_ARCH}"
565export BUILD_RANLIB = "${BUILD_PREFIX}ranlib -D"
566export BUILD_STRIP = "${BUILD_PREFIX}strip"
567BUILD_OBJCOPY = "${BUILD_PREFIX}objcopy"
568BUILD_OBJDUMP = "${BUILD_PREFIX}objdump"
569export BUILD_NM = "${BUILD_PREFIX}nm"
570BUILD_READELF = "${BUILD_PREFIX}readelf"
571
572export MAKE = "make"
573EXTRA_OEMAKE = ""
574EXTRA_OECONF = ""
575export LC_ALL = "en_US.UTF-8"
576export TZ = 'UTC'
577
578##################################################################
579# Patch handling.
580##################################################################
581PATCHTOOL = "quilt"
582PATCHRESOLVE = "noop"
583
584##################################################################
585# Build flags and options.
586##################################################################
587
588export BUILD_CPPFLAGS = "-isystem${STAGING_INCDIR_NATIVE}"
589BUILDSDK_CPPFLAGS = ""
590export CPPFLAGS = "${TARGET_CPPFLAGS}"
591TARGET_CPPFLAGS = ""
592
593export BUILD_CFLAGS = "${BUILD_CPPFLAGS} ${BUILD_OPTIMIZATION}"
594BUILDSDK_CFLAGS = "${BUILDSDK_CPPFLAGS} ${BUILD_OPTIMIZATION} ${DEBUG_PREFIX_MAP}"
595export CFLAGS = "${TARGET_CFLAGS}"
596TARGET_CFLAGS = "${TARGET_CPPFLAGS} ${SELECTED_OPTIMIZATION}"
597
598export BUILD_CXXFLAGS = "${BUILD_CFLAGS}"
599BUILDSDK_CXXFLAGS = "${BUILDSDK_CFLAGS}"
600export CXXFLAGS = "${TARGET_CXXFLAGS}"
601TARGET_CXXFLAGS = "${TARGET_CFLAGS}"
602
603export BUILD_LDFLAGS = "-L${STAGING_LIBDIR_NATIVE} \
604                        -L${STAGING_BASE_LIBDIR_NATIVE} \
605                        -Wl,--enable-new-dtags \
606                        -Wl,-rpath-link,${STAGING_LIBDIR_NATIVE} \
607                        -Wl,-rpath-link,${STAGING_BASE_LIBDIR_NATIVE} \
608                        -Wl,-rpath,${STAGING_LIBDIR_NATIVE} \
609                        -Wl,-rpath,${STAGING_BASE_LIBDIR_NATIVE} \
610                        -Wl,-O1"
611
612BUILDSDK_LDFLAGS = "-Wl,-O1"
613
614LINKER_HASH_STYLE ??= "gnu"
615
616TARGET_LINK_HASH_STYLE ?= "${@['-Wl,--hash-style=gnu',''][d.getVar('LINKER_HASH_STYLE') != 'gnu']}"
617
618ASNEEDED ?= "-Wl,--as-needed"
619
620export LDFLAGS = "${TARGET_LDFLAGS}"
621TARGET_LDFLAGS = "-Wl,-O1 ${TARGET_LINK_HASH_STYLE} ${ASNEEDED} ${DEBUG_PREFIX_MAP}"
622# mips does not support GNU hash style therefore we override
623LINKER_HASH_STYLE:mipsarch:libc-musl = "sysv"
624
625# Pass parallel make options to the compile task
626EXTRA_OEMAKE:prepend:task-compile = "${PARALLEL_MAKE} "
627PARALLEL_MAKEINST ??= "${PARALLEL_MAKE}"
628PARALLEL_MAKEINST[vardepvalue] = "1"
629# Pass parallel make options to the install task
630EXTRA_OEMAKE:prepend:task-install = "${PARALLEL_MAKEINST} "
631
632##################################################################
633# Optimization flags.
634##################################################################
635# Beware: applied last to first
636DEBUG_PREFIX_MAP ?= "-fmacro-prefix-map=${WORKDIR}=/usr/src/debug/${PN}/${EXTENDPE}${PV}-${PR} \
637                     -fdebug-prefix-map=${WORKDIR}=/usr/src/debug/${PN}/${EXTENDPE}${PV}-${PR} \
638                     -fdebug-prefix-map=${STAGING_DIR_HOST}= \
639                     -fdebug-prefix-map=${STAGING_DIR_NATIVE}= \
640"
641DEBUG_FLAGS ?= "-g -feliminate-unused-debug-types ${DEBUG_PREFIX_MAP}"
642
643# Disabled until the option works properly -feliminate-dwarf2-dups
644FULL_OPTIMIZATION = "-O2 -pipe ${DEBUG_FLAGS}"
645DEBUG_OPTIMIZATION = "-Og ${DEBUG_FLAGS} -pipe"
646SELECTED_OPTIMIZATION = "${@d.getVar(oe.utils.vartrue('DEBUG_BUILD', 'DEBUG_OPTIMIZATION', 'FULL_OPTIMIZATION', d))}"
647SELECTED_OPTIMIZATION[vardeps] += "FULL_OPTIMIZATION DEBUG_OPTIMIZATION DEBUG_BUILD"
648BUILD_OPTIMIZATION = "${@oe.utils.vartrue('DEBUG_BUILD', '-Og -g -feliminate-unused-debug-types', '-O2', d)} -pipe"
649BUILD_OPTIMIZATION[vardeps] += "DEBUG_BUILD"
650
651##################################################################
652# Reproducibility
653##################################################################
654
655SDE_DIR = "${WORKDIR}/source-date-epoch"
656SDE_FILE = "${SDE_DIR}/__source_date_epoch.txt"
657SDE_DEPLOYDIR = "${WORKDIR}/deploy-source-date-epoch"
658
659export PYTHONHASHSEED = "0"
660export PERL_HASH_SEED = "0"
661export SOURCE_DATE_EPOCH ?= "${@get_source_date_epoch_value(d)}"
662# A SOURCE_DATE_EPOCH of '0' might be misinterpreted as no SDE
663export SOURCE_DATE_EPOCH_FALLBACK ??= "1302044400"
664REPRODUCIBLE_TIMESTAMP_ROOTFS ??= "1520598896"
665
666##################################################################
667# Settings used by bitbake-layers.
668##################################################################
669BBLAYERS_LAYERINDEX_URL ??= "https://layers.openembedded.org/layerindex/"
670BBLAYERS_FETCH_DIR ??= "${COREBASE}"
671
672##################################################################
673# Download locations and utilities.
674##################################################################
675
676APACHE_MIRROR = "https://archive.apache.org/dist"
677CPAN_MIRROR = "https://search.cpan.org/CPAN"
678DEBIAN_MIRROR = "http://ftp.debian.org/debian/pool"
679GENTOO_MIRROR = "http://distfiles.gentoo.org/distfiles"
680GNOME_GIT = "git://gitlab.gnome.org/GNOME"
681GNOME_MIRROR = "https://download.gnome.org/sources/"
682GNU_MIRROR = "https://ftp.gnu.org/gnu"
683GNUPG_MIRROR = "https://www.gnupg.org/ftp/gcrypt"
684GPE_MIRROR = "http://gpe.linuxtogo.org/download/source"
685KERNELORG_MIRROR = "https://cdn.kernel.org/pub"
686SAMBA_MIRROR = "http://samba.org/samba/ftp"
687SAVANNAH_GNU_MIRROR = "https://download.savannah.gnu.org/releases"
688SAVANNAH_NONGNU_MIRROR = "https://download.savannah.nongnu.org/releases"
689SOURCEFORGE_MIRROR = "https://downloads.sourceforge.net"
690XLIBS_MIRROR = "https://xlibs.freedesktop.org/release"
691XORG_MIRROR = "https://www.x.org/releases/"
692
693SRC_URI[vardepsexclude] += "\
694    APACHE_MIRROR \
695    CPAN_MIRROR \
696    DEBIAN_MIRROR \
697    GENTOO_MIRROR \
698    GNOME_GIT \
699    GNOME_MIRROR \
700    GNU_MIRROR \
701    GNUPG_MIRROR \
702    GPE_MIRROR \
703    KERNELORG_MIRROR \
704    SAMBA_MIRROR \
705    SAVANNAH_GNU_MIRROR \
706    SAVANNAH_NONGNU_MIRROR \
707    SOURCEFORGE_MIRROR \
708    XLIBS_MIRROR \
709    XORG_MIRROR \
710"
711
712# You can use the mirror of your country to get faster downloads by putting
713#  export DEBIAN_MIRROR = "http://ftp.de.debian.org/debian/pool"
714#     into your local.conf
715
716SRCDATE = "${DATE}"
717SRCREV ??= "INVALID"
718AUTOREV = "${@bb.fetch2.get_autorev(d)}"
719AUTOREV[vardepvalue] = "${SRCPV}"
720# Set Dynamically in base.bbclass
721# SRCPV = "${@bb.fetch2.get_srcrev(d)}"
722SRCPV[vardepvalue] = "${SRCPV}"
723
724SRC_URI = ""
725
726# Use pseudo as the fakeroot implementation
727PSEUDO_LOCALSTATEDIR ?= "${WORKDIR}/pseudo/"
728PSEUDO_PASSWD ?= "${STAGING_DIR_TARGET}:${PSEUDO_SYSROOT}"
729PSEUDO_SYSROOT = "${COMPONENTS_DIR}/${BUILD_ARCH}/pseudo-native"
730PSEUDO_IGNORE_PATHS = "/usr/,/etc/,/lib,/dev/,/run/,${T},${WORKDIR}/recipe-sysroot,${SSTATE_DIR},${STAMPS_DIR}"
731PSEUDO_IGNORE_PATHS .= ",${TMPDIR}/sstate-control,${TMPDIR}/buildstats,${TMPDIR}/sysroots-components,${TMPDIR}/pkgdata"
732PSEUDO_IGNORE_PATHS .= ",${WORKDIR}/deploy-,${WORKDIR}/sstate-build-package_,${WORKDIR}/sstate-install-package_,${WORKDIR}/pkgdata-sysroot"
733PSEUDO_IGNORE_PATHS .= ",${DEPLOY_DIR},${BUILDHISTORY_DIR},${TOPDIR}/cache,${COREBASE}/scripts,${CCACHE_DIR}"
734
735export PSEUDO_DISABLED = "1"
736#export PSEUDO_PREFIX = "${STAGING_DIR_NATIVE}${prefix_native}"
737#export PSEUDO_BINDIR = "${STAGING_DIR_NATIVE}${bindir_native}"
738#export PSEUDO_LIBDIR = "${STAGING_DIR_NATIVE}$PSEUDOBINDIR/../lib/pseudo/lib
739FAKEROOTBASEENV = "PSEUDO_BINDIR=${PSEUDO_SYSROOT}${bindir_native} PSEUDO_LIBDIR=${PSEUDO_SYSROOT}${prefix_native}/lib/pseudo/lib PSEUDO_PREFIX=${PSEUDO_SYSROOT}${prefix_native} PSEUDO_IGNORE_PATHS=${@oe.path.canonicalize(d.getVar('PSEUDO_IGNORE_PATHS'))} PSEUDO_DISABLED=1 PYTHONDONTWRITEBYTECODE=1"
740FAKEROOTCMD = "${PSEUDO_SYSROOT}${bindir_native}/pseudo"
741FAKEROOTENV = "PSEUDO_PREFIX=${PSEUDO_SYSROOT}${prefix_native} PSEUDO_LOCALSTATEDIR=${PSEUDO_LOCALSTATEDIR} PSEUDO_PASSWD=${PSEUDO_PASSWD} PSEUDO_NOSYMLINKEXP=1 PSEUDO_IGNORE_PATHS=${@oe.path.canonicalize(d.getVar('PSEUDO_IGNORE_PATHS'))} PSEUDO_DISABLED=0"
742FAKEROOTNOENV = "PSEUDO_UNLOAD=1"
743FAKEROOTDIRS = "${PSEUDO_LOCALSTATEDIR}"
744FAKEROOTLOGS = "${WORKDIR}/pseudo/pseudo.log"
745PREFERRED_PROVIDER_virtual/fakeroot-native ?= "pseudo-native"
746
747##################################################################
748# Not sure about the rest of this yet.
749##################################################################
750
751# Pre-build configuration output
752BUILDCFG_HEADER = "Build Configuration${@" (mc:${BB_CURRENT_MC})" if d.getVar("BBMULTICONFIG") else ""}:"
753BUILDCFG_VARS = "BB_VERSION BUILD_SYS NATIVELSBSTRING TARGET_SYS MACHINE DISTRO DISTRO_VERSION TUNE_FEATURES TARGET_FPU"
754BUILDCFG_VARS[type] = "list"
755BUILDCFG_NEEDEDVARS = "TARGET_ARCH TARGET_OS"
756BUILDCFG_NEEDEDVARS[type] = "list"
757
758# Other
759
760export PKG_CONFIG_DIR = "${STAGING_DIR_HOST}${libdir}/pkgconfig"
761export PKG_CONFIG_PATH = "${PKG_CONFIG_DIR}:${STAGING_DATADIR}/pkgconfig"
762export PKG_CONFIG_LIBDIR = "${PKG_CONFIG_DIR}"
763export PKG_CONFIG_SYSROOT_DIR = "${STAGING_DIR_HOST}"
764export PKG_CONFIG_DISABLE_UNINSTALLED = "yes"
765export PKG_CONFIG_SYSTEM_LIBRARY_PATH = "${base_libdir}:${libdir}"
766export PKG_CONFIG_SYSTEM_INCLUDE_PATH = "${includedir}"
767
768# Don't allow git to chdir up past WORKDIR so that it doesn't detect the OE
769# repository when building a recipe
770export GIT_CEILING_DIRECTORIES = "${WORKDIR}"
771
772###
773### Config file processing
774###
775
776# An empty distro leads to :: entries in OVERRIDES and FILEOVERRIDES which
777# is a bad idea. Setting a dummy value is better than a ton of anonymous python.
778DISTRO ??= "nodistro"
779DISTRO_NAME ??= "OpenEmbedded"
780
781# Overrides are processed left to right, so the ones that are named later take precedence.
782# You generally want them to go from least to most specific. This means that:
783# A variable '<foo>:arm' overrides a variable '<foo>' when ${TARGET_ARCH} is arm.
784# A variable '<foo>:qemuarm' overrides '<foo>' and overrides '<foo>:arm' when ${MACHINE} is 'qemuarm'.
785# If you use combination ie '<foo>:qemuarm:arm', then '<foo>:qemuarm:arm' will override
786# '<foo>:qemuarm' and then '<foo>' will be overriden with that value from '<foo>:qemuarm'.
787# And finally '<foo>:forcevariable' overrides any standard variable, with the highest priority.
788# This works for functions as well, they are really just variables.
789#
790OVERRIDES = "${TARGET_OS}:${TRANSLATED_TARGET_ARCH}:pn-${PN}:${MACHINEOVERRIDES}:${DISTROOVERRIDES}:${CLASSOVERRIDE}${LIBCOVERRIDE}:forcevariable"
791LIBCOVERRIDE ?= ""
792CLASSOVERRIDE ?= "class-target"
793DISTROOVERRIDES ?= "${@d.getVar('DISTRO') or ''}"
794MACHINEOVERRIDES ?= "${MACHINE}"
795
796FILESOVERRIDES = "${TRANSLATED_TARGET_ARCH}:${MACHINEOVERRIDES}:${DISTROOVERRIDES}"
797
798##################################################################
799# Include the rest of the config files.
800##################################################################
801
802require conf/abi_version.conf
803include conf/site.conf
804include conf/auto.conf
805include conf/local.conf
806require conf/multiconfig/${BB_CURRENT_MC}.conf
807include conf/machine/${MACHINE}.conf
808include conf/machine-sdk/${SDKMACHINE}.conf
809include conf/distro/${DISTRO}.conf
810include conf/distro/defaultsetup.conf
811include conf/documentation.conf
812include conf/licenses.conf
813require conf/sanity.conf
814
815##################################################################
816# Weak variables (usually to retain backwards compatibility)
817##################################################################
818
819DL_DIR ?= "${TOPDIR}/downloads"
820SSTATE_DIR ?= "${TOPDIR}/sstate-cache"
821IMAGE_FSTYPES ?= "tar.gz"
822IMAGE_FSTYPES_DEBUGFS ?= "tar.gz"
823
824INITRAMFS_FSTYPES ?= "cpio.gz"
825# The maximum size in Kbytes for the generated initramfs image size.
826# Usually, it should be less than 1/2 of ram size, or you may fail to
827# boot it.
828INITRAMFS_MAXSIZE ??= "131072"
829
830DEFAULT_TASK_PROVIDER ?= "packagegroup-base"
831MACHINE_TASK_PROVIDER ?= "${DEFAULT_TASK_PROVIDER}"
832
833# The size in Kbytes for the generated image if it is larger than
834# the required size (du -ks IMAGE_ROOTFS * IMAGE_OVERHEAD_FACTOR),
835# and no effect if less than it.
836IMAGE_ROOTFS_SIZE ??= "65536"
837
838# Forcefully set CACHE now so future changes to things like
839# MACHINE don't change the path to the cache
840CACHE := "${CACHE}"
841
842# Default to setting automatically based on cpu count
843BB_NUMBER_THREADS ?= "${@oe.utils.cpu_count()}"
844
845# Default to setting automatically based on cpu count
846PARALLEL_MAKE ?= "-j ${@oe.utils.cpu_count()}"
847
848# Default parallelism and resource usage for xz
849XZ_MEMLIMIT ?= "50%"
850XZ_THREADS ?= "${@oe.utils.cpu_count(at_least=2)}"
851XZ_THREADS[vardepvalue] = "1"
852XZ_DEFAULTS ?= "--memlimit=${XZ_MEMLIMIT} --threads=${XZ_THREADS}"
853XZ_DEFAULTS[vardepsexclude] += "XZ_MEMLIMIT XZ_THREADS"
854
855# Default parallelism for zstd
856ZSTD_THREADS ?= "${@oe.utils.cpu_count(at_least=2)}"
857ZSTD_THREADS[vardepvalue] = "1"
858
859# Limit the number of threads that OpenMP libraries will use. Otherwise they
860# may fallback to using all CPUs
861export OMP_NUM_THREADS = "${BB_NUMBER_THREADS}"
862
863##################################################################
864# Magic Cookie for SANITY CHECK
865##################################################################
866OES_BITBAKE_CONF = "1"
867
868##################################################################
869# Machine properties and packagegroup-base stuff
870##################################################################
871
872MACHINE_FEATURES ?= ""
873DISTRO_FEATURES ?= ""
874
875DISTRO_EXTRA_RDEPENDS ?= ""
876DISTRO_EXTRA_RRECOMMENDS ?= ""
877MACHINE_EXTRA_RDEPENDS ?= ""
878MACHINE_EXTRA_RRECOMMENDS ?= ""
879MACHINE_ESSENTIAL_EXTRA_RDEPENDS ?= ""
880MACHINE_ESSENTIAL_EXTRA_RRECOMMENDS ?= ""
881
882EXTRA_IMAGE_FEATURES ??= ""
883IMAGE_FEATURES += "${EXTRA_IMAGE_FEATURES}"
884
885# Native distro features (will always be used for -native, even if they
886# are not enabled for target)
887DISTRO_FEATURES_NATIVE ?= "x11 ipv6 xattr"
888DISTRO_FEATURES_NATIVESDK ?= "x11"
889
890# Normally target distro features will not be applied to native builds:
891# Native distro features on this list will use the target feature value
892DISTRO_FEATURES_FILTER_NATIVE ?= "api-documentation debuginfod opengl wayland"
893DISTRO_FEATURES_FILTER_NATIVESDK ?= "api-documentation debuginfod opengl wayland"
894
895DISTRO_FEATURES_BACKFILL = "pulseaudio sysvinit gobject-introspection-data ldconfig"
896MACHINE_FEATURES_BACKFILL = "rtc qemu-usermode"
897
898COMBINED_FEATURES = "${@oe.utils.set_intersect('DISTRO_FEATURES', 'MACHINE_FEATURES', d)}"
899COMBINED_FEATURES[vardeps] += "DISTRO_FEATURES MACHINE_FEATURES"
900
901SERIAL_CONSOLE ??= ""
902SERIAL_CONSOLES ??= "${@d.getVar('SERIAL_CONSOLE').replace(' ', ';')}"
903
904NO_RECOMMENDATIONS ??= ""
905BAD_RECOMMENDATIONS ?= ""
906
907# Make sure MACHINE isn't exported
908# (breaks binutils at least)
909MACHINE[unexport] = "1"
910
911# Make sure TARGET_ARCH isn't exported
912# (breaks Makefiles using implicit rules, e.g. quilt, as GNU make has this
913# in them, undocumented)
914TARGET_ARCH[unexport] = "1"
915
916# Make sure DISTRO isn't exported
917# (breaks sysvinit at least)
918DISTRO[unexport] = "1"
919
920# Make sure SHELL isn't exported
921# (can break any number of things if the user's shell isn't POSIX-compliant,
922# including the flock command). The user's shell shouldn't affect our builds.
923SHELL[unexport] = "1"
924
925# Used by canadian-cross to handle string conversions on TARGET_ARCH where needed
926TRANSLATED_TARGET_ARCH ??= "${@d.getVar('TARGET_ARCH').replace("_", "-")}"
927
928# Set a default umask to use for tasks for determinism
929BB_DEFAULT_UMASK = "022"
930
931# Complete output from bitbake
932BB_CONSOLELOG ?= "${LOG_DIR}/cooker/${MACHINE}/${DATETIME}.log"
933
934# Setup our default hash policy
935BB_SIGNATURE_HANDLER ?= "OEBasicHash"
936BB_HASHEXCLUDE_COMMON ?= "TMPDIR FILE PATH PWD BB_TASKHASH BBPATH BBSERVER DL_DIR \
937    THISDIR FILESEXTRAPATHS FILE_DIRNAME HOME LOGNAME SHELL \
938    USER FILESPATH STAGING_DIR_HOST STAGING_DIR_TARGET COREBASE PRSERV_HOST \
939    STAMPS_DIR PRSERV_DUMPDIR PRSERV_DUMPFILE PRSERV_LOCKDOWN PARALLEL_MAKE \
940    CCACHE_DIR EXTERNAL_TOOLCHAIN CCACHE CCACHE_NOHASHDIR LICENSE_PATH SDKPKGSUFFIX \
941    WARN_QA ERROR_QA WORKDIR STAMPCLEAN PKGDATA_DIR BUILD_ARCH SSTATE_PKGARCH \
942    BB_WORKERCONTEXT BB_LIMITEDDEPS BB_UNIHASH extend_recipe_sysroot DEPLOY_DIR \
943    SSTATE_HASHEQUIV_METHOD SSTATE_HASHEQUIV_REPORT_TASKDATA \
944    SSTATE_HASHEQUIV_OWNER CCACHE_TOP_DIR BB_HASHSERVE GIT_CEILING_DIRECTORIES \
945    OMP_NUM_THREADS BB_CURRENTTASK"
946BB_BASEHASH_IGNORE_VARS ?= "${BB_HASHEXCLUDE_COMMON} PSEUDO_IGNORE_PATHS BUILDHISTORY_DIR \
947    SSTATE_DIR SOURCE_DATE_EPOCH"
948BB_HASHCONFIG_IGNORE_VARS ?= "${BB_HASHEXCLUDE_COMMON} DATE TIME SSH_AGENT_PID \
949    SSH_AUTH_SOCK PSEUDO_BUILD BB_ENV_PASSTHROUGH_ADDITIONS DISABLE_SANITY_CHECKS \
950    PARALLEL_MAKE BB_NUMBER_THREADS BB_ORIGENV BB_INVALIDCONF BBINCLUDED \
951    GIT_PROXY_COMMAND ALL_PROXY all_proxy NO_PROXY no_proxy FTP_PROXY ftp_proxy \
952    HTTP_PROXY http_proxy HTTPS_PROXY https_proxy SOCKS5_USER SOCKS5_PASSWD \
953    BB_SETSCENE_ENFORCE BB_CMDLINE BB_SERVER_TIMEOUT"
954BB_SIGNATURE_EXCLUDE_FLAGS ?= "doc deps depends \
955    lockfiles type vardepsexclude vardeps vardepvalue vardepvalueexclude \
956    file-checksums python func task export unexport noexec nostamp dirs cleandirs \
957    sstate-lockfile-shared prefuncs postfuncs export_func deptask rdeptask \
958    recrdeptask nodeprrecs stamp-extra-info sstate-outputdirs filename lineno \
959    progress mcdepends number_threads"
960
961MLPREFIX ??= ""
962MULTILIB_VARIANTS ??= ""
963
964# Older versions of bitbake (< 1.42) don't set BB_UNIHASH. For compatibility with these
965# versions, set BB_UNIHASH equivalent to BB_TASKHASH if unspecified, which is
966# what it would be anyway if the signature generator (e.g. OEEquivHash) doesn't
967# support unihashes.
968BB_UNIHASH ?= "${BB_TASKHASH}"
969