1DESCRIPTION = "Commented config.txt file for the Raspberry Pi. \
2               The Raspberry Pi config.txt file is read by the GPU before \
3               the ARM core is initialised. It can be used to set various \
4               system configuration parameters."
5LICENSE = "MIT"
6LIC_FILES_CHKSUM = "file://${COMMON_LICENSE_DIR}/MIT;md5=0835ade698e0bcf8506ecda2f7b4f302"
7
8COMPATIBLE_MACHINE = "^rpi$"
9
10SRCREV = "648ffc470824c43eb0d16c485f4c24816b32cd6f"
11SRC_URI = "git://github.com/Evilpaul/RPi-config.git;protocol=git;branch=master \
12          "
13
14S = "${WORKDIR}/git"
15
16PR = "r5"
17
18INHIBIT_DEFAULT_DEPS = "1"
19
20PITFT="${@bb.utils.contains("MACHINE_FEATURES", "pitft", "1", "0", d)}"
21PITFT22="${@bb.utils.contains("MACHINE_FEATURES", "pitft22", "1", "0", d)}"
22PITFT28r="${@bb.utils.contains("MACHINE_FEATURES", "pitft28r", "1", "0", d)}"
23PITFT28c="${@bb.utils.contains("MACHINE_FEATURES", "pitft28c", "1", "0", d)}"
24PITFT35r="${@bb.utils.contains("MACHINE_FEATURES", "pitft35r", "1", "0", d)}"
25
26VC4GRAPHICS="${@bb.utils.contains("MACHINE_FEATURES", "vc4graphics", "1", "0", d)}"
27VC4DTBO ?= "vc4-kms-v3d"
28GPIO_IR ?= "18"
29GPIO_IR_TX ?= "17"
30
31CAN_OSCILLATOR ?= "16000000"
32
33WM8960="${@bb.utils.contains("MACHINE_FEATURES", "wm8960", "1", "0", d)}"
34
35inherit deploy nopackages
36
37do_deploy() {
38    install -d ${DEPLOYDIR}/${BOOTFILES_DIR_NAME}
39    CONFIG=${DEPLOYDIR}/${BOOTFILES_DIR_NAME}/config.txt
40
41    cp ${S}/config.txt $CONFIG
42
43    if [ -n "${KEY_DECODE_MPG2}" ]; then
44        sed -i '/#decode_MPG2=/ c\decode_MPG2=${KEY_DECODE_MPG2}' $CONFIG
45    fi
46    if [ -n "${KEY_DECODE_WVC1}" ]; then
47        sed -i '/#decode_WVC1=/ c\decode_WVC1=${KEY_DECODE_WVC1}' $CONFIG
48    fi
49    if [ -n "${DISABLE_OVERSCAN}" ]; then
50        sed -i '/#disable_overscan=/ c\disable_overscan=${DISABLE_OVERSCAN}' $CONFIG
51    fi
52    if [ "${DISABLE_SPLASH}" = "1" ]; then
53        sed -i '/#disable_splash=/ c\disable_splash=${DISABLE_SPLASH}' $CONFIG
54    fi
55
56    # Set overclocking options
57    if [ -n "${ARM_FREQ}" ]; then
58        sed -i '/#arm_freq=/ c\arm_freq=${ARM_FREQ}' $CONFIG
59    fi
60    if [ -n "${GPU_FREQ}" ]; then
61        sed -i '/#gpu_freq=/ c\gpu_freq=${GPU_FREQ}' $CONFIG
62    fi
63    if [ -n "${CORE_FREQ}" ]; then
64        sed -i '/#core_freq=/ c\core_freq=${CORE_FREQ}' $CONFIG
65    fi
66    if [ -n "${SDRAM_FREQ}" ]; then
67        sed -i '/#sdram_freq=/ c\sdram_freq=${SDRAM_FREQ}' $CONFIG
68    fi
69    if [ -n "${OVER_VOLTAGE}" ]; then
70        sed -i '/#over_voltage=/ c\over_voltage=${OVER_VOLTAGE}' $CONFIG
71    fi
72
73    # GPU memory
74    if [ -n "${GPU_MEM}" ]; then
75        sed -i '/#gpu_mem=/ c\gpu_mem=${GPU_MEM}' $CONFIG
76    fi
77    if [ -n "${GPU_MEM_256}" ]; then
78        sed -i '/#gpu_mem_256=/ c\gpu_mem_256=${GPU_MEM_256}' $CONFIG
79    fi
80    if [ -n "${GPU_MEM_512}" ]; then
81        sed -i '/#gpu_mem_512=/ c\gpu_mem_512=${GPU_MEM_512}' $CONFIG
82    fi
83    if [ -n "${GPU_MEM_1024}" ]; then
84        sed -i '/#gpu_mem_1024=/ c\gpu_mem_1024=${GPU_MEM_1024}' $CONFIG
85    fi
86
87    # Set boot delay
88    if [ -n "${BOOT_DELAY}" ]; then
89        sed -i '/#boot_delay=/ c\boot_delay=${BOOT_DELAY}' $CONFIG
90    fi
91    if [ -n "${BOOT_DELAY_MS}" ]; then
92        sed -i '/#boot_delay_ms=/ c\boot_delay_ms=${BOOT_DELAY_MS}' $CONFIG
93    fi
94
95    # Set HDMI and composite video options
96    if [ -n "${HDMI_FORCE_HOTPLUG}" ]; then
97        sed -i '/#hdmi_force_hotplug=/ c\hdmi_force_hotplug=${HDMI_FORCE_HOTPLUG}' $CONFIG
98    fi
99    if [ -n "${HDMI_DRIVE}" ]; then
100        sed -i '/#hdmi_drive=/ c\hdmi_drive=${HDMI_DRIVE}' $CONFIG
101    fi
102    if [ -n "${HDMI_GROUP}" ]; then
103        sed -i '/#hdmi_group=/ c\hdmi_group=${HDMI_GROUP}' $CONFIG
104    fi
105    if [ -n "${HDMI_MODE}" ]; then
106        sed -i '/#hdmi_mode=/ c\hdmi_mode=${HDMI_MODE}' $CONFIG
107    fi
108    if [ -n "${HDMI_CVT}" ]; then
109        echo 'hdmi_cvt=${HDMI_CVT}' >> $CONFIG
110    fi
111    if [ -n "${CONFIG_HDMI_BOOST}" ]; then
112        sed -i '/#config_hdmi_boost=/ c\config_hdmi_boost=${CONFIG_HDMI_BOOST}' $CONFIG
113    fi
114    if [ -n "${SDTV_MODE}" ]; then
115        sed -i '/#sdtv_mode=/ c\sdtv_mode=${SDTV_MODE}' $CONFIG
116    fi
117    if [ -n "${SDTV_ASPECT}" ]; then
118        sed -i '/#sdtv_aspect=/ c\sdtv_aspect=${SDTV_ASPECT}' $CONFIG
119    fi
120    if [ -n "${DISPLAY_ROTATE}" ]; then
121        sed -i '/#display_rotate=/ c\display_rotate=${DISPLAY_ROTATE}' $CONFIG
122    fi
123
124    # Video camera support
125    if [ "${VIDEO_CAMERA}" = "1" ]; then
126        #   It has been observed that Raspberry Pi 4B 4GB may fail to enable the
127        # camera if "start_x=1" is at the end of the file. Therefore,
128        # "start_x=1" has been set to replace the original occurrence in
129        # config.txt, which is at the middle of the file.
130        #   The exact underlying cause is unknown. There are similar issues
131        # reported in the raspberrypi/firware repo and the conclusion reached
132        # was that there could be a file size limitation affecting certain
133        # variables. It was commented that this limitation could be 4k but
134        # not proved.
135        sed -i '/#start_x=/ c\start_x=1' $CONFIG
136    fi
137
138    # Offline compositing support
139    if [ "${DISPMANX_OFFLINE}" = "1" ]; then
140        echo "# Enable offline compositing" >>$CONFIG
141        echo "dispmanx_offline=1" >>$CONFIG
142    fi
143
144    # SPI bus support
145    if [ "${ENABLE_SPI_BUS}" = "1" ] || [ "${PITFT}" = "1" ]; then
146        echo "# Enable SPI bus" >>$CONFIG
147        echo "dtparam=spi=on" >>$CONFIG
148    fi
149
150    # I2C support
151    if [ "${ENABLE_I2C}" = "1" ] || [ "${PITFT}" = "1" ]; then
152        echo "# Enable I2C" >>$CONFIG
153        echo "dtparam=i2c1=on" >>$CONFIG
154        echo "dtparam=i2c_arm=on" >>$CONFIG
155    fi
156
157    # PiTFT22 display support
158    if [ "${PITFT22}" = "1" ]; then
159        echo "# Enable PITFT22 display" >>$CONFIG
160        echo "dtoverlay=pitft22,rotate=270,speed=32000000,txbuflen=32768" >>$CONFIG
161    fi
162    if [ "${PITFT28r}" = "1" ]; then
163        echo "# Enable PITFT28r display" >>$CONFIG
164        echo "dtoverlay=pitft28-resistive,rotate=90,speed=32000000,txbuflen=32768" >>$CONFIG
165    fi
166    if [ "${PITFT28c}" = "1" ]; then
167        echo "# Enable PITFT28c display" >>$CONFIG
168        echo "dtoverlay=pitft28-capacitive,rotate=90,speed=32000000,txbuflen=32768" >>$CONFIG
169        echo "dtoverlay=pitft28-capacitive,touch-swapxy,touch-invx" >>$CONFIG
170    fi
171    if [ "${PITFT35r}" = "1" ]; then
172        echo "# Enable PITFT35r display" >>$CONFIG
173        echo "dtoverlay=pitft35-resistive,rotate=90,speed=42000000,fps=20" >>$CONFIG
174    fi
175
176    # UART support
177    if [ "${ENABLE_UART}" = "1" ]; then
178        echo "# Enable UART" >>$CONFIG
179        echo "enable_uart=1" >>$CONFIG
180    fi
181
182    # Infrared support
183    if [ "${ENABLE_IR}" = "1" ]; then
184        echo "# Enable infrared" >>$CONFIG
185        echo "dtoverlay=gpio-ir,gpio_pin=${GPIO_IR}" >>$CONFIG
186        echo "dtoverlay=gpio-ir-tx,gpio_pin=${GPIO_IR_TX}" >>$CONFIG
187    fi
188
189    # VC4 Graphics support
190    if [ "${VC4GRAPHICS}" = "1" ]; then
191        echo "# Enable VC4 Graphics" >> $CONFIG
192        echo "dtoverlay=${VC4DTBO}" >> $CONFIG
193    fi
194
195    # Choose Camera Sensor to be used, default imx219 sensor
196    if [ "${RASPBERRYPI_CAMERA_V2}" = "1" ]; then
197        echo "# Enable Sony RaspberryPi Camera(imx219)" >> $CONFIG
198        echo "dtoverlay=imx219" >> $CONFIG
199    fi
200
201    # Choose Camera Sensor to be used, default imx477 sensor
202    #if [ "${RASPBERRYPI_HD_CAMERA}" = "1" ]; then
203    #    echo "# Enable Sony RaspberryPi Camera(imx477)" >> $CONFIG
204    #    echo "dtoverlay=imx477" >> $CONFIG
205    #fi
206
207    # Waveshare "C" 1024x600 7" Rev2.1 IPS capacitive touch (http://www.waveshare.com/7inch-HDMI-LCD-C.htm)
208    if [ "${WAVESHARE_1024X600_C_2_1}" = "1" ]; then
209        echo "# Waveshare \"C\" 1024x600 7\" Rev2.1 IPS capacitive touch screen" >> $CONFIG
210        echo "max_usb_current=1" >> $CONFIG
211        echo "hdmi_group=2" >> $CONFIG
212        echo "hdmi_mode=87" >> $CONFIG
213        echo "hdmi_cvt 1024 600 60 6 0 0 0" >> $CONFIG
214        echo "hdmi_drive=1" >> $CONFIG
215    fi
216
217    # DWC2 USB peripheral support
218    if [ "${ENABLE_DWC2_PERIPHERAL}" = "1" ]; then
219        echo "# Enable USB peripheral mode" >> $CONFIG
220        echo "dtoverlay=dwc2,dr_mode=peripheral" >> $CONFIG
221    fi
222
223    # DWC2 USB host mode support
224    if [ "${ENABLE_DWC2_HOST}" = "1" ]; then
225        echo "# Enable USB host mode" >> $CONFIG
226        echo "dtoverlay=dwc2,dr_mode=host" >> $CONFIG
227    fi
228
229    # AT86RF23X support
230    if [ "${ENABLE_AT86RF}" = "1" ]; then
231        echo "# Enable AT86RF23X" >>$CONFIG
232        echo "dtoverlay=at86rf233,speed=3000000" >>$CONFIG
233    fi
234
235    # ENABLE DUAL CAN
236    if [ "${ENABLE_DUAL_CAN}" = "1" ]; then
237        echo "# Enable DUAL CAN" >>$CONFIG
238        echo "dtoverlay=mcp2515-can0,oscillator=${CAN_OSCILLATOR},interrupt=25" >>$CONFIG
239        echo "dtoverlay=mcp2515-can1,oscillator=${CAN_OSCILLATOR},interrupt=24" >>$CONFIG
240    # ENABLE CAN
241    elif [ "${ENABLE_CAN}" = "1" ]; then
242        echo "# Enable CAN" >>$CONFIG
243        echo "dtoverlay=mcp2515-can0,oscillator=${CAN_OSCILLATOR},interrupt=25" >>$CONFIG
244    fi
245
246    # Append extra config if the user has provided any
247    printf "${RPI_EXTRA_CONFIG}\n" >> $CONFIG
248
249    # Handle setup with armstub file
250    if [ "${@bb.utils.contains("MACHINE_FEATURES", "armstub", "1", "0", d)}" = "1" ]; then
251        echo "\n# ARM stub configuration" >> $CONFIG
252        echo "armstub=${ARMSTUB}" >> $CONFIG
253        case "${ARMSTUB}" in
254            *-gic.bin)
255                echo  "enable_gic=1" >> $CONFIG
256                ;;
257        esac
258    fi
259
260    # WM8960 support
261    if [ "${WM8960}" = "1" ]; then
262        echo "# Enable WM8960" >> $CONFIG
263        echo "dtoverlay=wm8960-soundcard" >> $CONFIG
264    fi
265}
266
267do_deploy:append:raspberrypi3-64() {
268    echo "# have a properly sized image" >> $CONFIG
269    echo "disable_overscan=1" >> $CONFIG
270
271    echo "# Enable audio (loads snd_bcm2835)" >> $CONFIG
272    echo "dtparam=audio=on" >> $CONFIG
273}
274
275addtask deploy before do_build after do_install
276do_deploy[dirs] += "${DEPLOYDIR}/${BOOTFILES_DIR_NAME}"
277
278PACKAGE_ARCH = "${MACHINE_ARCH}"
279