1inherit image_types
2
3#
4# Create an image that can be written onto a SD card using dd.
5#
6# The disk layout used is:
7#
8#    0                      -> IMAGE_ROOTFS_ALIGNMENT         - reserved for other data
9#    IMAGE_ROOTFS_ALIGNMENT -> BOOT_SPACE                     - bootloader and kernel
10#    BOOT_SPACE             -> SDIMG_SIZE                     - rootfs
11#
12
13#                                                     Default Free space = 1.3x
14#                                                     Use IMAGE_OVERHEAD_FACTOR to add more space
15#                                                     <--------->
16#            4MiB              48MiB           SDIMG_ROOTFS
17# <-----------------------> <----------> <---------------------->
18#  ------------------------ ------------ ------------------------
19# | IMAGE_ROOTFS_ALIGNMENT | BOOT_SPACE | ROOTFS_SIZE            |
20#  ------------------------ ------------ ------------------------
21# ^                        ^            ^                        ^
22# |                        |            |                        |
23# 0                      4MiB     4MiB + 48MiB       4MiB + 48Mib + SDIMG_ROOTFS
24
25# This image depends on the rootfs image
26IMAGE_TYPEDEP:rpi-sdimg = "${SDIMG_ROOTFS_TYPE}"
27
28# Kernel image name
29SDIMG_KERNELIMAGE:raspberrypi  ?= "kernel.img"
30SDIMG_KERNELIMAGE:raspberrypi2 ?= "kernel7.img"
31SDIMG_KERNELIMAGE:raspberrypi3-64 ?= "kernel8.img"
32
33# Boot partition volume id
34# Shorten raspberrypi to just rpi to keep it under 11 characters
35# now enforced by mkfs.vfat from dosfstools-4.2
36BOOTDD_VOLUME_ID ?= "${@d.getVar('MACHINE').replace('raspberrypi', 'rpi')}"
37
38# Boot partition size [in KiB] (will be rounded up to IMAGE_ROOTFS_ALIGNMENT)
39BOOT_SPACE ?= "49152"
40
41# Set alignment to 4MB [in KiB]
42IMAGE_ROOTFS_ALIGNMENT = "4096"
43
44# Use an uncompressed ext3 by default as rootfs
45SDIMG_ROOTFS_TYPE ?= "ext3"
46SDIMG_ROOTFS = "${IMGDEPLOYDIR}/${IMAGE_LINK_NAME}.${SDIMG_ROOTFS_TYPE}"
47
48# For the names of kernel artifacts
49inherit kernel-artifact-names
50
51RPI_SDIMG_EXTRA_DEPENDS ?= ""
52
53do_image_rpi_sdimg[depends] = " \
54    parted-native:do_populate_sysroot \
55    mtools-native:do_populate_sysroot \
56    dosfstools-native:do_populate_sysroot \
57    virtual/kernel:do_deploy \
58    rpi-bootfiles:do_deploy \
59    ${@bb.utils.contains('MACHINE_FEATURES', 'armstub', 'armstubs:do_deploy', '' ,d)} \
60    ${@bb.utils.contains('RPI_USE_U_BOOT', '1', 'u-boot:do_deploy', '',d)} \
61    ${@bb.utils.contains('RPI_USE_U_BOOT', '1', 'u-boot-default-script:do_deploy', '',d)} \
62    ${RPI_SDIMG_EXTRA_DEPENDS} \
63"
64
65do_image_rpi_sdimg[recrdeps] = "do_build"
66
67# SD card image name
68SDIMG = "${IMGDEPLOYDIR}/${IMAGE_NAME}${IMAGE_NAME_SUFFIX}.rpi-sdimg"
69
70# Additional files and/or directories to be copied into the vfat partition from the IMAGE_ROOTFS.
71FATPAYLOAD ?= ""
72
73# SD card vfat partition image name
74SDIMG_VFAT_DEPLOY ?= "${RPI_USE_U_BOOT}"
75SDIMG_VFAT = "${IMAGE_NAME}.vfat"
76SDIMG_LINK_VFAT = "${IMGDEPLOYDIR}/${IMAGE_LINK_NAME}.vfat"
77
78IMAGE_CMD:rpi-sdimg () {
79
80    # Align partitions
81    BOOT_SPACE_ALIGNED=$(expr ${BOOT_SPACE} + ${IMAGE_ROOTFS_ALIGNMENT} - 1)
82    BOOT_SPACE_ALIGNED=$(expr ${BOOT_SPACE_ALIGNED} - ${BOOT_SPACE_ALIGNED} % ${IMAGE_ROOTFS_ALIGNMENT})
83    SDIMG_SIZE=$(expr ${IMAGE_ROOTFS_ALIGNMENT} + ${BOOT_SPACE_ALIGNED} + $ROOTFS_SIZE)
84
85    echo "Creating filesystem with Boot partition ${BOOT_SPACE_ALIGNED} KiB and RootFS $ROOTFS_SIZE KiB"
86
87    # Check if we are building with device tree support
88    DTS="${@make_dtb_boot_files(d)}"
89
90    # Initialize sdcard image file
91    dd if=/dev/zero of=${SDIMG} bs=1024 count=0 seek=${SDIMG_SIZE}
92
93    # Create partition table
94    parted -s ${SDIMG} mklabel msdos
95    # Create boot partition and mark it as bootable
96    parted -s ${SDIMG} unit KiB mkpart primary fat32 ${IMAGE_ROOTFS_ALIGNMENT} $(expr ${BOOT_SPACE_ALIGNED} \+ ${IMAGE_ROOTFS_ALIGNMENT})
97    parted -s ${SDIMG} set 1 boot on
98    # Create rootfs partition to the end of disk
99    parted -s ${SDIMG} -- unit KiB mkpart primary ext2 $(expr ${BOOT_SPACE_ALIGNED} \+ ${IMAGE_ROOTFS_ALIGNMENT}) -1s
100    parted ${SDIMG} print
101
102    # Create a vfat image with boot files
103    BOOT_BLOCKS=$(LC_ALL=C parted -s ${SDIMG} unit b print | awk '/ 1 / { print substr($4, 1, length($4 -1)) / 512 /2 }')
104    rm -f ${WORKDIR}/boot.img
105    mkfs.vfat -F32 -n "${BOOTDD_VOLUME_ID}" -S 512 -C ${WORKDIR}/boot.img $BOOT_BLOCKS
106    mcopy -v -i ${WORKDIR}/boot.img -s ${DEPLOY_DIR_IMAGE}/${BOOTFILES_DIR_NAME}/* ::/ || bbfatal "mcopy cannot copy ${DEPLOY_DIR_IMAGE}/${BOOTFILES_DIR_NAME}/* into boot.img"
107    if [ "${@bb.utils.contains("MACHINE_FEATURES", "armstub", "1", "0", d)}" = "1" ]; then
108        mcopy -v -i ${WORKDIR}/boot.img -s ${DEPLOY_DIR_IMAGE}/armstubs/${ARMSTUB} ::/ || bbfatal "mcopy cannot copy ${DEPLOY_DIR_IMAGE}/armstubs/${ARMSTUB} into boot.img"
109    fi
110    if test -n "${DTS}"; then
111        # Copy board device trees (including overlays)
112        # There is an assumption here - no DTB in other directories than root
113        # and root/overlays. mmd/mcopy are not very flexible tools.
114        mmd -i ${WORKDIR}/boot.img overlays
115        for entry in ${DTS} ; do
116            # Split entry at optional ';'
117            if [ $(echo "$entry" | grep -c \;) = "0" ] ; then
118                DEPLOY_FILE="$entry"
119                DEST_FILENAME="$entry"
120            else
121                DEPLOY_FILE="$(echo "$entry" | cut -f1 -d\;)"
122                DEST_FILENAME="$(echo "$entry" | cut -f2- -d\;)"
123            fi
124            mcopy -v -i ${WORKDIR}/boot.img -s ${DEPLOY_DIR_IMAGE}/${DEPLOY_FILE} ::${DEST_FILENAME} || bbfatal "mcopy cannot copy ${DEPLOY_DIR_IMAGE}/${DEPLOY_FILE} into boot.img"
125        done
126    fi
127    if [ "${RPI_USE_U_BOOT}" = "1" ]; then
128        mcopy -v -i ${WORKDIR}/boot.img -s ${DEPLOY_DIR_IMAGE}/u-boot.bin ::${SDIMG_KERNELIMAGE} || bbfatal "mcopy cannot copy ${DEPLOY_DIR_IMAGE}/u-boot.bin into boot.img"
129        mcopy -v -i ${WORKDIR}/boot.img -s ${DEPLOY_DIR_IMAGE}/boot.scr ::boot.scr || bbfatal "mcopy cannot copy ${DEPLOY_DIR_IMAGE}/boot.scr into boot.img"
130        if [ ! -z "${INITRAMFS_IMAGE}" -a "${INITRAMFS_IMAGE_BUNDLE}" = "1" ]; then
131            mcopy -v -i ${WORKDIR}/boot.img -s ${DEPLOY_DIR_IMAGE}/${KERNEL_IMAGETYPE}-${INITRAMFS_LINK_NAME}.bin ::${KERNEL_IMAGETYPE} || bbfatal "mcopy cannot copy ${DEPLOY_DIR_IMAGE}/${KERNEL_IMAGETYPE}-${INITRAMFS_LINK_NAME}.bin into boot.img"
132        else
133            mcopy -v -i ${WORKDIR}/boot.img -s ${DEPLOY_DIR_IMAGE}/${KERNEL_IMAGETYPE} ::${KERNEL_IMAGETYPE} || bbfatal "mcopy cannot copy ${DEPLOY_DIR_IMAGE}/${KERNEL_IMAGETYPE} into boot.img"
134        fi
135    else
136        if [ ! -z "${INITRAMFS_IMAGE}" -a "${INITRAMFS_IMAGE_BUNDLE}" = "1" ]; then
137            mcopy -v -i ${WORKDIR}/boot.img -s ${DEPLOY_DIR_IMAGE}/${KERNEL_IMAGETYPE}-${INITRAMFS_LINK_NAME}.bin ::${SDIMG_KERNELIMAGE} || bbfatal "mcopy cannot copy ${DEPLOY_DIR_IMAGE}/${KERNEL_IMAGETYPE}-${INITRAMFS_LINK_NAME}.bin into boot.img"
138        else
139            mcopy -v -i ${WORKDIR}/boot.img -s ${DEPLOY_DIR_IMAGE}/${KERNEL_IMAGETYPE} ::${SDIMG_KERNELIMAGE} || bbfatal "mcopy cannot copy ${DEPLOY_DIR_IMAGE}/${KERNEL_IMAGETYPE} into boot.img"
140        fi
141    fi
142
143    # Add files (eg. hypervisor binaries) from the deploy dir
144    if [ -n "${DEPLOYPAYLOAD}" ] ; then
145        echo "Copying deploy file payload into VFAT"
146        for entry in ${DEPLOYPAYLOAD} ; do
147            # Split entry at optional ':' to enable file renaming for the destination
148            if [ $(echo "$entry" | grep -c :) = "0" ] ; then
149                DEPLOY_FILE="$entry"
150                DEST_FILENAME="$entry"
151            else
152                DEPLOY_FILE="$(echo "$entry" | cut -f1 -d:)"
153                DEST_FILENAME="$(echo "$entry" | cut -f2- -d:)"
154            fi
155            mcopy -v -i ${WORKDIR}/boot.img -s ${DEPLOY_DIR_IMAGE}/${DEPLOY_FILE} ::${DEST_FILENAME} || bbfatal "mcopy cannot copy ${DEPLOY_DIR_IMAGE}/${DEPLOY_FILE} into boot.img"
156        done
157    fi
158
159    if [ -n "${FATPAYLOAD}" ] ; then
160        echo "Copying payload into VFAT"
161        for entry in ${FATPAYLOAD} ; do
162            # use bbwarn instead of bbfatal to stop aborting on vfat issues like not supporting .~lock files
163            mcopy -v -i ${WORKDIR}/boot.img -s ${IMAGE_ROOTFS}$entry :: || bbwarn "mcopy cannot copy ${IMAGE_ROOTFS}$entry into boot.img"
164        done
165    fi
166
167    # Add stamp file
168    echo "${IMAGE_NAME}" > ${WORKDIR}/image-version-info
169    mcopy -v -i ${WORKDIR}/boot.img ${WORKDIR}/image-version-info :: || bbfatal "mcopy cannot copy ${WORKDIR}/image-version-info into boot.img"
170
171    # Deploy vfat partition
172    if [ "${SDIMG_VFAT_DEPLOY}" = "1" ]; then
173        cp ${WORKDIR}/boot.img ${IMGDEPLOYDIR}/${SDIMG_VFAT}
174        ln -sf ${SDIMG_VFAT} ${SDIMG_LINK_VFAT}
175    fi
176
177    # Burn Partitions
178    dd if=${WORKDIR}/boot.img of=${SDIMG} conv=notrunc seek=1 bs=$(expr ${IMAGE_ROOTFS_ALIGNMENT} \* 1024)
179    # If SDIMG_ROOTFS_TYPE is a .xz file use xzcat
180    if echo "${SDIMG_ROOTFS_TYPE}" | egrep -q "*\.xz"
181    then
182        xzcat ${SDIMG_ROOTFS} | dd of=${SDIMG} conv=notrunc seek=1 bs=$(expr 1024 \* ${BOOT_SPACE_ALIGNED} + ${IMAGE_ROOTFS_ALIGNMENT} \* 1024)
183    else
184        dd if=${SDIMG_ROOTFS} of=${SDIMG} conv=notrunc seek=1 bs=$(expr 1024 \* ${BOOT_SPACE_ALIGNED} + ${IMAGE_ROOTFS_ALIGNMENT} \* 1024)
185    fi
186}
187
188ROOTFS_POSTPROCESS_COMMAND += " rpi_generate_sysctl_config ; "
189
190rpi_generate_sysctl_config() {
191    # systemd sysctl config
192    test -d ${IMAGE_ROOTFS}${sysconfdir}/sysctl.d && \
193        echo "vm.min_free_kbytes = 8192" > ${IMAGE_ROOTFS}${sysconfdir}/sysctl.d/rpi-vm.conf
194
195    # sysv sysctl config
196    IMAGE_SYSCTL_CONF="${IMAGE_ROOTFS}${sysconfdir}/sysctl.conf"
197    test -e ${IMAGE_ROOTFS}${sysconfdir}/sysctl.conf && \
198        sed -e "/vm.min_free_kbytes/d" -i ${IMAGE_SYSCTL_CONF}
199    echo "" >> ${IMAGE_SYSCTL_CONF} && echo "vm.min_free_kbytes = 8192" >> ${IMAGE_SYSCTL_CONF}
200}
201