1# Generates MRW settings override yaml for phosphor-settings-manager
2# The default YAML file, mrw-override-settings.yaml, is empty, therefore no
3# settings will be overwritten. To override, modify mrw-override-settings.yaml.
4
5SUMMARY = "Generates MRW settings override YAML for phosphor-settings-manager."
6PR = "r1"
7LICENSE = "Apache-2.0"
8LIC_FILES_CHKSUM = "file://${COREBASE}/meta/files/common-licenses/Apache-2.0;md5=89aea4e17d99a7cacdbeed46a0096b10"
9
10inherit phosphor-settings-manager
11inherit mrw-xml
12inherit native
13
14DEPENDS += "mrw-native mrw-perl-tools-native"
15
16SRC_URI += "file://mrw-override-settings.yaml"
17
18S = "${WORKDIR}"
19
20MRW_EXPRESSION_VARS ?= ""
21
22do_install() {
23    DEST=${D}${config_datadir}
24    install -D mrw-override-settings.yaml ${DEST}/mrw-override-settings.yaml
25
26    SETTINGS=${D}${settings_datadir}
27    install -d ${SETTINGS}
28
29    # gen_settings.pl replaces any MRW variables with their value
30    ${bindir}/perl-native/perl \
31        ${bindir}/gen_settings.pl \
32        -i ${mrw_datadir}/${MRW_XML} \
33        -s ${DEST}/mrw-override-settings.yaml \
34        -o ${SETTINGS}/mrw-settings.override.yaml \
35        ${MRW_EXPRESSION_VARS} \
36        -f
37}
38