1SUMMARY = "Hash table and linked list for C structures"
2DESCRIPTION = " uthash-dev provides a hash table implementation using C preprocessor macros.\n\
3 This package also includes:\n\
4  * utlist.h provides linked list macros for C structures\n\
5  * utarray.h implements dynamic arrays using macros\n\
6  * utstring.h implements a basic dynamic string\n\
7"
8HOMEPAGE = "https://troydhanson.github.io/uthash/"
9SECTION = "base"
10LICENSE = "BSD-1-Clause"
11LIC_FILES_CHKSUM = "file://LICENSE;md5=736712b5904dd42f8678df7172bc5f2b"
12SRCREV = "e493aa90a2833b4655927598f169c31cfcdf7861"
13
14SRC_URI = "\
15    git://github.com/troydhanson/${BPN}.git \
16    file://run-ptest \
17"
18
19S = "${WORKDIR}/git"
20
21inherit ptest
22
23do_compile[noexec] = "1"
24
25do_compile_ptest() {
26    oe_runmake -C tests tests_only TEST_TARGET=
27}
28
29do_install () {
30    install -dm755 ${D}${includedir}
31    install -m0644 src/*.h ${D}${includedir}
32}
33
34do_install_ptest() {
35    install -dm755 ${D}${PTEST_PATH}/tests
36    install -m0755 tests/test*[0-9] ${D}${PTEST_PATH}/tests
37    install -m0644 tests/test*[0-9].ans ${D}${PTEST_PATH}/tests
38    install -m0644 tests/test*[0-9].dat ${D}${PTEST_PATH}/tests
39}
40
41# The main package is empty and non-existent, so -dev
42# should not depend on it...
43RDEPENDS:${PN}-dev = ""
44RDEPENDS:${PN}-ptest:remove = "${PN}"
45
46BBCLASSEXTEND = "native"
47