1DESCRIPTION = "Commented config.txt file for the Raspberry Pi. \
2               The Raspberry Pi config.txt file is read by the GPU before \
3               the ARM core is initialised. It can be used to set various \
4               system configuration parameters."
5LICENSE = "MIT"
6LIC_FILES_CHKSUM = "file://${COMMON_LICENSE_DIR}/MIT;md5=0835ade698e0bcf8506ecda2f7b4f302"
7
8COMPATIBLE_MACHINE = "^rpi$"
9
10SRCREV = "648ffc470824c43eb0d16c485f4c24816b32cd6f"
11SRC_URI = "git://github.com/Evilpaul/RPi-config.git;protocol=https;branch=master \
12          "
13
14S = "${WORKDIR}/git"
15
16PR = "r5"
17
18INHIBIT_DEFAULT_DEPS = "1"
19
20PITFT="${@bb.utils.contains("MACHINE_FEATURES", "pitft", "1", "0", d)}"
21PITFT22="${@bb.utils.contains("MACHINE_FEATURES", "pitft22", "1", "0", d)}"
22PITFT28r="${@bb.utils.contains("MACHINE_FEATURES", "pitft28r", "1", "0", d)}"
23PITFT28c="${@bb.utils.contains("MACHINE_FEATURES", "pitft28c", "1", "0", d)}"
24PITFT35r="${@bb.utils.contains("MACHINE_FEATURES", "pitft35r", "1", "0", d)}"
25
26VC4GRAPHICS="${@bb.utils.contains("MACHINE_FEATURES", "vc4graphics", "1", "0", d)}"
27VC4DTBO ?= "vc4-kms-v3d"
28GPIO_IR ?= "18"
29GPIO_IR_TX ?= "17"
30
31CAN_OSCILLATOR ?= "16000000"
32
33ENABLE_UART ??= ""
34
35WM8960="${@bb.utils.contains("MACHINE_FEATURES", "wm8960", "1", "0", d)}"
36
37GPIO_SHUTDOWN_PIN ??= ""
38
39inherit deploy nopackages
40
41do_deploy() {
42    install -d ${DEPLOYDIR}/${BOOTFILES_DIR_NAME}
43    CONFIG=${DEPLOYDIR}/${BOOTFILES_DIR_NAME}/config.txt
44
45    cp ${S}/config.txt $CONFIG
46
47    if [ -n "${KEY_DECODE_MPG2}" ]; then
48        sed -i '/#decode_MPG2=/ c\decode_MPG2=${KEY_DECODE_MPG2}' $CONFIG
49    fi
50    if [ -n "${KEY_DECODE_WVC1}" ]; then
51        sed -i '/#decode_WVC1=/ c\decode_WVC1=${KEY_DECODE_WVC1}' $CONFIG
52    fi
53    if [ -n "${DISABLE_OVERSCAN}" ]; then
54        sed -i '/#disable_overscan=/ c\disable_overscan=${DISABLE_OVERSCAN}' $CONFIG
55    fi
56    if [ "${DISABLE_SPLASH}" = "1" ]; then
57        sed -i '/#disable_splash=/ c\disable_splash=${DISABLE_SPLASH}' $CONFIG
58    fi
59
60    # Set overclocking options
61    if [ -n "${ARM_FREQ}" ]; then
62        sed -i '/#arm_freq=/ c\arm_freq=${ARM_FREQ}' $CONFIG
63    fi
64    if [ -n "${GPU_FREQ}" ]; then
65        sed -i '/#gpu_freq=/ c\gpu_freq=${GPU_FREQ}' $CONFIG
66    fi
67    if [ -n "${CORE_FREQ}" ]; then
68        sed -i '/#core_freq=/ c\core_freq=${CORE_FREQ}' $CONFIG
69    fi
70    if [ -n "${SDRAM_FREQ}" ]; then
71        sed -i '/#sdram_freq=/ c\sdram_freq=${SDRAM_FREQ}' $CONFIG
72    fi
73    if [ -n "${OVER_VOLTAGE}" ]; then
74        sed -i '/#over_voltage=/ c\over_voltage=${OVER_VOLTAGE}' $CONFIG
75    fi
76
77    # GPU memory
78    if [ -n "${GPU_MEM}" ]; then
79        sed -i '/#gpu_mem=/ c\gpu_mem=${GPU_MEM}' $CONFIG
80    fi
81    if [ -n "${GPU_MEM_256}" ]; then
82        sed -i '/#gpu_mem_256=/ c\gpu_mem_256=${GPU_MEM_256}' $CONFIG
83    fi
84    if [ -n "${GPU_MEM_512}" ]; then
85        sed -i '/#gpu_mem_512=/ c\gpu_mem_512=${GPU_MEM_512}' $CONFIG
86    fi
87    if [ -n "${GPU_MEM_1024}" ]; then
88        sed -i '/#gpu_mem_1024=/ c\gpu_mem_1024=${GPU_MEM_1024}' $CONFIG
89    fi
90
91    # Set boot delay
92    if [ -n "${BOOT_DELAY}" ]; then
93        sed -i '/#boot_delay=/ c\boot_delay=${BOOT_DELAY}' $CONFIG
94    fi
95    if [ -n "${BOOT_DELAY_MS}" ]; then
96        sed -i '/#boot_delay_ms=/ c\boot_delay_ms=${BOOT_DELAY_MS}' $CONFIG
97    fi
98
99    # Set HDMI and composite video options
100    if [ -n "${HDMI_FORCE_HOTPLUG}" ]; then
101        sed -i '/#hdmi_force_hotplug=/ c\hdmi_force_hotplug=${HDMI_FORCE_HOTPLUG}' $CONFIG
102    fi
103    if [ -n "${HDMI_DRIVE}" ]; then
104        sed -i '/#hdmi_drive=/ c\hdmi_drive=${HDMI_DRIVE}' $CONFIG
105    fi
106    if [ -n "${HDMI_GROUP}" ]; then
107        sed -i '/#hdmi_group=/ c\hdmi_group=${HDMI_GROUP}' $CONFIG
108    fi
109    if [ -n "${HDMI_MODE}" ]; then
110        sed -i '/#hdmi_mode=/ c\hdmi_mode=${HDMI_MODE}' $CONFIG
111    fi
112    if [ -n "${HDMI_CVT}" ]; then
113        echo 'hdmi_cvt=${HDMI_CVT}' >> $CONFIG
114    fi
115    if [ -n "${CONFIG_HDMI_BOOST}" ]; then
116        sed -i '/#config_hdmi_boost=/ c\config_hdmi_boost=${CONFIG_HDMI_BOOST}' $CONFIG
117    fi
118    if [ -n "${SDTV_MODE}" ]; then
119        sed -i '/#sdtv_mode=/ c\sdtv_mode=${SDTV_MODE}' $CONFIG
120    fi
121    if [ -n "${SDTV_ASPECT}" ]; then
122        sed -i '/#sdtv_aspect=/ c\sdtv_aspect=${SDTV_ASPECT}' $CONFIG
123    fi
124    if [ -n "${DISPLAY_ROTATE}" ]; then
125        sed -i '/#display_rotate=/ c\display_rotate=${DISPLAY_ROTATE}' $CONFIG
126    fi
127
128    # Video camera support
129    if [ "${VIDEO_CAMERA}" = "1" ]; then
130        #   It has been observed that Raspberry Pi 4B 4GB may fail to enable the
131        # camera if "start_x=1" is at the end of the file. Therefore,
132        # "start_x=1" has been set to replace the original occurrence in
133        # config.txt, which is at the middle of the file.
134        #   The exact underlying cause is unknown. There are similar issues
135        # reported in the raspberrypi/firware repo and the conclusion reached
136        # was that there could be a file size limitation affecting certain
137        # variables. It was commented that this limitation could be 4k but
138        # not proved.
139        sed -i '/#start_x=/ c\start_x=1' $CONFIG
140    fi
141
142    # Offline compositing support
143    if [ "${DISPMANX_OFFLINE}" = "1" ]; then
144        echo "# Enable offline compositing" >>$CONFIG
145        echo "dispmanx_offline=1" >>$CONFIG
146    fi
147
148    # SPI bus support
149    if [ "${ENABLE_SPI_BUS}" = "1" ] || [ "${PITFT}" = "1" ]; then
150        echo "# Enable SPI bus" >>$CONFIG
151        echo "dtparam=spi=on" >>$CONFIG
152    fi
153
154    # I2C support
155    if [ "${ENABLE_I2C}" = "1" ] || [ "${PITFT}" = "1" ]; then
156        echo "# Enable I2C" >>$CONFIG
157        echo "dtparam=i2c1=on" >>$CONFIG
158        echo "dtparam=i2c_arm=on" >>$CONFIG
159    fi
160
161    # PiTFT22 display support
162    if [ "${PITFT22}" = "1" ]; then
163        echo "# Enable PITFT22 display" >>$CONFIG
164        echo "dtoverlay=pitft22,rotate=270,speed=32000000,txbuflen=32768" >>$CONFIG
165    fi
166    if [ "${PITFT28r}" = "1" ]; then
167        echo "# Enable PITFT28r display" >>$CONFIG
168        echo "dtoverlay=pitft28-resistive,rotate=90,speed=32000000,txbuflen=32768" >>$CONFIG
169    fi
170    if [ "${PITFT28c}" = "1" ]; then
171        echo "# Enable PITFT28c display" >>$CONFIG
172        echo "dtoverlay=pitft28-capacitive,rotate=90,speed=32000000,txbuflen=32768" >>$CONFIG
173        echo "dtoverlay=pitft28-capacitive,touch-swapxy,touch-invx" >>$CONFIG
174    fi
175    if [ "${PITFT35r}" = "1" ]; then
176        echo "# Enable PITFT35r display" >>$CONFIG
177        echo "dtoverlay=pitft35-resistive,rotate=90,speed=42000000,fps=20" >>$CONFIG
178    fi
179
180    # UART support
181    if [ "${ENABLE_UART}" = "1" ] || [ "${ENABLE_UART}" = "0" ] ; then
182        echo "# Enable UART" >>$CONFIG
183        echo "enable_uart=${ENABLE_UART}" >>$CONFIG
184    elif [ -n "${ENABLE_UART}" ]; then
185        bbfatal "Invalid value for ENABLE_UART [${ENABLE_UART}]. The value for ENABLE_UART can be 0 or 1."
186    fi
187
188    # Infrared support
189    if [ "${ENABLE_IR}" = "1" ]; then
190        echo "# Enable infrared" >>$CONFIG
191        echo "dtoverlay=gpio-ir,gpio_pin=${GPIO_IR}" >>$CONFIG
192        echo "dtoverlay=gpio-ir-tx,gpio_pin=${GPIO_IR_TX}" >>$CONFIG
193    fi
194
195    # VC4 Graphics support
196    if [ "${VC4GRAPHICS}" = "1" ]; then
197        echo "# Enable VC4 Graphics" >> $CONFIG
198        echo "dtoverlay=${VC4DTBO}" >> $CONFIG
199    fi
200
201    # Choose Camera Sensor to be used, default imx219 sensor
202    if [ "${RASPBERRYPI_CAMERA_V2}" = "1" ]; then
203        echo "# Enable Sony RaspberryPi Camera(imx219)" >> $CONFIG
204        echo "dtoverlay=imx219" >> $CONFIG
205    fi
206
207    # Choose Camera Sensor to be used, default imx477 sensor
208    #if [ "${RASPBERRYPI_HD_CAMERA}" = "1" ]; then
209    #    echo "# Enable Sony RaspberryPi Camera(imx477)" >> $CONFIG
210    #    echo "dtoverlay=imx477" >> $CONFIG
211    #fi
212
213    # Waveshare "C" 1024x600 7" Rev2.1 IPS capacitive touch (http://www.waveshare.com/7inch-HDMI-LCD-C.htm)
214    if [ "${WAVESHARE_1024X600_C_2_1}" = "1" ]; then
215        echo "# Waveshare \"C\" 1024x600 7\" Rev2.1 IPS capacitive touch screen" >> $CONFIG
216        echo "max_usb_current=1" >> $CONFIG
217        echo "hdmi_group=2" >> $CONFIG
218        echo "hdmi_mode=87" >> $CONFIG
219        echo "hdmi_cvt 1024 600 60 6 0 0 0" >> $CONFIG
220        echo "hdmi_drive=1" >> $CONFIG
221    fi
222
223    # DWC2 USB peripheral support
224    if ([ "${ENABLE_DWC2_PERIPHERAL}" = "1" ] && [ "${ENABLE_DWC2_OTG}" != "1" ]); then
225        echo "# Enable USB peripheral mode" >> $CONFIG
226        echo "dtoverlay=dwc2,dr_mode=peripheral" >> $CONFIG
227    fi
228
229    # DWC2 USB host mode support
230    if [ "${ENABLE_DWC2_HOST}" = "1" ]; then
231        echo "# Enable USB host mode" >> $CONFIG
232        echo "dtoverlay=dwc2,dr_mode=host" >> $CONFIG
233    fi
234
235    # DWC2 USB OTG support
236    if ([ "${ENABLE_DWC2_OTG}" = "1" ] && [ "${ENABLE_DWC2_PERIPHERAL}" != "1" ]); then
237        echo "# Enable USB OTG mode" >> $CONFIG
238        echo "dtoverlay=dwc2,dr_mode=otg" >> $CONFIG
239    fi
240
241    # AT86RF23X support
242    if [ "${ENABLE_AT86RF}" = "1" ]; then
243        echo "# Enable AT86RF23X" >>$CONFIG
244        echo "dtoverlay=at86rf233,speed=3000000" >>$CONFIG
245    fi
246
247    # ENABLE DUAL CAN
248    if [ "${ENABLE_DUAL_CAN}" = "1" ]; then
249        echo "# Enable DUAL CAN" >>$CONFIG
250        echo "dtoverlay=mcp2515-can0,oscillator=${CAN_OSCILLATOR},interrupt=25" >>$CONFIG
251        echo "dtoverlay=mcp2515-can1,oscillator=${CAN_OSCILLATOR},interrupt=24" >>$CONFIG
252    # ENABLE CAN
253    elif [ "${ENABLE_CAN}" = "1" ]; then
254        echo "# Enable CAN" >>$CONFIG
255        echo "dtoverlay=mcp2515-can0,oscillator=${CAN_OSCILLATOR},interrupt=25" >>$CONFIG
256    fi
257
258
259    if [ "${ENABLE_GPIO_SHUTDOWN}" = "1" ]; then
260        if ([ "${ENABLE_I2C}" = "1" ] || [ "${PITFT}" = "1" ]) && [ -z "${GPIO_SHUTDOWN_PIN}" ]; then
261            # By default GPIO shutdown uses the same pin as the (master) I2C SCL.
262            # If I2C is configured and an alternative pin is not configured for
263            # gpio-shutdown, there is a configuration conflict.
264            bbfatal "I2C and gpio-shutdown are both enabled and using the same pins!"
265        fi
266        echo "# Enable gpio-shutdown" >> $CONFIG
267        if [ -z "${GPIO_SHUTDOWN_PIN}" ]; then
268            echo "dtoverlay=gpio-shutdown" >> $CONFIG
269        else
270            echo "dtoverlay=gpio-shutdown,gpio_pin=${GPIO_SHUTDOWN_PIN}" >> $CONFIG
271        fi
272    fi
273
274    # Append extra config if the user has provided any
275    printf "${RPI_EXTRA_CONFIG}\n" >> $CONFIG
276
277    # Handle setup with armstub file
278    if [ "${@bb.utils.contains("MACHINE_FEATURES", "armstub", "1", "0", d)}" = "1" ]; then
279        echo "\n# ARM stub configuration" >> $CONFIG
280        echo "armstub=${ARMSTUB}" >> $CONFIG
281        case "${ARMSTUB}" in
282            *-gic.bin)
283                echo  "enable_gic=1" >> $CONFIG
284                ;;
285        esac
286    fi
287
288    # WM8960 support
289    if [ "${WM8960}" = "1" ]; then
290        echo "# Enable WM8960" >> $CONFIG
291        echo "dtoverlay=wm8960-soundcard" >> $CONFIG
292    fi
293}
294
295do_deploy:append:raspberrypi3-64() {
296    echo "# have a properly sized image" >> $CONFIG
297    echo "disable_overscan=1" >> $CONFIG
298
299    echo "# Enable audio (loads snd_bcm2835)" >> $CONFIG
300    echo "dtparam=audio=on" >> $CONFIG
301}
302
303do_deploy:append() {
304    if grep -q -E '^.{80}.$' ${DEPLOYDIR}/${BOOTFILES_DIR_NAME}/config.txt; then
305        bbwarn "config.txt contains lines longer than 80 characters, this is not supported"
306    fi
307}
308
309addtask deploy before do_build after do_install
310do_deploy[dirs] += "${DEPLOYDIR}/${BOOTFILES_DIR_NAME}"
311
312PACKAGE_ARCH = "${MACHINE_ARCH}"
313