1SUMMARY = "Hardware Diagnostics for POWER Systems"
2
3DESCRIPTION = \
4    "In the event of a system fatal error reported by the internal system \
5    hardware (processor chips, memory chips, I/O chips, system memory, etc.), \
6    POWER Systems have the ability to diagnose the root cause of the failure \
7    and perform any service action needed to avoid repeated system failures."
8
9HOMEPAGE = "https://github.com/openbmc/openpower-hw-diags"
10
11LICENSE = "Apache-2.0"
12LIC_FILES_CHKSUM = "file://LICENSE;md5=86d3f3a95c324c9479bd8986968f4327"
13
14PR = "r1"
15PV = "0.1+git${SRCPV}"
16
17SRC_URI = "git://github.com/openbmc/openpower-hw-diags;branch=master;protocol=https"
18SRCREV = "6b2a5a4e15e54ffd155fab69b6aa775a58b4f5cc"
19
20S = "${WORKDIR}/git"
21
22inherit pkgconfig meson systemd
23
24SYSTEMD_SERVICE:${PN} = "attn_handler.service"
25
26DEPENDS = "boost libgpiod pdbg phosphor-logging sdbusplus openpower-libhei \
27           nlohmann-json valijson fmt"
28
29# This is required so that libhei is installed with the chip data files.
30RDEPENDS:${PN} += "openpower-libhei"
31
32# Conditionally pull in PHAL APIs, if available.
33PACKAGECONFIG ??= "${@bb.utils.filter('MACHINE_FEATURES', 'phal', d)}"
34PACKAGECONFIG[phal] = "-Dphal=enabled, -Dphal=disabled, ipl pdata"
35
36# Don't build CI tests
37EXTRA_OEMESON = "-Dtests=disabled"
38
39pkg_postinst:${PN}() {
40    mkdir -p $D$systemd_system_unitdir/obmc-host-startmin@0.target.wants
41    LINK="$D$systemd_system_unitdir/obmc-host-startmin@0.target.wants/attn_handler.service"
42    TARGET="../attn_handler.service"
43    ln -s $TARGET $LINK
44}
45
46pkg_prerm:${PN}() {
47    LINK="$D$systemd_system_unitdir/obmc-host-startmin@0.target.wants/attn_handler.service"
48    rm $LINK
49}
50