1DESCRIPTION = "Graphics libraries for BCM2835."
2LICENSE = "Proprietary"
3
4LIC_FILES_CHKSUM = "file://LICENCE;md5=86e53f5f5909ee66900418028de11780"
5
6PROVIDES = "virtual/libgles2 virtual/egl"
7COMPATIBLE_MACHINE = "^rpi$"
8
9INHIBIT_DEFAULT_DEPS = "1"
10
11include recipes-bsp/common/firmware.inc
12
13SRC_URI += " \
14    file://egl.pc \
15    file://vchiq.sh \
16"
17
18S = "${RPIFW_S}/${VCDIR}"
19
20INCPR = "r1"
21
22inherit pkgconfig update-rc.d
23
24do_install () {
25  install -d ${D}${bindir}
26  cp -R bin/* ${D}${bindir}
27
28  install -d ${D}${sbindir}
29  cp -R sbin/* ${D}${sbindir}
30
31  install -d ${D}${libdir}
32  # note: -H option to deref symlinked .so
33  cp -R -H lib/* ${D}${libdir}
34
35  install -d ${D}${includedir}
36  cp -R include/* ${D}${includedir}
37
38  install -d ${D}${libdir}/pkgconfig
39  install -m 0644 ${WORKDIR}/egl.pc ${D}${libdir}/pkgconfig/
40
41  install -d ${D}/${sysconfdir}/init.d
42  install -m 0755 ${WORKDIR}/vchiq.sh ${D}${sysconfdir}/init.d/
43}
44
45# These are proprietary binaries generated elsewhere so don't check ldflags
46INSANE_SKIP_${PN} = "ldflags"
47
48INITSCRIPT_NAME = "vchiq.sh"
49INITSCRIPT_PARAMS = "start 03 S ."
50
51FILES_${PN} = "${bindir}/* \
52               ${sbindir}/* \
53               ${libdir}/lib*.so \
54               ${sysconfdir}/init.d \
55               ${libdir}/plugins"
56FILES_${PN}-dev = "${libdir}/pkgconfig \
57                   ${includedir}"
58FILES_${PN}-dbg += "${libdir}/plugins/.debug"
59