1SUMMARY = "A C++11 library for serialization"
2HOMEPAGE = "https://uscilab.github.io/cereal/"
3
4SECTION = "libs"
5
6LICENSE = "BSD-3-Clause & MIT & BSL-1.0"
7LIC_FILES_CHKSUM = "\
8    file://LICENSE;md5=4921372a1fb38469e667c38b17a1c4b3 \
9    file://include/cereal/external/rapidxml/license.txt;md5=d63ab70ba21ca0544b03284958324301 \
10    file://include/cereal/external/LICENSE;md5=b07578c9df99c0b8b45eb041efd4a645 \
11    file://include/cereal/external/rapidjson/LICENSE;md5=e7abb663111d4ac17cf00323698aff08 \
12    file://include/cereal/external/rapidjson/msinttypes/LICENSE;md5=dffce65b98c773976de2e338bd130f46 \
13"
14
15DEPENDS = " ${@bb.utils.contains('DISTRO_FEATURES', 'ptest', 'boost', '', d)} "
16
17PROVIDES += "${PN}-dev"
18
19PV .= "+git"
20SRCREV = "ebef1e929807629befafbb2918ea1a08c7194554"
21SRC_URI = "git://github.com/USCiLab/cereal.git;branch=master;protocol=https \
22           file://0001-sandbox-Do-not-use-int8_t-in-std-uniform_int_distrib.patch \
23           file://0001-cmake-Use-idirafter-instead-of-isystem.patch \
24           file://0001-doctest-Do-not-use-unnamed-class.patch \
25           file://run-ptest \
26"
27
28S = "${WORKDIR}/git"
29
30inherit cmake pkgconfig ptest
31
32CXXFLAGS:append:toolchain-clang = " -Wno-error=c++11-narrowing-const-reference"
33
34LIBATOMIC:mips = "${@bb.utils.contains('PTEST_ENABLED', '1', '-DCEREAL_THREAD_LIBS="-latomic"', '', d)}"
35LIBATOMIC:riscv32 = "${@bb.utils.contains('PTEST_ENABLED', '1', '-DCEREAL_THREAD_LIBS="-latomic"', '', d)}"
36LIBATOMIC:powerpc = "${@bb.utils.contains('PTEST_ENABLED', '1', '-DCEREAL_THREAD_LIBS="-latomic"', '', d)}"
37
38PACKAGECONFIG ??= "${@bb.utils.contains('PTEST_ENABLED', '1', 'with-tests', '', d)}"
39PACKAGECONFIG[with-tests] = "-DWITH_WERROR=OFF -DBUILD_TESTS=ON ${LIBATOMIC},,"
40EXTRA_OECMAKE = "${@bb.utils.contains('DISTRO_FEATURES', 'ptest', '', '-DJUST_INSTALL_CEREAL=ON', d)} \
41                 ${@['','-DSKIP_PORTABILITY_TEST=ON'][d.getVar('SITEINFO_BITS') != '32']}"
42
43do_install_ptest() {
44    install -d ${D}${PTEST_PATH}/tests
45    cp ${B}/unittests/test_*  ${D}${PTEST_PATH}/tests
46}
47
48ALLOW_EMPTY:${PN} = "1"
49
50RDEPENDS:${PN}-dev = ""
51
52BBCLASSEXTEND = "native nativesdk"
53
54#it needs to work with CXXFLAGS += " -mlong-double-64" but ppc only supports 128bit long double
55COMPATIBLE_HOST:powerpc:libc-musl = "null"
56COMPATIBLE_HOST:powerpc64le:libc-musl = "null"
57