1SUMMARY = "A C++11 library for serialization"
2HOMEPAGE = "https://uscilab.github.io/cereal/"
3
4SECTION = "libs"
5
6LICENSE = "BSD-3-Clause & MIT & BSL-1.0"
7LIC_FILES_CHKSUM = "\
8    file://LICENSE;md5=4921372a1fb38469e667c38b17a1c4b3 \
9    file://include/cereal/external/rapidxml/license.txt;md5=d63ab70ba21ca0544b03284958324301 \
10    file://include/cereal/external/LICENSE;md5=b07578c9df99c0b8b45eb041efd4a645 \
11    file://include/cereal/external/rapidjson/LICENSE;md5=e7abb663111d4ac17cf00323698aff08 \
12    file://include/cereal/external/rapidjson/msinttypes/LICENSE;md5=dffce65b98c773976de2e338bd130f46 \
13"
14
15DEPENDS = " ${@bb.utils.contains('DISTRO_FEATURES', 'ptest', 'boost', '', d)} "
16
17PROVIDES += "${PN}-dev"
18
19PV .= "+git${SRCPV}"
20SRCREV = "ebef1e929807629befafbb2918ea1a08c7194554"
21SRC_URI = "git://github.com/USCiLab/cereal.git;branch=master;protocol=https \
22           file://run-ptest \
23"
24
25S = "${WORKDIR}/git"
26
27inherit cmake pkgconfig ptest
28
29LIBATOMIC:mips = "${@bb.utils.contains('PTEST_ENABLED', '1', '-DCEREAL_THREAD_LIBS="-latomic"', '', d)}"
30LIBATOMIC:riscv32 = "${@bb.utils.contains('PTEST_ENABLED', '1', '-DCEREAL_THREAD_LIBS="-latomic"', '', d)}"
31
32PACKAGECONFIG ??= "${@bb.utils.contains('PTEST_ENABLED', '1', 'with-tests', '', d)}"
33PACKAGECONFIG[with-tests] = "-DWITH_WERROR=OFF -DBUILD_TESTS=ON ${LIBATOMIC},,"
34EXTRA_OECMAKE = "${@bb.utils.contains('DISTRO_FEATURES', 'ptest', '', '-DJUST_INSTALL_CEREAL=ON', d)} \
35                 ${@['','-DSKIP_PORTABILITY_TEST=ON'][d.getVar('SITEINFO_BITS') != '32']}"
36
37do_install_ptest() {
38    install -d ${D}${PTEST_PATH}/tests
39    cp ${B}/unittests/test_*  ${D}${PTEST_PATH}/tests
40}
41
42ALLOW_EMPTY:${PN} = "1"
43
44RDEPENDS:${PN}-dev = ""
45
46BBCLASSEXTEND = "native nativesdk"
47
48#it needs to work with CXXFLAGS += " -mlong-double-64" but ppc64 only supports 128bit long double
49COMPATIBLE_HOST:powerpc64le = "null"
50COMPATIBLE_HOST:powerpc = "null"
51