1PACKAGECONFIG:append = " virtual_pnor"
2
3RDEPENDS:${PN} += " \
4        bash \
5"
6
7SYSTEMD_SERVICE:${PN} += " \
8        obmc-vpnor-updatesymlinks.service \
9        obmc-vpnor-check-clearvolatile@.service \
10        obmc-vpnor-enable-clearvolatile@.service \
11        "
12
13# To handle warm reboot scenarios, the checking and clearing of
14# the volatile section must occur in both the chassis and host
15# targets
16
17# Host target installation - only clear if going through
18# full host start target
19ENABLE_CLEAR_VOLATILE_TMPL = "obmc-vpnor-enable-clearvolatile@.service"
20HOST_START_TGTFMT = "obmc-host-start@{0}.target"
21ENABLE_CLEAR_VOLATILE_INSTFMT = "obmc-vpnor-enable-clearvolatile@{0}.service"
22ENABLE_CLEAR_VOLATILE_START_FMT = "../${ENABLE_CLEAR_VOLATILE_TMPL}:${HOST_START_TGTFMT}.requires/${ENABLE_CLEAR_VOLATILE_INSTFMT}"
23
24CHECK_CLEAR_VOLATILE_TMPL = "obmc-vpnor-check-clearvolatile@.service"
25HOST_STARTMIN_TGTFMT = "obmc-host-startmin@{0}.target"
26CHECK_CLEAR_VOLATILE_INSTFMT = "obmc-vpnor-check-clearvolatile@{0}.service"
27CHECK_CLEAR_VOLATILE_START_FMT = "../${CHECK_CLEAR_VOLATILE_TMPL}:${HOST_STARTMIN_TGTFMT}.requires/${CHECK_CLEAR_VOLATILE_INSTFMT}"
28
29UPDATE_SYMLINKS_SVC = "obmc-vpnor-updatesymlinks.service"
30MBOXD_RELOAD_SVC = "mboxd-reload@{0}.service"
31UPDATE_SYMLINKS_FMT = "../${UPDATE_SYMLINKS_SVC}:${MBOXD_RELOAD_SVC}.wants/${UPDATE_SYMLINKS_SVC}"
32
33SYSTEMD_LINK:${PN} += "${@compose_list_zip(d, 'ENABLE_CLEAR_VOLATILE_START_FMT', 'OBMC_HOST_INSTANCES')}"
34SYSTEMD_LINK:${PN} += "${@compose_list_zip(d, 'CHECK_CLEAR_VOLATILE_START_FMT', 'OBMC_HOST_INSTANCES')}"
35SYSTEMD_LINK:${PN} += "${@compose_list_zip(d, 'UPDATE_SYMLINKS_FMT', 'OBMC_HOST_INSTANCES')}"
36
37# Chassis target installation - always enable and clear in chassis
38# power on
39CHASSIS_PON_TGTFMT = "obmc-chassis-poweron@{0}.target"
40ENABLE_CLEAR_VOLATILE_PON_FMT = "../${ENABLE_CLEAR_VOLATILE_TMPL}:${CHASSIS_PON_TGTFMT}.requires/${ENABLE_CLEAR_VOLATILE_INSTFMT}"
41
42CHECK_CLEAR_VOLATILE_PON_FMT = "../${CHECK_CLEAR_VOLATILE_TMPL}:${CHASSIS_PON_TGTFMT}.requires/${CHECK_CLEAR_VOLATILE_INSTFMT}"
43
44SYSTEMD_LINK:${PN} += "${@compose_list_zip(d, 'ENABLE_CLEAR_VOLATILE_PON_FMT', 'OBMC_CHASSIS_INSTANCES')}"
45SYSTEMD_LINK:${PN} += "${@compose_list_zip(d, 'CHECK_CLEAR_VOLATILE_PON_FMT', 'OBMC_CHASSIS_INSTANCES')}"
46