1python multilib_virtclass_handler () {
2    cls = e.data.getVar("BBEXTENDCURR")
3    variant = e.data.getVar("BBEXTENDVARIANT")
4    if cls != "multilib" or not variant:
5        return
6
7    localdata = bb.data.createCopy(e.data)
8    localdata.delVar('TMPDIR')
9    e.data.setVar('STAGING_KERNEL_DIR', localdata.getVar('STAGING_KERNEL_DIR'))
10
11    # There should only be one kernel in multilib configs
12    # We also skip multilib setup for module packages.
13    provides = (e.data.getVar("PROVIDES") or "").split()
14    non_ml_recipes = d.getVar('NON_MULTILIB_RECIPES').split()
15    bpn = e.data.getVar("BPN")
16    if "virtual/kernel" in provides or \
17            bb.data.inherits_class('module-base', e.data) or \
18            bpn in non_ml_recipes:
19        raise bb.parse.SkipRecipe("We shouldn't have multilib variants for %s" % bpn)
20
21    save_var_name=e.data.getVar("MULTILIB_SAVE_VARNAME") or ""
22    for name in save_var_name.split():
23        val=e.data.getVar(name)
24        if val:
25            e.data.setVar(name + "_MULTILIB_ORIGINAL", val)
26
27    overrides = e.data.getVar("OVERRIDES", False)
28    pn = e.data.getVar("PN", False)
29    overrides = overrides.replace("pn-${PN}", "pn-${PN}:pn-" + pn)
30    e.data.setVar("OVERRIDES", overrides)
31
32    if bb.data.inherits_class('image', e.data):
33        e.data.setVar("MLPREFIX", variant + "-")
34        e.data.setVar("PN", variant + "-" + e.data.getVar("PN", False))
35        e.data.setVar('SDKTARGETSYSROOT', e.data.getVar('SDKTARGETSYSROOT'))
36        override = ":virtclass-multilib-" + variant
37        e.data.setVar("OVERRIDES", e.data.getVar("OVERRIDES", False) + override)
38        target_vendor = e.data.getVar("TARGET_VENDOR_" + "virtclass-multilib-" + variant, False)
39        if target_vendor:
40            e.data.setVar("TARGET_VENDOR", target_vendor)
41        return
42
43    if bb.data.inherits_class('cross-canadian', e.data):
44        # Multilib cross-candian should use the same nativesdk sysroot without MLPREFIX
45        e.data.setVar("RECIPE_SYSROOT", "${WORKDIR}/recipe-sysroot")
46        e.data.setVar("STAGING_DIR_TARGET", "${WORKDIR}/recipe-sysroot")
47        e.data.setVar("STAGING_DIR_HOST", "${WORKDIR}/recipe-sysroot")
48        e.data.setVar("MLPREFIX", variant + "-")
49        override = ":virtclass-multilib-" + variant
50        e.data.setVar("OVERRIDES", e.data.getVar("OVERRIDES", False) + override)
51        return
52
53    if bb.data.inherits_class('native', e.data):
54        raise bb.parse.SkipRecipe("We can't extend native recipes")
55
56    if bb.data.inherits_class('nativesdk', e.data) or bb.data.inherits_class('crosssdk', e.data):
57        raise bb.parse.SkipRecipe("We can't extend nativesdk recipes")
58
59    if bb.data.inherits_class('allarch', e.data) and not d.getVar('MULTILIB_VARIANTS') \
60        and not bb.data.inherits_class('packagegroup', e.data):
61        raise bb.parse.SkipRecipe("Don't extend allarch recipes which are not packagegroups")
62
63    # Expand this since this won't work correctly once we set a multilib into place
64    e.data.setVar("ALL_MULTILIB_PACKAGE_ARCHS", e.data.getVar("ALL_MULTILIB_PACKAGE_ARCHS"))
65
66    override = ":virtclass-multilib-" + variant
67
68    blacklist = e.data.getVarFlag('PNBLACKLIST', e.data.getVar('PN'))
69    if blacklist:
70        pn_new = variant + "-" + e.data.getVar('PN')
71        if not e.data.getVarFlag('PNBLACKLIST', pn_new):
72            e.data.setVarFlag('PNBLACKLIST', pn_new, blacklist)
73
74    e.data.setVar("MLPREFIX", variant + "-")
75    e.data.setVar("PN", variant + "-" + e.data.getVar("PN", False))
76    e.data.setVar("OVERRIDES", e.data.getVar("OVERRIDES", False) + override)
77
78    # Expand WHITELIST_GPL-3.0 with multilib prefix
79    pkgs = e.data.getVar("WHITELIST_GPL-3.0")
80    for pkg in pkgs.split():
81        pkgs += " " + variant + "-" + pkg
82    e.data.setVar("WHITELIST_GPL-3.0", pkgs)
83
84    # DEFAULTTUNE can change TARGET_ARCH override so expand this now before update_data
85    newtune = e.data.getVar("DEFAULTTUNE_" + "virtclass-multilib-" + variant, False)
86    if newtune:
87        e.data.setVar("DEFAULTTUNE", newtune)
88}
89
90addhandler multilib_virtclass_handler
91multilib_virtclass_handler[eventmask] = "bb.event.RecipePreFinalise"
92
93python __anonymous () {
94    variant = d.getVar("BBEXTENDVARIANT")
95
96    import oe.classextend
97
98    clsextend = oe.classextend.ClassExtender(variant, d)
99
100    if bb.data.inherits_class('image', d):
101        clsextend.map_depends_variable("PACKAGE_INSTALL")
102        clsextend.map_depends_variable("LINGUAS_INSTALL")
103        clsextend.map_depends_variable("RDEPENDS")
104        pinstall = d.getVar("LINGUAS_INSTALL") + " " + d.getVar("PACKAGE_INSTALL")
105        d.setVar("PACKAGE_INSTALL", pinstall)
106        d.setVar("LINGUAS_INSTALL", "")
107        # FIXME, we need to map this to something, not delete it!
108        d.setVar("PACKAGE_INSTALL_ATTEMPTONLY", "")
109        bb.build.deltask('do_populate_sdk', d)
110        bb.build.deltask('do_populate_sdk_ext', d)
111        return
112
113    clsextend.map_depends_variable("DEPENDS")
114    clsextend.map_variable("PROVIDES")
115
116    if bb.data.inherits_class('cross-canadian', d):
117        return
118
119    clsextend.rename_packages()
120    clsextend.rename_package_variables((d.getVar("PACKAGEVARS") or "").split())
121
122    clsextend.map_packagevars()
123    clsextend.map_regexp_variable("PACKAGES_DYNAMIC")
124    clsextend.map_variable("INITSCRIPT_PACKAGES")
125    clsextend.map_variable("USERADD_PACKAGES")
126    clsextend.map_variable("SYSTEMD_PACKAGES")
127    clsextend.map_variable("UPDATERCPN")
128}
129
130PACKAGEFUNCS_append = " do_package_qa_multilib"
131
132python do_package_qa_multilib() {
133
134    def check_mlprefix(pkg, var, mlprefix):
135        values = bb.utils.explode_deps(d.getVar('%s_%s' % (var, pkg)) or d.getVar(var) or "")
136        candidates = []
137        for i in values:
138            if i.startswith('virtual/'):
139                i = i[len('virtual/'):]
140            if (not i.startswith('kernel-module')) and (not i.startswith(mlprefix)) and \
141                (not 'cross-canadian' in i) and (not i.startswith("nativesdk-")) and \
142                (not i.startswith("rtld")) and (not i.startswith('kernel-vmlinux')) \
143                and (not i.startswith("kernel-image")):
144                candidates.append(i)
145        if len(candidates) > 0:
146            msg = "%s package %s - suspicious values '%s' in %s" \
147                   % (d.getVar('PN'), pkg, ' '.join(candidates), var)
148            package_qa_handle_error("multilib", msg, d)
149
150    ml = d.getVar('MLPREFIX')
151    if not ml:
152        return
153
154    # exception for ${MLPREFIX}target-sdk-provides-dummy
155    if 'target-sdk-provides-dummy' in d.getVar('PN'):
156        return
157
158    packages = d.getVar('PACKAGES')
159    for pkg in packages.split():
160        check_mlprefix(pkg, 'RDEPENDS', ml)
161        check_mlprefix(pkg, 'RPROVIDES', ml)
162        check_mlprefix(pkg, 'RRECOMMENDS', ml)
163        check_mlprefix(pkg, 'RSUGGESTS', ml)
164        check_mlprefix(pkg, 'RREPLACES', ml)
165        check_mlprefix(pkg, 'RCONFLICTS', ml)
166}
167