1inherit image_types
2
3#
4# Create an image that can be written onto a SD card using dd.
5#
6# The disk layout used is:
7#
8#    0                      -> IMAGE_ROOTFS_ALIGNMENT         - reserved for other data
9#    IMAGE_ROOTFS_ALIGNMENT -> BOOT_SPACE                     - bootloader and kernel
10#    BOOT_SPACE             -> SDIMG_SIZE                     - rootfs
11#
12
13#                                                     Default Free space = 1.3x
14#                                                     Use IMAGE_OVERHEAD_FACTOR to add more space
15#                                                     <--------->
16#            4MiB              48MiB           SDIMG_ROOTFS
17# <-----------------------> <----------> <---------------------->
18#  ------------------------ ------------ ------------------------
19# | IMAGE_ROOTFS_ALIGNMENT | BOOT_SPACE | ROOTFS_SIZE            |
20#  ------------------------ ------------ ------------------------
21# ^                        ^            ^                        ^
22# |                        |            |                        |
23# 0                      4MiB     4MiB + 48MiB       4MiB + 48Mib + SDIMG_ROOTFS
24
25# This image depends on the rootfs image
26IMAGE_TYPEDEP:rpi-sdimg = "${SDIMG_ROOTFS_TYPE}"
27
28# Kernel image name
29SDIMG_KERNELIMAGE:raspberrypi  ?= "kernel.img"
30SDIMG_KERNELIMAGE:raspberrypi2 ?= "kernel7.img"
31SDIMG_KERNELIMAGE:raspberrypi3-64 ?= "kernel8.img"
32
33# Boot partition volume id
34# Shorten raspberrypi to just rpi to keep it under 11 characters
35# now enforced by mkfs.vfat from dosfstools-4.2
36BOOTDD_VOLUME_ID ?= "${@d.getVar('MACHINE').replace('raspberrypi', 'rpi')}"
37
38# Boot partition size [in KiB] (will be rounded up to IMAGE_ROOTFS_ALIGNMENT)
39BOOT_SPACE ?= "49152"
40
41# Set alignment to 4MB [in KiB]
42IMAGE_ROOTFS_ALIGNMENT = "4096"
43
44# Use an uncompressed ext3 by default as rootfs
45SDIMG_ROOTFS_TYPE ?= "ext3"
46SDIMG_ROOTFS = "${IMGDEPLOYDIR}/${IMAGE_LINK_NAME}.${SDIMG_ROOTFS_TYPE}"
47
48# For the names of kernel artifacts
49inherit kernel-artifact-names
50
51RPI_SDIMG_EXTRA_DEPENDS ?= ""
52
53do_image_rpi_sdimg[depends] = " \
54    parted-native:do_populate_sysroot \
55    mtools-native:do_populate_sysroot \
56    dosfstools-native:do_populate_sysroot \
57    virtual/kernel:do_deploy \
58    rpi-bootfiles:do_deploy \
59    ${@bb.utils.contains('MACHINE_FEATURES', 'armstub', 'armstubs:do_deploy', '' ,d)} \
60    ${@bb.utils.contains('RPI_USE_U_BOOT', '1', 'u-boot:do_deploy', '',d)} \
61    ${@bb.utils.contains('RPI_USE_U_BOOT', '1', 'u-boot-default-script:do_deploy', '',d)} \
62    ${RPI_SDIMG_EXTRA_DEPENDS} \
63"
64
65do_image_rpi_sdimg[recrdeps] = "do_build"
66
67# SD card image name
68SDIMG = "${IMGDEPLOYDIR}/${IMAGE_NAME}${IMAGE_NAME_SUFFIX}.rpi-sdimg"
69
70# Additional files and/or directories to be copied into the vfat partition from the IMAGE_ROOTFS.
71FATPAYLOAD ?= ""
72
73# SD card vfat partition image name
74SDIMG_VFAT_DEPLOY ?= "${RPI_USE_U_BOOT}"
75SDIMG_VFAT = "${IMAGE_NAME}.vfat"
76SDIMG_LINK_VFAT = "${IMGDEPLOYDIR}/${IMAGE_LINK_NAME}.vfat"
77
78def split_overlays(d, out, ver=None):
79    dts = d.getVar("KERNEL_DEVICETREE")
80    # Device Tree Overlays are assumed to be suffixed by '-overlay.dtb' (4.1.x) or by '.dtbo' (4.4.9+) string and will be put in a dedicated folder
81    if out:
82        overlays = oe.utils.str_filter_out('\S+\-overlay\.dtb$', dts, d)
83        overlays = oe.utils.str_filter_out('\S+\.dtbo$', overlays, d)
84    else:
85        overlays = oe.utils.str_filter('\S+\-overlay\.dtb$', dts, d) + \
86                   " " + oe.utils.str_filter('\S+\.dtbo$', dts, d)
87
88    return overlays
89
90IMAGE_CMD:rpi-sdimg () {
91
92    # Align partitions
93    BOOT_SPACE_ALIGNED=$(expr ${BOOT_SPACE} + ${IMAGE_ROOTFS_ALIGNMENT} - 1)
94    BOOT_SPACE_ALIGNED=$(expr ${BOOT_SPACE_ALIGNED} - ${BOOT_SPACE_ALIGNED} % ${IMAGE_ROOTFS_ALIGNMENT})
95    SDIMG_SIZE=$(expr ${IMAGE_ROOTFS_ALIGNMENT} + ${BOOT_SPACE_ALIGNED} + $ROOTFS_SIZE)
96
97    echo "Creating filesystem with Boot partition ${BOOT_SPACE_ALIGNED} KiB and RootFS $ROOTFS_SIZE KiB"
98
99    # Check if we are building with device tree support
100    DTS="${KERNEL_DEVICETREE}"
101
102    # Initialize sdcard image file
103    dd if=/dev/zero of=${SDIMG} bs=1024 count=0 seek=${SDIMG_SIZE}
104
105    # Create partition table
106    parted -s ${SDIMG} mklabel msdos
107    # Create boot partition and mark it as bootable
108    parted -s ${SDIMG} unit KiB mkpart primary fat32 ${IMAGE_ROOTFS_ALIGNMENT} $(expr ${BOOT_SPACE_ALIGNED} \+ ${IMAGE_ROOTFS_ALIGNMENT})
109    parted -s ${SDIMG} set 1 boot on
110    # Create rootfs partition to the end of disk
111    parted -s ${SDIMG} -- unit KiB mkpart primary ext2 $(expr ${BOOT_SPACE_ALIGNED} \+ ${IMAGE_ROOTFS_ALIGNMENT}) -1s
112    parted ${SDIMG} print
113
114    # Create a vfat image with boot files
115    BOOT_BLOCKS=$(LC_ALL=C parted -s ${SDIMG} unit b print | awk '/ 1 / { print substr($4, 1, length($4 -1)) / 512 /2 }')
116    rm -f ${WORKDIR}/boot.img
117    mkfs.vfat -F32 -n "${BOOTDD_VOLUME_ID}" -S 512 -C ${WORKDIR}/boot.img $BOOT_BLOCKS
118    mcopy -v -i ${WORKDIR}/boot.img -s ${DEPLOY_DIR_IMAGE}/${BOOTFILES_DIR_NAME}/* ::/ || bbfatal "mcopy cannot copy ${DEPLOY_DIR_IMAGE}/${BOOTFILES_DIR_NAME}/* into boot.img"
119    if [ "${@bb.utils.contains("MACHINE_FEATURES", "armstub", "1", "0", d)}" = "1" ]; then
120        mcopy -v -i ${WORKDIR}/boot.img -s ${DEPLOY_DIR_IMAGE}/armstubs/${ARMSTUB} ::/ || bbfatal "mcopy cannot copy ${DEPLOY_DIR_IMAGE}/armstubs/${ARMSTUB} into boot.img"
121    fi
122    if test -n "${DTS}"; then
123        # Copy board device trees to root folder
124        for dtbf in ${@split_overlays(d, True)}; do
125            dtb=`basename $dtbf`
126            mcopy -v -i ${WORKDIR}/boot.img -s ${DEPLOY_DIR_IMAGE}/$dtb ::$dtb || bbfatal "mcopy cannot copy ${DEPLOY_DIR_IMAGE}/$dtb into boot.img"
127        done
128
129        # Copy device tree overlays to dedicated folder
130        mmd -i ${WORKDIR}/boot.img overlays
131        for dtbf in ${@split_overlays(d, False)}; do
132            dtb=`basename $dtbf`
133            mcopy -v -i ${WORKDIR}/boot.img -s ${DEPLOY_DIR_IMAGE}/$dtb ::overlays/$dtb || bbfatal "mcopy cannot copy ${DEPLOY_DIR_IMAGE}/$dtb into boot.img"
134        done
135    fi
136    if [ "${RPI_USE_U_BOOT}" = "1" ]; then
137        mcopy -v -i ${WORKDIR}/boot.img -s ${DEPLOY_DIR_IMAGE}/u-boot.bin ::${SDIMG_KERNELIMAGE} || bbfatal "mcopy cannot copy ${DEPLOY_DIR_IMAGE}/u-boot.bin into boot.img"
138        mcopy -v -i ${WORKDIR}/boot.img -s ${DEPLOY_DIR_IMAGE}/boot.scr ::boot.scr || bbfatal "mcopy cannot copy ${DEPLOY_DIR_IMAGE}/boot.scr into boot.img"
139        if [ ! -z "${INITRAMFS_IMAGE}" -a "${INITRAMFS_IMAGE_BUNDLE}" = "1" ]; then
140            mcopy -v -i ${WORKDIR}/boot.img -s ${DEPLOY_DIR_IMAGE}/${KERNEL_IMAGETYPE}-${INITRAMFS_LINK_NAME}.bin ::${KERNEL_IMAGETYPE} || bbfatal "mcopy cannot copy ${DEPLOY_DIR_IMAGE}/${KERNEL_IMAGETYPE}-${INITRAMFS_LINK_NAME}.bin into boot.img"
141        else
142            mcopy -v -i ${WORKDIR}/boot.img -s ${DEPLOY_DIR_IMAGE}/${KERNEL_IMAGETYPE} ::${KERNEL_IMAGETYPE} || bbfatal "mcopy cannot copy ${DEPLOY_DIR_IMAGE}/${KERNEL_IMAGETYPE} into boot.img"
143        fi
144    else
145        if [ ! -z "${INITRAMFS_IMAGE}" -a "${INITRAMFS_IMAGE_BUNDLE}" = "1" ]; then
146            mcopy -v -i ${WORKDIR}/boot.img -s ${DEPLOY_DIR_IMAGE}/${KERNEL_IMAGETYPE}-${INITRAMFS_LINK_NAME}.bin ::${SDIMG_KERNELIMAGE} || bbfatal "mcopy cannot copy ${DEPLOY_DIR_IMAGE}/${KERNEL_IMAGETYPE}-${INITRAMFS_LINK_NAME}.bin into boot.img"
147        else
148            mcopy -v -i ${WORKDIR}/boot.img -s ${DEPLOY_DIR_IMAGE}/${KERNEL_IMAGETYPE} ::${SDIMG_KERNELIMAGE} || bbfatal "mcopy cannot copy ${DEPLOY_DIR_IMAGE}/${KERNEL_IMAGETYPE} into boot.img"
149        fi
150    fi
151
152    # Add files (eg. hypervisor binaries) from the deploy dir
153    if [ -n "${DEPLOYPAYLOAD}" ] ; then
154        echo "Copying deploy file payload into VFAT"
155        for entry in ${DEPLOYPAYLOAD} ; do
156            # Split entry at optional ':' to enable file renaming for the destination
157            if [ $(echo "$entry" | grep -c :) = "0" ] ; then
158                DEPLOY_FILE="$entry"
159                DEST_FILENAME="$entry"
160            else
161                DEPLOY_FILE="$(echo "$entry" | cut -f1 -d:)"
162                DEST_FILENAME="$(echo "$entry" | cut -f2- -d:)"
163            fi
164            mcopy -v -i ${WORKDIR}/boot.img -s ${DEPLOY_DIR_IMAGE}/${DEPLOY_FILE} ::${DEST_FILENAME} || bbfatal "mcopy cannot copy ${DEPLOY_DIR_IMAGE}/${DEPLOY_FILE} into boot.img"
165        done
166    fi
167
168    if [ -n "${FATPAYLOAD}" ] ; then
169        echo "Copying payload into VFAT"
170        for entry in ${FATPAYLOAD} ; do
171            # use bbwarn instead of bbfatal to stop aborting on vfat issues like not supporting .~lock files
172            mcopy -v -i ${WORKDIR}/boot.img -s ${IMAGE_ROOTFS}$entry :: || bbwarn "mcopy cannot copy ${IMAGE_ROOTFS}$entry into boot.img"
173        done
174    fi
175
176    # Add stamp file
177    echo "${IMAGE_NAME}" > ${WORKDIR}/image-version-info
178    mcopy -v -i ${WORKDIR}/boot.img ${WORKDIR}/image-version-info :: || bbfatal "mcopy cannot copy ${WORKDIR}/image-version-info into boot.img"
179
180    # Deploy vfat partition
181    if [ "${SDIMG_VFAT_DEPLOY}" = "1" ]; then
182        cp ${WORKDIR}/boot.img ${IMGDEPLOYDIR}/${SDIMG_VFAT}
183        ln -sf ${SDIMG_VFAT} ${SDIMG_LINK_VFAT}
184    fi
185
186    # Burn Partitions
187    dd if=${WORKDIR}/boot.img of=${SDIMG} conv=notrunc seek=1 bs=$(expr ${IMAGE_ROOTFS_ALIGNMENT} \* 1024)
188    # If SDIMG_ROOTFS_TYPE is a .xz file use xzcat
189    if echo "${SDIMG_ROOTFS_TYPE}" | egrep -q "*\.xz"
190    then
191        xzcat ${SDIMG_ROOTFS} | dd of=${SDIMG} conv=notrunc seek=1 bs=$(expr 1024 \* ${BOOT_SPACE_ALIGNED} + ${IMAGE_ROOTFS_ALIGNMENT} \* 1024)
192    else
193        dd if=${SDIMG_ROOTFS} of=${SDIMG} conv=notrunc seek=1 bs=$(expr 1024 \* ${BOOT_SPACE_ALIGNED} + ${IMAGE_ROOTFS_ALIGNMENT} \* 1024)
194    fi
195}
196
197ROOTFS_POSTPROCESS_COMMAND += " rpi_generate_sysctl_config ; "
198
199rpi_generate_sysctl_config() {
200    # systemd sysctl config
201    test -d ${IMAGE_ROOTFS}${sysconfdir}/sysctl.d && \
202        echo "vm.min_free_kbytes = 8192" > ${IMAGE_ROOTFS}${sysconfdir}/sysctl.d/rpi-vm.conf
203
204    # sysv sysctl config
205    IMAGE_SYSCTL_CONF="${IMAGE_ROOTFS}${sysconfdir}/sysctl.conf"
206    test -e ${IMAGE_ROOTFS}${sysconfdir}/sysctl.conf && \
207        sed -e "/vm.min_free_kbytes/d" -i ${IMAGE_SYSCTL_CONF}
208    echo "" >> ${IMAGE_SYSCTL_CONF} && echo "vm.min_free_kbytes = 8192" >> ${IMAGE_SYSCTL_CONF}
209}
210