1SUMMARY = "Snowball compiler and stemming algorithms"
2HOMEPAGE = "https://snowballstem.org/"
3LICENSE = "BSD-3-Clause"
4LIC_FILES_CHKSUM = "file://COPYING;md5=19139aaf3c8c8fa1ca6edd59c072fb9f"
5
6DEPENDS:append:class-target = " ${BPN}-native"
7
8SRC_URI = "git://github.com/snowballstem/snowball.git;branch=master;protocol=https \
9           file://0001-Build-so-lib.patch \
10           "
11SRCREV = "48a67a2831005f49c48ec29a5837640e23e54e6b"
12S = "${WORKDIR}/git"
13
14LIBVER = "0.0.0"
15
16inherit lib_package
17
18do_compile:prepend:class-target() {
19    # use native tools
20    sed -i 's:./snowball :snowball :g' ${S}/GNUmakefile
21}
22
23do_install() {
24    install -d ${D}${bindir}
25    install -m 755 ${S}/snowball ${D}${bindir}
26    install -m 755 ${S}/stemwords ${D}${bindir}
27
28    install -d ${D}${libdir}
29    install -m 755 ${S}/libstemmer.so.${LIBVER} ${D}${libdir}/
30    ln -s libstemmer.so.${LIBVER} ${D}${libdir}/libstemmer.so.0
31    ln -s libstemmer.so.${LIBVER} ${D}${libdir}/libstemmer.so
32
33    install -d ${D}${includedir}
34    install -m 644 ${S}/include/*.h ${D}${includedir}
35}
36
37BBCLASSEXTEND = "native"
38