1SUMMARY = "WebKit web rendering engine for the GTK+ platform"
2HOMEPAGE = "https://www.webkitgtk.org/"
3BUGTRACKER = "https://bugs.webkit.org/"
4
5LICENSE = "BSD-2-Clause & LGPL-2.0-or-later"
6LIC_FILES_CHKSUM = "file://Source/JavaScriptCore/COPYING.LIB;md5=d0c6d6397a5d84286dda758da57bd691 \
7                    file://Source/WebCore/LICENSE-APPLE;md5=4646f90082c40bcf298c285f8bab0b12 \
8                    file://Source/WebCore/LICENSE-LGPL-2;md5=36357ffde2b64ae177b2494445b79d21 \
9                    file://Source/WebCore/LICENSE-LGPL-2.1;md5=a778a33ef338abbaf8b8a7c36b6eec80 \
10                    "
11
12SRC_URI = "https://www.webkitgtk.org/releases/webkitgtk-${PV}.tar.xz \
13           file://0001-FindGObjectIntrospection.cmake-prefix-variables-obta.patch \
14           file://reproducibility.patch \
15           file://no-musttail-arm.patch \
16           file://0001-LowLevelInterpreter.cpp-339-21-error-t6-was-not-decl.patch \
17           file://30e1d5e22213fdaca2a29ec3400c927d710a37a8.patch \
18           "
19SRC_URI[sha256sum] = "523f42c8ff24832add17631f6eaafe8f9303afe316ef1a7e1844b952a7f7521b"
20
21inherit cmake pkgconfig gobject-introspection perlnative features_check upstream-version-is-even gi-docgen
22
23S = "${WORKDIR}/webkitgtk-${PV}"
24
25ANY_OF_DISTRO_FEATURES = "${GTK3DISTROFEATURES}"
26REQUIRED_DISTRO_FEATURES = "${@bb.utils.contains('DISTRO_FEATURES', 'wayland', 'opengl', '', d)}"
27
28CVE_PRODUCT = "webkitgtk webkitgtk\+"
29
30DEPENDS += " \
31          ruby-native \
32          gperf-native \
33          unifdef-native \
34          cairo \
35          harfbuzz \
36          jpeg \
37          atk \
38          libwebp \
39          gtk+3 \
40          libxslt \
41          libtasn1 \
42          libnotify \
43          gstreamer1.0 \
44          gstreamer1.0-plugins-base \
45          glib-2.0-native \
46          gettext-native \
47          "
48
49PACKAGECONFIG_SOUP ?= "soup3"
50PACKAGECONFIG ??= " \
51	   ${@bb.utils.filter('DISTRO_FEATURES', 'systemd wayland x11', d)} \
52	   ${@bb.utils.contains('DISTRO_FEATURES', 'x11 opengl', 'webgl opengl', '', d)} \
53	   ${@bb.utils.contains('DISTRO_FEATURES', 'x11', '', 'webgl gles2', d)} \
54	   ${@bb.utils.contains('DISTRO_FEATURES', 'opengl', 'opengl-or-es', '', d)} \
55	   enchant \
56	   libsecret \
57	   ${PACKAGECONFIG_SOUP} \
58	   "
59
60PACKAGECONFIG[wayland] = "-DENABLE_WAYLAND_TARGET=ON,-DENABLE_WAYLAND_TARGET=OFF,wayland libwpe wpebackend-fdo wayland-native"
61PACKAGECONFIG[angle] = "-DUSE_ANGLE_WEBGL=ON,-DUSE_ANGLE_WEBGL=OFF"
62PACKAGECONFIG[x11] = "-DENABLE_X11_TARGET=ON,-DENABLE_X11_TARGET=OFF,virtual/libx11 libxcomposite libxdamage libxrender libxt"
63PACKAGECONFIG[geoclue] = "-DENABLE_GEOLOCATION=ON,-DENABLE_GEOLOCATION=OFF,geoclue"
64PACKAGECONFIG[enchant] = "-DENABLE_SPELLCHECK=ON,-DENABLE_SPELLCHECK=OFF,enchant2"
65PACKAGECONFIG[gles2] = "-DENABLE_GLES2=ON,-DENABLE_GLES2=OFF,virtual/libgles2"
66PACKAGECONFIG[jpegxl] = " -DUSE_JPEGXL=ON,-DUSE_JPEGXL=OFF,libjxl"
67PACKAGECONFIG[webgl] = "-DENABLE_WEBGL=ON,-DENABLE_WEBGL=OFF,virtual/egl"
68PACKAGECONFIG[opengl] = "-DENABLE_GRAPHICS_CONTEXT_GL=ON,-DENABLE_GRAPHICS_CONTEXT_GL=OFF,virtual/egl"
69PACKAGECONFIG[opengl-or-es] = "-DUSE_OPENGL_OR_ES=ON,-DUSE_OPENGL_OR_ES=OFF"
70PACKAGECONFIG[libsecret] = "-DUSE_LIBSECRET=ON,-DUSE_LIBSECRET=OFF,libsecret"
71PACKAGECONFIG[libhyphen] = "-DUSE_LIBHYPHEN=ON,-DUSE_LIBHYPHEN=OFF,libhyphen"
72PACKAGECONFIG[woff2] = "-DUSE_WOFF2=ON,-DUSE_WOFF2=OFF,woff2"
73PACKAGECONFIG[openjpeg] = "-DUSE_OPENJPEG=ON,-DUSE_OPENJPEG=OFF,openjpeg"
74PACKAGECONFIG[systemd] = "-DUSE_SYSTEMD=ON,-DUSE_SYSTEMD=off,systemd"
75PACKAGECONFIG[reduce-size] = "-DCMAKE_BUILD_TYPE=MinSizeRel,-DCMAKE_BUILD_TYPE=Release,,"
76PACKAGECONFIG[lcms] = "-DUSE_LCMS=ON,-DUSE_LCMS=OFF,lcms"
77PACKAGECONFIG[soup2] = "-DUSE_SOUP2=ON,-DUSE_SOUP2=OFF,libsoup-2.4,,,soup3"
78PACKAGECONFIG[soup3] = ",,libsoup,,,soup2"
79PACKAGECONFIG[journald] = "-DENABLE_JOURNALD_LOG=ON,-DENABLE_JOURNALD_LOG=OFF,systemd"
80PACKAGECONFIG[avif] = "-DUSE_AVIF_LOG=ON,-DUSE_AVIF=OFF,libavif"
81PACKAGECONFIG[media-recorder] = "-DENABLE_MEDIA_RECORDER=ON,-DENABLE_MEDIA_RECORDER=OFF,gstreamer1.0-plugins-bad"
82PACKAGECONFIG[gamepad] = "-DENABLE_GAMEPAD=ON,-DENABLE_GAMEPAD=OFF,libmanette"
83PACKAGECONFIG[webrtc] = "-DENABLE_WEB_RTC=ON,-DENABLE_WEB_RTC=OFF"
84PACKAGECONFIG[bubblewrap] = "-DENABLE_BUBBLEWRAP_SANDBOX=ON -DBWRAP_EXECUTABLE=${bindir}/bwrap -DDBUS_PROXY_EXECUTABLE=${bindir}/xdg-dbus-proxy,-DENABLE_BUBBLEWRAP_SANDBOX=OFF,,bubblewrap xdg-dbus-proxy"
85PACKAGECONFIG[backtrace] = "-DUSE_LIBBACKTRACE=ON,-DUSE_LIBBACKTRACE=OFF,libbacktrace"
86
87EXTRA_OECMAKE = " \
88	-DPORT=GTK \
89	-DUSE_GTK4=OFF \
90	${@bb.utils.contains('GI_DATA_ENABLED', 'True', '-DENABLE_INTROSPECTION=ON', '-DENABLE_INTROSPECTION=OFF', d)} \
91	${@bb.utils.contains('GIDOCGEN_ENABLED', 'True', '-DENABLE_DOCUMENTATION=ON', '-DENABLE_DOCUMENTATION=OFF', d)} \
92	-DENABLE_MINIBROWSER=ON \
93	-DCMAKE_EXPORT_COMPILE_COMMANDS=OFF \
94		"
95# Unless DEBUG_BUILD is enabled, pass -g1 to massively reduce the size of the
96# debug symbols (4.3GB to 700M at time of writing)
97DEBUG_FLAGS:append = "${@oe.utils.vartrue('DEBUG_BUILD', '', ' -g1', d)}"
98
99# Javascript JIT is not supported on ARC
100EXTRA_OECMAKE:append:arc = " -DENABLE_JIT=OFF "
101# By default 25-bit "medium" calls are used on ARC
102# which is not enough for binaries larger than 32 MiB
103CFLAGS:append:arc = " -mlong-calls"
104CXXFLAGS:append:arc = " -mlong-calls"
105
106# Needed for non-mesa graphics stacks when x11 is disabled
107CXXFLAGS += "${@bb.utils.contains('DISTRO_FEATURES', 'x11', '', '-DEGL_NO_X11=1', d)}"
108
109# Javascript JIT is not supported on powerpc
110EXTRA_OECMAKE:append:powerpc = " -DENABLE_JIT=OFF "
111EXTRA_OECMAKE:append:powerpc64 = " -DENABLE_JIT=OFF "
112
113# ARM JIT code does not build on ARMv4/5/6 anymore
114EXTRA_OECMAKE:append:armv4 = " -DENABLE_JIT=OFF "
115EXTRA_OECMAKE:append:armv5 = " -DENABLE_JIT=OFF "
116EXTRA_OECMAKE:append:armv6 = " -DENABLE_JIT=OFF "
117
118# And for armv7* don't enable it for softfp, because after:
119# https://github.com/WebKit/WebKit/commit/a2ec4ef1997d6fafa6ffc607bffb54e76168a918
120# https://bugs.webkit.org/show_bug.cgi?id=242172
121# softfp armv7* fails because WEBASSEMBLY is left enabled by default and JIT gets
122# explicitly disabled causing:
123# http://errors.yoctoproject.org/Errors/Details/734587/
124# PR was sent upstream, but the end result is the same both JIT and WEBASSEMBLY disabled
125# https://github.com/WebKit/WebKit/pull/17447
126EXTRA_OECMAKE:append:armv7a = " -DENABLE_JIT=${@bb.utils.contains('TUNE_FEATURES', 'callconvention-hard', 'ON', 'OFF', d)}"
127EXTRA_OECMAKE:append:armv7r = " -DENABLE_JIT=${@bb.utils.contains('TUNE_FEATURES', 'callconvention-hard', 'ON', 'OFF', d)}"
128EXTRA_OECMAKE:append:armv7ve = " -DENABLE_JIT=${@bb.utils.contains('TUNE_FEATURES', 'callconvention-hard', 'ON', 'OFF', d)}"
129
130EXTRA_OECMAKE:append:mipsarch = " -DUSE_LD_GOLD=OFF "
131EXTRA_OECMAKE:append:powerpc = " -DUSE_LD_GOLD=OFF "
132
133# JIT and gold linker does not work on RISCV
134EXTRA_OECMAKE:append:riscv32 = " -DUSE_LD_GOLD=OFF -DENABLE_JIT=OFF"
135EXTRA_OECMAKE:append:riscv64 = " -DUSE_LD_GOLD=OFF"
136
137# JIT not supported on MIPS either
138EXTRA_OECMAKE:append:mipsarch = " -DENABLE_JIT=OFF -DENABLE_C_LOOP=ON "
139
140# JIT not supported on X32
141# An attempt was made to upstream JIT support for x32 in
142# https://bugs.webkit.org/show_bug.cgi?id=100450, but this was closed as
143# unresolved due to limited X32 adoption.
144EXTRA_OECMAKE:append:x86-x32 = " -DENABLE_JIT=OFF "
145
146SECURITY_CFLAGS:remove:aarch64 = "-fpie"
147SECURITY_CFLAGS:append:aarch64 = " -fPIE"
148
149FILES:${PN} += "${libdir}/webkit2gtk-4.*/injected-bundle/libwebkit2gtkinjectedbundle.so"
150
151RRECOMMENDS:${PN} += "ca-certificates shared-mime-info"
152
153# http://errors.yoctoproject.org/Errors/Details/20370/
154ARM_INSTRUCTION_SET:armv4 = "arm"
155ARM_INSTRUCTION_SET:armv5 = "arm"
156ARM_INSTRUCTION_SET:armv6 = "arm"
157
158# https://bugzilla.yoctoproject.org/show_bug.cgi?id=9474
159# https://bugs.webkit.org/show_bug.cgi?id=159880
160# JSC JIT can build on ARMv7 with -marm, but doesn't work on runtime.
161# Upstream only tests regularly the JSC JIT on ARMv7 with Thumb2 (-mthumb).
162ARM_INSTRUCTION_SET:armv7a = "thumb"
163ARM_INSTRUCTION_SET:armv7r = "thumb"
164ARM_INSTRUCTION_SET:armv7ve = "thumb"
165
166# ANGLE requires SSE support as of webkit 2.40.x on 32 bit x86
167COMPATIBLE_HOST:x86 = "${@bb.utils.contains_any('TUNE_FEATURES', 'core2 corei7', '.*', 'null', d)}"
168
169# introspection inside qemu-arm hangs forever on musl/arm builds
170# therefore disable GI_DATA
171GI_DATA_ENABLED:libc-musl:armv7a = "False"
172GI_DATA_ENABLED:libc-musl:armv7ve = "False"
173
174do_install:append() {
175	mv ${D}${bindir}/WebKitWebDriver ${D}${bindir}/WebKitWebDriver3
176}
177
178PACKAGE_PREPROCESS_FUNCS += "src_package_preprocess"
179src_package_preprocess () {
180        # Trim build paths from comments in generated sources to ensure reproducibility
181        sed -i -e "s,${WORKDIR},,g" \
182            ${B}/JavaScriptCore/DerivedSources/*.h \
183            ${B}/JavaScriptCore/DerivedSources/yarr/*.h \
184            ${B}/JavaScriptCore/PrivateHeaders/JavaScriptCore/*.h \
185            ${B}/WebCore/DerivedSources/*.cpp \
186            ${B}/WebKitGTK/DerivedSources/webkit/*.cpp
187}
188
189