1SUMMARY = "The eCryptfs mount helper and support libraries"
2DESCRIPTION = "eCryptfs is a stacked cryptographic filesystem \
3    that ships in Linux kernel versions 2.6.19 and above. This \
4    package provides the mount helper and supporting libraries \
5    to perform key management and mount functions."
6HOMEPAGE = "https://launchpad.net/ecryptfs"
7SECTION = "base"
8
9LICENSE = "GPL-2.0-only"
10LIC_FILES_CHKSUM = "file://COPYING;md5=8ca43cbc842c2336e835926c2166c28b"
11
12DEPENDS = "keyutils libgcrypt intltool-native glib-2.0-native"
13
14SRC_URI = "\
15    https://launchpad.net/ecryptfs/trunk/${PV}/+download/${BPN}_${PV}.orig.tar.gz \
16    file://ecryptfs-utils-CVE-2016-6224.patch \
17    file://0001-avoid-race-condition.patch \
18    file://ecryptfs.service \
19    file://define_musl_sword_type.patch \
20    "
21
22SRC_URI[md5sum] = "83513228984f671930752c3518cac6fd"
23SRC_URI[sha256sum] = "112cb3e37e81a1ecd8e39516725dec0ce55c5f3df6284e0f4cc0f118750a987f"
24
25UPSTREAM_CHECK_URI = "https://launchpad.net/ecryptfs/+download"
26
27inherit autotools pkgconfig systemd
28
29SYSTEMD_PACKAGES = "${PN}"
30SYSTEMD_SERVICE:${PN} = "ecryptfs.service"
31
32EXTRA_OECONF = "\
33    --libdir=${base_libdir} \
34    --disable-pywrap \
35    --disable-nls \
36    --with-pamdir=${base_libdir}/security \
37    --disable-openssl \
38    "
39
40PACKAGECONFIG ??= "nss \
41    ${@bb.utils.filter('DISTRO_FEATURES', 'pam', d)} \
42    "
43PACKAGECONFIG[nss] = "--enable-nss,--disable-nss,nss,"
44PACKAGECONFIG[pam] = "--enable-pam,--disable-pam,libpam,"
45
46do_configure:prepend() {
47    export NSS_CFLAGS="-I${STAGING_INCDIR}/nspr -I${STAGING_INCDIR}/nss3"
48    export NSS_LIBS="-L${STAGING_BASELIBDIR} -lssl3 -lsmime3 -lnss3 -lsoftokn3 -lnssutil3"
49    export KEYUTILS_CFLAGS="-I${STAGING_INCDIR}"
50    export KEYUTILS_LIBS="-L${STAGING_LIBDIR} -lkeyutils"
51    sed -i -e "s;rootsbindir=\"/sbin\";rootsbindir=\"\${base_sbindir}\";g" ${S}/configure.ac
52}
53
54do_install:append() {
55    chmod 4755 ${D}${base_sbindir}/mount.ecryptfs_private
56    # ${base_libdir} is identical to ${libdir} when usrmerge enabled
57    if ! ${@bb.utils.contains('DISTRO_FEATURES','usrmerge','true','false',d)}; then
58        mkdir -p ${D}/${libdir}
59        mv ${D}/${base_libdir}/pkgconfig ${D}/${libdir}
60    fi
61    sed -i -e 's:-I${STAGING_INCDIR}::' \
62           -e 's:-L${STAGING_LIBDIR}::' ${D}/${libdir}/pkgconfig/libecryptfs.pc
63    sed -i -e "s: ${base_sbindir}/cryptsetup: ${sbindir}/cryptsetup:" ${D}${bindir}/ecryptfs-setup-swap
64    if ${@bb.utils.contains('DISTRO_FEATURES','systemd','true','false',d)}; then
65        install -D -m 0644 ${WORKDIR}/ecryptfs.service ${D}${systemd_system_unitdir}/ecryptfs.service
66    fi
67}
68
69FILES:${PN} += "${base_libdir}/security/* ${base_libdir}/ecryptfs/*"
70
71RDEPENDS:${PN} += "cryptsetup"
72RRECOMMENDS:${PN} = "gettext-runtime"
73