1SUMMARY = "Multiplatform C library implementing the SSHv2 and SSHv1 protocol"
2HOMEPAGE = "http://www.libssh.org"
3SECTION = "libs"
4LICENSE = "LGPL-2.1-only"
5LIC_FILES_CHKSUM = "file://COPYING;md5=dabb4958b830e5df11d2b0ed8ea255a0"
6
7DEPENDS = "zlib openssl"
8
9SRC_URI = "git://git.libssh.org/projects/libssh.git;protocol=https;branch=stable-0.10 \
10           file://0001-tests-CMakeLists.txt-do-not-search-ssh-sshd-commands.patch \
11           file://0001-libgcrypt.c-Fix-prototype-of-des3_encrypt-des3_decry.patch \
12           file://run-ptest \
13          "
14SRCREV = "10e09e273f69e149389b3e0e5d44b8c221c2e7f6"
15
16S = "${WORKDIR}/git"
17
18inherit cmake ptest
19
20PACKAGECONFIG ??= "gcrypt ${@bb.utils.contains('PTEST_ENABLED', '1', 'tests', '', d)}"
21PACKAGECONFIG[gssapi] = "-DWITH_GSSAPI=1, -DWITH_GSSAPI=0, krb5, "
22PACKAGECONFIG[gcrypt] = "-DWITH_GCRYPT=1, -DWITH_GCRYPT=0, libgcrypt, "
23PACKAGECONFIG[tests] = "-DUNIT_TESTING=1, -DUNIT_TESTING=0, cmocka"
24
25ARM_INSTRUCTION_SET:armv5 = "arm"
26
27EXTRA_OECMAKE = " \
28    -DWITH_PCAP=1 \
29    -DWITH_SFTP=1 \
30    -DWITH_ZLIB=1 \
31    -DWITH_EXAMPLES=0 \
32    "
33
34do_compile:prepend () {
35    if [ ${PTEST_ENABLED} = "1" ]; then
36        sed -i -e 's|${B}|${PTEST_PATH}|g' ${B}/config.h
37        sed -i -e 's|${S}|${PTEST_PATH}|g' ${B}/config.h
38    fi
39}
40
41do_install_ptest () {
42    install -d ${D}${PTEST_PATH}/tests
43    cp -f ${B}/tests/unittests/torture_* ${D}${PTEST_PATH}/tests/
44    install -d ${D}${PTEST_PATH}/tests/unittests
45    cp -f ${S}/tests/unittests/hello*.sh ${D}${PTEST_PATH}/tests/unittests/
46}
47
48BBCLASSEXTEND = "native nativesdk"
49