1# Copyright (C) 2012 Linux Foundation
2# Author: Richard Purdie
3# Some code and influence taken from srctree.bbclass:
4# Copyright (C) 2009 Chris Larson <clarson@kergoth.com>
5# Released under the MIT license (see COPYING.MIT for the terms)
6#
7# externalsrc.bbclass enables use of an existing source tree, usually external to
8# the build system to build a piece of software rather than the usual fetch/unpack/patch
9# process.
10#
11# To use, add externalsrc to the global inherit and set EXTERNALSRC to point at the
12# directory you want to use containing the sources e.g. from local.conf for a recipe
13# called "myrecipe" you would do:
14#
15# INHERIT += "externalsrc"
16# EXTERNALSRC_pn-myrecipe = "/path/to/my/source/tree"
17#
18# In order to make this class work for both target and native versions (or with
19# multilibs/cross or other BBCLASSEXTEND variants), B is set to point to a separate
20# directory under the work directory (split source and build directories). This is
21# the default, but the build directory can be set to the source directory if
22# circumstances dictate by setting EXTERNALSRC_BUILD to the same value, e.g.:
23#
24# EXTERNALSRC_BUILD_pn-myrecipe = "/path/to/my/source/tree"
25#
26
27SRCTREECOVEREDTASKS ?= "do_patch do_unpack do_fetch"
28EXTERNALSRC_SYMLINKS ?= "oe-workdir:${WORKDIR} oe-logs:${T}"
29
30python () {
31    externalsrc = d.getVar('EXTERNALSRC')
32    externalsrcbuild = d.getVar('EXTERNALSRC_BUILD')
33
34    if externalsrc and not externalsrc.startswith("/"):
35        bb.error("EXTERNALSRC must be an absolute path")
36    if externalsrcbuild and not externalsrcbuild.startswith("/"):
37        bb.error("EXTERNALSRC_BUILD must be an absolute path")
38
39    # If this is the base recipe and EXTERNALSRC is set for it or any of its
40    # derivatives, then enable BB_DONT_CACHE to force the recipe to always be
41    # re-parsed so that the file-checksums function for do_compile is run every
42    # time.
43    bpn = d.getVar('BPN')
44    classextend = (d.getVar('BBCLASSEXTEND') or '').split()
45    if bpn == d.getVar('PN') or not classextend:
46        if (externalsrc or
47                ('native' in classextend and
48                 d.getVar('EXTERNALSRC_pn-%s-native' % bpn)) or
49                ('nativesdk' in classextend and
50                 d.getVar('EXTERNALSRC_pn-nativesdk-%s' % bpn)) or
51                ('cross' in classextend and
52                 d.getVar('EXTERNALSRC_pn-%s-cross' % bpn))):
53            d.setVar('BB_DONT_CACHE', '1')
54
55    if externalsrc:
56        import oe.recipeutils
57        import oe.path
58
59        d.setVar('S', externalsrc)
60        if externalsrcbuild:
61            d.setVar('B', externalsrcbuild)
62        else:
63            d.setVar('B', '${WORKDIR}/${BPN}-${PV}/')
64
65        local_srcuri = []
66        fetch = bb.fetch2.Fetch((d.getVar('SRC_URI') or '').split(), d)
67        for url in fetch.urls:
68            url_data = fetch.ud[url]
69            parm = url_data.parm
70            if (url_data.type == 'file' or
71                    'type' in parm and parm['type'] == 'kmeta'):
72                local_srcuri.append(url)
73
74        d.setVar('SRC_URI', ' '.join(local_srcuri))
75
76        if '{SRCPV}' in d.getVar('PV', False):
77            # Dummy value because the default function can't be called with blank SRC_URI
78            d.setVar('SRCPV', '999')
79
80        if d.getVar('CONFIGUREOPT_DEPTRACK') == '--disable-dependency-tracking':
81            d.setVar('CONFIGUREOPT_DEPTRACK', '')
82
83        tasks = filter(lambda k: d.getVarFlag(k, "task"), d.keys())
84
85        for task in tasks:
86            if task.endswith("_setscene"):
87                # sstate is never going to work for external source trees, disable it
88                bb.build.deltask(task, d)
89            else:
90                # Since configure will likely touch ${S}, ensure only we lock so one task has access at a time
91                d.appendVarFlag(task, "lockfiles", " ${S}/singletask.lock")
92
93            # We do not want our source to be wiped out, ever (kernel.bbclass does this for do_clean)
94            cleandirs = oe.recipeutils.split_var_value(d.getVarFlag(task, 'cleandirs', False) or '')
95            setvalue = False
96            for cleandir in cleandirs[:]:
97                if oe.path.is_path_parent(externalsrc, d.expand(cleandir)):
98                    cleandirs.remove(cleandir)
99                    setvalue = True
100            if setvalue:
101                d.setVarFlag(task, 'cleandirs', ' '.join(cleandirs))
102
103        fetch_tasks = ['do_fetch', 'do_unpack']
104        # If we deltask do_patch, there's no dependency to ensure do_unpack gets run, so add one
105        # Note that we cannot use d.appendVarFlag() here because deps is expected to be a list object, not a string
106        d.setVarFlag('do_configure', 'deps', (d.getVarFlag('do_configure', 'deps', False) or []) + ['do_unpack'])
107
108        for task in d.getVar("SRCTREECOVEREDTASKS").split():
109            if local_srcuri and task in fetch_tasks:
110                continue
111            bb.build.deltask(task, d)
112
113        d.prependVarFlag('do_compile', 'prefuncs', "externalsrc_compile_prefunc ")
114        d.prependVarFlag('do_configure', 'prefuncs', "externalsrc_configure_prefunc ")
115
116        d.setVarFlag('do_compile', 'file-checksums', '${@srctree_hash_files(d)}')
117        d.setVarFlag('do_configure', 'file-checksums', '${@srctree_configure_hash_files(d)}')
118
119        # We don't want the workdir to go away
120        d.appendVar('RM_WORK_EXCLUDE', ' ' + d.getVar('PN'))
121
122        bb.build.addtask('do_buildclean',
123                         'do_clean' if d.getVar('S') == d.getVar('B') else None,
124                         None, d)
125
126        # If B=S the same builddir is used even for different architectures.
127        # Thus, use a shared CONFIGURESTAMPFILE and STAMP directory so that
128        # change of do_configure task hash is correctly detected and stamps are
129        # invalidated if e.g. MACHINE changes.
130        if d.getVar('S') == d.getVar('B'):
131            configstamp = '${TMPDIR}/work-shared/${PN}/${EXTENDPE}${PV}-${PR}/configure.sstate'
132            d.setVar('CONFIGURESTAMPFILE', configstamp)
133            d.setVar('STAMP', '${STAMPS_DIR}/work-shared/${PN}/${EXTENDPE}${PV}-${PR}')
134            d.setVar('STAMPCLEAN', '${STAMPS_DIR}/work-shared/${PN}/*-*')
135}
136
137python externalsrc_configure_prefunc() {
138    s_dir = d.getVar('S')
139    # Create desired symlinks
140    symlinks = (d.getVar('EXTERNALSRC_SYMLINKS') or '').split()
141    newlinks = []
142    for symlink in symlinks:
143        symsplit = symlink.split(':', 1)
144        lnkfile = os.path.join(s_dir, symsplit[0])
145        target = d.expand(symsplit[1])
146        if len(symsplit) > 1:
147            if os.path.islink(lnkfile):
148                # Link already exists, leave it if it points to the right location already
149                if os.readlink(lnkfile) == target:
150                    continue
151                os.unlink(lnkfile)
152            elif os.path.exists(lnkfile):
153                # File/dir exists with same name as link, just leave it alone
154                continue
155            os.symlink(target, lnkfile)
156            newlinks.append(symsplit[0])
157    # Hide the symlinks from git
158    try:
159        git_exclude_file = os.path.join(s_dir, '.git/info/exclude')
160        if os.path.exists(git_exclude_file):
161            with open(git_exclude_file, 'r+') as efile:
162                elines = efile.readlines()
163                for link in newlinks:
164                    if link in elines or '/'+link in elines:
165                        continue
166                    efile.write('/' + link + '\n')
167    except IOError as ioe:
168        bb.note('Failed to hide EXTERNALSRC_SYMLINKS from git')
169}
170
171python externalsrc_compile_prefunc() {
172    # Make it obvious that this is happening, since forgetting about it could lead to much confusion
173    bb.plain('NOTE: %s: compiling from external source tree %s' % (d.getVar('PN'), d.getVar('EXTERNALSRC')))
174}
175
176do_buildclean[dirs] = "${S} ${B}"
177do_buildclean[nostamp] = "1"
178do_buildclean[doc] = "Call 'make clean' or equivalent in ${B}"
179externalsrc_do_buildclean() {
180	if [ -e Makefile -o -e makefile -o -e GNUmakefile ]; then
181		rm -f ${@' '.join([x.split(':')[0] for x in (d.getVar('EXTERNALSRC_SYMLINKS') or '').split()])}
182		if [ "${CLEANBROKEN}" != "1" ]; then
183			oe_runmake clean || die "make failed"
184		fi
185	else
186		bbnote "nothing to do - no makefile found"
187	fi
188}
189
190def srctree_hash_files(d, srcdir=None):
191    import shutil
192    import subprocess
193    import tempfile
194
195    s_dir = srcdir or d.getVar('EXTERNALSRC')
196    git_dir = None
197
198    try:
199        git_dir = os.path.join(s_dir,
200            subprocess.check_output(['git', '-C', s_dir, 'rev-parse', '--git-dir'], stderr=subprocess.DEVNULL).decode("utf-8").rstrip())
201    except subprocess.CalledProcessError:
202        pass
203
204    ret = " "
205    if git_dir is not None:
206        oe_hash_file = os.path.join(git_dir, 'oe-devtool-tree-sha1')
207        with tempfile.NamedTemporaryFile(prefix='oe-devtool-index') as tmp_index:
208            # Clone index
209            shutil.copyfile(os.path.join(git_dir, 'index'), tmp_index.name)
210            # Update our custom index
211            env = os.environ.copy()
212            env['GIT_INDEX_FILE'] = tmp_index.name
213            subprocess.check_output(['git', 'add', '-A', '.'], cwd=s_dir, env=env)
214            sha1 = subprocess.check_output(['git', 'write-tree'], cwd=s_dir, env=env).decode("utf-8")
215        with open(oe_hash_file, 'w') as fobj:
216            fobj.write(sha1)
217        ret = oe_hash_file + ':True'
218    else:
219        ret = s_dir + '/*:True'
220    return ret
221
222def srctree_configure_hash_files(d):
223    """
224    Get the list of files that should trigger do_configure to re-execute,
225    based on the value of CONFIGURE_FILES
226    """
227    in_files = (d.getVar('CONFIGURE_FILES') or '').split()
228    out_items = []
229    search_files = []
230    for entry in in_files:
231        if entry.startswith('/'):
232            out_items.append('%s:%s' % (entry, os.path.exists(entry)))
233        else:
234            search_files.append(entry)
235    if search_files:
236        s_dir = d.getVar('EXTERNALSRC')
237        for root, _, files in os.walk(s_dir):
238            for f in files:
239                if f in search_files:
240                    out_items.append('%s:True' % os.path.join(root, f))
241    return ' '.join(out_items)
242
243EXPORT_FUNCTIONS do_buildclean
244