1SUMMARY = "udisks provides dbus interfaces for disks and storage devices"
2LICENSE = "GPL-2.0-or-later & LGPL-2.0-or-later"
3LIC_FILES_CHKSUM = "file://COPYING;md5=dd79f6dbbffdbc8e86b086a8f0c0ef43"
4
5DEPENDS = " \
6    glib-2.0-native \
7    libxslt-native \
8    acl \
9    libatasmart \
10    polkit \
11    libgudev \
12    glib-2.0 \
13    dbus-glib \
14    libblockdev \
15"
16DEPENDS += "${@bb.utils.filter('DISTRO_FEATURES', 'systemd', d)}"
17
18RDEPENDS:${PN} = "acl"
19
20SRC_URI = " \
21	git://github.com/storaged-project/udisks.git;branch=2.10.x-branch;protocol=https \
22	file://0001-Makefile.am-Dont-include-buildpath.patch \
23"
24SRCREV = "18c9faf089e306ad6f3f51f5cb887a6b9aa08350"
25S = "${WORKDIR}/git"
26
27CVE_PRODUCT = "udisks"
28
29inherit autotools-brokensep systemd gtk-doc gobject-introspection gettext features_check
30
31REQUIRED_DISTRO_FEATURES = "polkit"
32
33EXTRA_OECONF = "--disable-man --disable-gtk-doc"
34
35do_configure:prepend() {
36    # | configure.ac:656: error: required file 'build-aux/config.rpath' not found
37    mkdir -p ${S}/build-aux
38    touch ${S}/build-aux/config.rpath
39}
40
41PACKAGECONFIG ?= ""
42
43PACKAGECONFIG[lvm2] = "--enable-lvm2,--disable-lvm2,lvm2"
44PACKAGECONFIG[btrfs] = "--enable-btrfs,--disable-btrfs,,btrfs-tools"
45PACKAGECONFIG[lsm] = "--enable-lsm,--disable-lsm,libstoragemgmt"
46
47FILES:${PN} += " \
48    ${datadir}/dbus-1/ \
49    ${datadir}/polkit-1 \
50    ${datadir}/bash-completion \
51    ${datadir}/zsh \
52    ${libdir}/polkit-1/extensions/*.so \
53    ${nonarch_base_libdir}/udev/* \
54    ${exec_prefix}${nonarch_base_libdir}/udisks2/* \
55    ${systemd_system_unitdir} \
56"
57
58PACKAGES =+ "${PN}-libs"
59FILES:${PN}-libs = "${libdir}/lib*${SOLIBS}"
60FILES:${PN} += "${nonarch_libdir}/tmpfiles.d"
61
62SYSTEMD_SERVICE:${PN} = "${BPN}.service"
63SYSTEMD_AUTO_ENABLE = "disable"
64