1python multilib_virtclass_handler () {
2    cls = e.data.getVar("BBEXTENDCURR")
3    variant = e.data.getVar("BBEXTENDVARIANT")
4    if cls != "multilib" or not variant:
5        return
6
7    localdata = bb.data.createCopy(e.data)
8    localdata.delVar('TMPDIR')
9    e.data.setVar('STAGING_KERNEL_DIR', localdata.getVar('STAGING_KERNEL_DIR'))
10
11    # There should only be one kernel in multilib configs
12    # We also skip multilib setup for module packages.
13    provides = (e.data.getVar("PROVIDES") or "").split()
14    non_ml_recipes = d.getVar('NON_MULTILIB_RECIPES').split()
15    bpn = e.data.getVar("BPN")
16    if "virtual/kernel" in provides or \
17            bb.data.inherits_class('module-base', e.data) or \
18            bpn in non_ml_recipes:
19        raise bb.parse.SkipRecipe("We shouldn't have multilib variants for %s" % bpn)
20
21    save_var_name=e.data.getVar("MULTILIB_SAVE_VARNAME") or ""
22    for name in save_var_name.split():
23        val=e.data.getVar(name)
24        if val:
25            e.data.setVar(name + "_MULTILIB_ORIGINAL", val)
26
27    overrides = e.data.getVar("OVERRIDES", False)
28    pn = e.data.getVar("PN", False)
29    overrides = overrides.replace("pn-${PN}", "pn-${PN}:pn-" + pn)
30    e.data.setVar("OVERRIDES", overrides)
31
32    if bb.data.inherits_class('image', e.data):
33        e.data.setVar("MLPREFIX", variant + "-")
34        e.data.setVar("PN", variant + "-" + e.data.getVar("PN", False))
35        e.data.setVar('SDKTARGETSYSROOT', e.data.getVar('SDKTARGETSYSROOT'))
36        override = ":virtclass-multilib-" + variant
37        e.data.setVar("OVERRIDES", e.data.getVar("OVERRIDES", False) + override)
38        target_vendor = e.data.getVar("TARGET_VENDOR_" + "virtclass-multilib-" + variant, False)
39        if target_vendor:
40            e.data.setVar("TARGET_VENDOR", target_vendor)
41        return
42
43    if bb.data.inherits_class('cross-canadian', e.data):
44        # Multilib cross-candian should use the same nativesdk sysroot without MLPREFIX
45        e.data.setVar("RECIPE_SYSROOT", "${WORKDIR}/recipe-sysroot")
46        e.data.setVar("STAGING_DIR_TARGET", "${WORKDIR}/recipe-sysroot")
47        e.data.setVar("STAGING_DIR_HOST", "${WORKDIR}/recipe-sysroot")
48        e.data.setVar("MLPREFIX", variant + "-")
49        override = ":virtclass-multilib-" + variant
50        e.data.setVar("OVERRIDES", e.data.getVar("OVERRIDES", False) + override)
51        return
52
53    if bb.data.inherits_class('native', e.data):
54        raise bb.parse.SkipRecipe("We can't extend native recipes")
55
56    if bb.data.inherits_class('nativesdk', e.data) or bb.data.inherits_class('crosssdk', e.data):
57        raise bb.parse.SkipRecipe("We can't extend nativesdk recipes")
58
59    if bb.data.inherits_class('allarch', e.data) and not d.getVar('MULTILIB_VARIANTS') \
60        and not bb.data.inherits_class('packagegroup', e.data):
61        raise bb.parse.SkipRecipe("Don't extend allarch recipes which are not packagegroups")
62
63    # Expand this since this won't work correctly once we set a multilib into place
64    e.data.setVar("ALL_MULTILIB_PACKAGE_ARCHS", e.data.getVar("ALL_MULTILIB_PACKAGE_ARCHS"))
65
66    override = ":virtclass-multilib-" + variant
67
68    blacklist = e.data.getVarFlag('PNBLACKLIST', e.data.getVar('PN'))
69    if blacklist:
70        pn_new = variant + "-" + e.data.getVar('PN')
71        if not e.data.getVarFlag('PNBLACKLIST', pn_new):
72            e.data.setVarFlag('PNBLACKLIST', pn_new, blacklist)
73
74    e.data.setVar("MLPREFIX", variant + "-")
75    e.data.setVar("PN", variant + "-" + e.data.getVar("PN", False))
76    e.data.setVar("OVERRIDES", e.data.getVar("OVERRIDES", False) + override)
77
78    # Expand WHITELIST_GPL-3.0 with multilib prefix
79    pkgs = e.data.getVar("WHITELIST_GPL-3.0")
80    for pkg in pkgs.split():
81        pkgs += " " + variant + "-" + pkg
82    e.data.setVar("WHITELIST_GPL-3.0", pkgs)
83
84    # DEFAULTTUNE can change TARGET_ARCH override so expand this now before update_data
85    newtune = e.data.getVar("DEFAULTTUNE_" + "virtclass-multilib-" + variant, False)
86    if newtune:
87        e.data.setVar("DEFAULTTUNE", newtune)
88}
89
90addhandler multilib_virtclass_handler
91multilib_virtclass_handler[eventmask] = "bb.event.RecipePreFinalise"
92
93python __anonymous () {
94    if bb.data.inherits_class('image', d):
95        variant = d.getVar("BBEXTENDVARIANT")
96        import oe.classextend
97
98        clsextend = oe.classextend.ClassExtender(variant, d)
99
100        clsextend.map_depends_variable("PACKAGE_INSTALL")
101        clsextend.map_depends_variable("LINGUAS_INSTALL")
102        clsextend.map_depends_variable("RDEPENDS")
103        pinstall = d.getVar("LINGUAS_INSTALL") + " " + d.getVar("PACKAGE_INSTALL")
104        d.setVar("PACKAGE_INSTALL", pinstall)
105        d.setVar("LINGUAS_INSTALL", "")
106        # FIXME, we need to map this to something, not delete it!
107        d.setVar("PACKAGE_INSTALL_ATTEMPTONLY", "")
108        bb.build.deltask('do_populate_sdk', d)
109        bb.build.deltask('do_populate_sdk_ext', d)
110        return
111}
112
113python multilib_virtclass_handler_postkeyexp () {
114    cls = d.getVar("BBEXTENDCURR")
115    variant = d.getVar("BBEXTENDVARIANT")
116    if cls != "multilib" or not variant:
117        return
118
119    variant = d.getVar("BBEXTENDVARIANT")
120
121    import oe.classextend
122
123    clsextend = oe.classextend.ClassExtender(variant, d)
124
125    if bb.data.inherits_class('image', d):
126        return
127
128    clsextend.map_depends_variable("DEPENDS")
129    clsextend.map_variable("PROVIDES")
130
131    if bb.data.inherits_class('cross-canadian', d):
132        return
133
134    clsextend.rename_packages()
135    clsextend.rename_package_variables((d.getVar("PACKAGEVARS") or "").split())
136
137    clsextend.map_packagevars()
138    clsextend.map_regexp_variable("PACKAGES_DYNAMIC")
139    clsextend.map_variable("INITSCRIPT_PACKAGES")
140    clsextend.map_variable("USERADD_PACKAGES")
141    clsextend.map_variable("SYSTEMD_PACKAGES")
142    clsextend.map_variable("UPDATERCPN")
143
144    reset_alternative_priority(d)
145}
146
147addhandler multilib_virtclass_handler_postkeyexp
148multilib_virtclass_handler_postkeyexp[eventmask] = "bb.event.RecipePostKeyExpansion"
149
150def reset_alternative_priority(d):
151    if not bb.data.inherits_class('update-alternatives', d):
152        return
153
154    # There might be multiple multilibs at the same time, e.g., lib32 and
155    # lib64, each of them should have a different priority.
156    multilib_variants = d.getVar('MULTILIB_VARIANTS')
157    bbextendvariant = d.getVar('BBEXTENDVARIANT')
158    reset_gap = multilib_variants.split().index(bbextendvariant) + 1
159
160    # ALTERNATIVE_PRIORITY = priority
161    alt_priority_recipe = d.getVar('ALTERNATIVE_PRIORITY')
162    # Reset ALTERNATIVE_PRIORITY when found
163    if alt_priority_recipe:
164        reset_priority = int(alt_priority_recipe) - reset_gap
165        bb.debug(1, '%s: Setting ALTERNATIVE_PRIORITY to %s' % (d.getVar('PN'), reset_priority))
166        d.setVar('ALTERNATIVE_PRIORITY', reset_priority)
167
168    handled_pkgs = []
169    for pkg in (d.getVar('PACKAGES') or "").split():
170        # ALTERNATIVE_PRIORITY_pkg = priority
171        alt_priority_pkg = d.getVar('ALTERNATIVE_PRIORITY_%s' % pkg)
172        # Reset ALTERNATIVE_PRIORITY_pkg when found
173        if alt_priority_pkg:
174            reset_priority = int(alt_priority_pkg) - reset_gap
175            if not pkg in handled_pkgs:
176                handled_pkgs.append(pkg)
177                bb.debug(1, '%s: Setting ALTERNATIVE_PRIORITY_%s to %s' % (pkg, pkg, reset_priority))
178                d.setVar('ALTERNATIVE_PRIORITY_%s' % pkg, reset_priority)
179
180        for alt_name in (d.getVar('ALTERNATIVE_%s' % pkg) or "").split():
181            # ALTERNATIVE_PRIORITY_pkg[tool]  = priority
182            alt_priority_pkg_name = d.getVarFlag('ALTERNATIVE_PRIORITY_%s' % pkg, alt_name)
183            # ALTERNATIVE_PRIORITY[tool] = priority
184            alt_priority_name = d.getVarFlag('ALTERNATIVE_PRIORITY', alt_name)
185
186            if alt_priority_pkg_name:
187                reset_priority = int(alt_priority_pkg_name) - reset_gap
188                bb.debug(1, '%s: Setting ALTERNATIVE_PRIORITY_%s[%s] to %s' % (pkg, pkg, alt_name, reset_priority))
189                d.setVarFlag('ALTERNATIVE_PRIORITY_%s' % pkg, alt_name, reset_priority)
190            elif alt_priority_name:
191                reset_priority = int(alt_priority_name) - reset_gap
192                bb.debug(1, '%s: Setting ALTERNATIVE_PRIORITY[%s] to %s' % (pkg, alt_name, reset_priority))
193                d.setVarFlag('ALTERNATIVE_PRIORITY', alt_name, reset_priority)
194
195PACKAGEFUNCS_append = " do_package_qa_multilib"
196
197python do_package_qa_multilib() {
198
199    def check_mlprefix(pkg, var, mlprefix):
200        values = bb.utils.explode_deps(d.getVar('%s_%s' % (var, pkg)) or d.getVar(var) or "")
201        candidates = []
202        for i in values:
203            if i.startswith('virtual/'):
204                i = i[len('virtual/'):]
205
206            if (not (i.startswith(mlprefix) or i.startswith("kernel-") \
207                    or ('cross-canadian' in i) or i.startswith("nativesdk-") \
208                    or i.startswith("rtld") or i.startswith("/"))):
209                candidates.append(i)
210
211        if len(candidates) > 0:
212            msg = "%s package %s - suspicious values '%s' in %s" \
213                   % (d.getVar('PN'), pkg, ' '.join(candidates), var)
214            package_qa_handle_error("multilib", msg, d)
215
216    ml = d.getVar('MLPREFIX')
217    if not ml:
218        return
219
220    # exception for ${MLPREFIX}target-sdk-provides-dummy
221    if 'target-sdk-provides-dummy' in d.getVar('PN'):
222        return
223
224    packages = d.getVar('PACKAGES')
225    for pkg in packages.split():
226        check_mlprefix(pkg, 'RDEPENDS', ml)
227        check_mlprefix(pkg, 'RPROVIDES', ml)
228        check_mlprefix(pkg, 'RRECOMMENDS', ml)
229        check_mlprefix(pkg, 'RSUGGESTS', ml)
230        check_mlprefix(pkg, 'RREPLACES', ml)
231        check_mlprefix(pkg, 'RCONFLICTS', ml)
232}
233