1SUMMARY = "Poppler is a PDF rendering library based on the xpdf-3.0 code base"
2HOMEPAGE = "https://poppler.freedesktop.org/"
3LICENSE = "GPL-2.0-only"
4LIC_FILES_CHKSUM = "file://COPYING;md5=751419260aa954499f7abaabaa882bbe"
5
6SRC_URI = "http://poppler.freedesktop.org/${BP}.tar.xz \
7           file://0001-Do-not-overwrite-all-our-build-flags.patch \
8           file://basename-include.patch \
9           file://0001-cmake-Do-not-use-isystem.patch \
10           "
11SRC_URI[sha256sum] = "b6d893dc7dcd4138b9e9df59a13c59695e50e80dc5c2cacee0674670693951a1"
12
13DEPENDS = "fontconfig zlib cairo lcms glib-2.0 glib-2.0-native"
14
15inherit cmake pkgconfig gobject-introspection
16
17PACKAGECONFIG ??= "jpeg openjpeg png tiff nss splash"
18PACKAGECONFIG[jpeg] = "-DWITH_JPEG=ON -DENABLE_DCTDECODER=libjpeg,-DWITH_JPEG=OFF -DENABLE_DCTDECODER=none,jpeg"
19PACKAGECONFIG[png] = "-DWITH_PNG=ON,-DWITH_PNG=OFF,libpng"
20PACKAGECONFIG[tiff] = "-DWITH_TIFF=ON,-DWITH_TIFF=OFF,tiff"
21PACKAGECONFIG[curl] = "-DENABLE_LIBCURL=ON,-DENABLE_LIBCURL=OFF,curl"
22PACKAGECONFIG[openjpeg] = "-DENABLE_LIBOPENJPEG=openjpeg2,-DENABLE_LIBOPENJPEG=none,openjpeg"
23PACKAGECONFIG[qt5] = "-DENABLE_QT5=ON,-DENABLE_QT5=OFF,qtbase qttools-native"
24PACKAGECONFIG[nss] = "-DWITH_NSS3=ON,-DWITH_NSS3=OFF,nss"
25PACKAGECONFIG[splash] = "-DENABLE_SPLASH=ON -DENABLE_BOOST=ON,-DENABLE_SPLASH=OFF -DENABLE_BOOST=OFF,boost"
26
27# surprise - did not expect this to work :)
28inherit ${@bb.utils.contains('PACKAGECONFIG', 'qt5', 'cmake_qt5', '', d)}
29
30SECURITY_CFLAGS = "${SECURITY_NO_PIE_CFLAGS}"
31
32EXTRA_OECMAKE += " \
33    -DENABLE_CMS=lcms2 \
34    -DENABLE_UNSTABLE_API_ABI_HEADERS=ON \
35    -DBUILD_GTK_TESTS=OFF \
36    -DENABLE_ZLIB=ON \
37    -DRUN_GPERF_IF_PRESENT=OFF \
38    -DCMAKE_CXX_IMPLICIT_INCLUDE_DIRECTORIES:PATH='${STAGING_INCDIR}' \
39    ${@bb.utils.contains('GI_DATA_ENABLED', 'True', '-DENABLE_GOBJECT_INTROSPECTION=ON', '-DENABLE_GOBJECT_INTROSPECTION=OFF', d)} \
40"
41EXTRA_OECMAKE:append:class-native = " -DENABLE_CPP=OFF"
42
43do_configure:append() {
44    # poppler macro uses pkg-config to check for g-ir runtimes. Something
45    # makes them point to /usr/bin. Align them to sysroot - that's where the
46    # gir-wrappers are:
47    sed -i 's: ${bindir}/g-ir: ${STAGING_BINDIR}/g-ir:' ${B}/build.ninja
48}
49
50PACKAGES =+ "libpoppler libpoppler-glib"
51FILES:libpoppler = "${libdir}/libpoppler.so.*"
52FILES:libpoppler-glib = "${libdir}/libpoppler-glib.so.*"
53
54RDEPENDS:libpoppler = "poppler-data"
55
56BBCLASSEXTEND = "native"
57