1SUMMARY = "Entity Manager"
2DESCRIPTION = "Entity Manager provides d-bus configuration data \
3and configures system sensors"
4
5SRC_URI = "git://github.com/openbmc/entity-manager.git;branch=master;protocol=https \
6           file://blocklist.json \
7          "
8SRCREV = "309c0b13646b747bd35e63dd53ad38d6f129ff53"
9PV = "0.1+git${SRCPV}"
10
11LICENSE = "Apache-2.0"
12LIC_FILES_CHKSUM = "file://LICENCE;md5=a6a4edad4aed50f39a66d098d74b265b"
13
14DEPENDS = "boost \
15           dbus \
16           nlohmann-json \
17           sdbusplus \
18           valijson \
19           ${PYTHON_PN}-jsonschema-native \
20"
21
22S = "${WORKDIR}/git"
23inherit pkgconfig meson systemd python3native
24
25EXTRA_OEMESON = "-Dtests=disabled"
26
27PACKAGECONFIG ??= "ipmi-fru"
28PACKAGECONFIG[ipmi-fru] = "-Dfru-device=true, -Dfru-device=false, i2c-tools,"
29
30EXTRA_ENTITY_MANAGER_PACKAGES = " \
31    ${@bb.utils.contains('PACKAGECONFIG', 'ipmi-fru', 'fru-device', '', d)} \
32    "
33
34PACKAGE_BEFORE_PN = "${EXTRA_ENTITY_MANAGER_PACKAGES}"
35
36do_install:append() {
37    install -D ${WORKDIR}/blocklist.json ${D}${datadir}/${BPN}/blacklist.json
38}
39
40FILES:${PN} += " \
41    ${datadir}/dbus-1/system-services/xyz.openbmc_project.EntityManager.service \
42    "
43FILES:fru-device = "${bindir}/fru-device ${datadir}/${BPN}/blacklist.json"
44
45SYSTEMD_PACKAGES = "${PN} ${EXTRA_ENTITY_MANAGER_PACKAGES}"
46SYSTEMD_SERVICE:${PN} = "xyz.openbmc_project.EntityManager.service"
47SYSTEMD_SERVICE:fru-device = "xyz.openbmc_project.FruDevice.service"
48SYSTEMD_AUTO_ENABLE:fru-device_ibm-power-cpu = "disable"
49