1SUMMARY = "TCTI module for use with TSS2 libraries in UEFI environment"
2SECTION = "security/tpm"
3LICENSE = "BSD-2-Clause"
4LIC_FILES_CHKSUM = "file://LICENSE;md5=500b2e742befc3da00684d8a1d5fd9da"
5DEPENDS = "libtss2-dev libtss2-mu-dev gnu-efi-native gnu-efi pkgconfig autoconf-archive-native"
6
7SRC_URI = "git://github.com/tpm2-software/tpm2-tcti-uefi.git;branch=master;protocol=https \
8           file://configure_oe_fixup.patch \
9           file://0001-configure.ac-stop-inserting-host-directories-into-co.patch \
10           file://fix_header_file.patch \
11"
12
13SRCREV = "0241b08f069f0fdb3612f5c1b938144dbe9be811"
14
15UPSTREAM_CHECK_URI = "https://github.com/tpm2-software/${BPN}/releases"
16
17S = "${WORKDIR}/git"
18
19inherit autotools pkgconfig
20
21EFIDIR ?= "/EFI/BOOT"
22
23EFI_ARCH:x86 = "ia32"
24EFI_ARCH:x86-64 = "x86_64"
25
26CFLAGS:append = " -I${STAGING_INCDIR}/efi -I${STAGING_INCDIR}/efi/${EFI_ARCH}"
27
28EXTRA_OECONF:append = " \
29    --with-efi-includedir=${STAGING_INCDIR} \
30    --with-efi-crt0=${STAGING_LIBDIR}/crt0-efi-${EFI_ARCH}.o \
31    --with-efi-lds=${STAGING_LIBDIR}/elf_${EFI_ARCH}_efi.lds \
32"
33
34do_compile:append() {
35	oe_runmake example
36}
37
38do_install:append() {
39	install -d "${D}${EFIDIR}"
40	install -m 0755 "${B}"/example/*.efi "${D}${EFIDIR}"
41}
42
43COMPATIBLE_HOST = "(i.86|x86_64).*-linux"
44
45FILES:${PN} += "${EFIDIR}"
46
47RDEPENDS:${PN} = "gnu-efi libtss2-mu"
48