1SUMMARY = "Implementation of XDG Sound Theme and Name Specifications"
2DESCRIPTION = "Libcanberra is an implementation of the XDG Sound Theme and Name Specifications, for generating event sounds on free desktops."
3LICENSE = "LGPLv2.1+"
4LIC_FILES_CHKSUM = "file://LGPL;md5=2d5025d4aa3495befef8f17206a5b0a1 \
5                    file://src/canberra.h;beginline=7;endline=24;md5=c616c687cf8da540a14f917e0d23ab03"
6
7DEPENDS = "libtool libvorbis"
8
9inherit autotools gtk-doc
10
11SRC_URI = " \
12    http://0pointer.de/lennart/projects/${BPN}/${BPN}-${PV}.tar.xz \
13    file://0001-build-gtk-and-gtk3-version-for-canberra_gtk_play.patch \
14    file://0001-gtk-Don-t-assume-all-GdkDisplays-are-GdkX11Displays-.patch \
15"
16SRC_URI[md5sum] = "34cb7e4430afaf6f447c4ebdb9b42072"
17SRC_URI[sha256sum] = "c2b671e67e0c288a69fc33dc1b6f1b534d07882c2aceed37004bf48c601afa72"
18
19EXTRA_OECONF = "\
20    --enable-null \
21    --disable-oss \
22    --disable-tdb \
23    --disable-lynx \
24"
25
26PACKAGECONFIG ??= "${@bb.utils.filter('DISTRO_FEATURES', 'alsa pulseaudio', d)} \
27                   ${@bb.utils.contains('DISTRO_FEATURES', 'x11', 'gtk gtk3', '', d)} \
28"
29PACKAGECONFIG[alsa] = "--enable-alsa, --disable-alsa, alsa-lib"
30PACKAGECONFIG[pulseaudio] = "--enable-pulse, --disable-pulse, pulseaudio"
31PACKAGECONFIG[gstreamer] = "--enable-gstreamer, --disable-gstreamer, gstreamer1.0"
32PACKAGECONFIG[gtk] = "--enable-gtk, --disable-gtk, gtk+"
33PACKAGECONFIG[gtk3] = "--enable-gtk3, --disable-gtk3, gtk+3"
34
35python populate_packages:prepend() {
36    plugindir = d.expand('${libdir}/${BPN}-${PV}/')
37    do_split_packages(d, plugindir, '^libcanberra-(.*)\.so$', 'libcanberra-%s', '%s support library', extra_depends='' )
38    do_split_packages(d, plugindir, '^libcanberra-(.*)\.la$', 'libcanberra-%s', '%s support library', extra_depends='' )
39}
40
41PACKAGES =+ "${PN}-gnome ${PN}-gtk2 ${PN}-gtk3 ${PN}-systemd"
42PACKAGES_DYNAMIC += "^libcanberra-.*"
43
44FILES:${PN} = "${bindir}/ ${libdir}/${BPN}.so.*"
45
46FILES:${PN}-dev += "${datadir}/vala/vapi ${libdir}/*/modules/*.la ${libdir}/*/*.la"
47
48FILES:${PN}-dbg += "${libdir}/${BPN}-${PV}/.debug ${libdir}/gtk-*/modules/.debug"
49
50FILES:${PN}-gtk2 = "${libdir}/${BPN}-gtk.so.* \
51                    ${libdir}/gtk-2.0/modules/*.so \
52                    ${bindir}/canberra-gtk-play"
53
54# -gtk3 ships a symlink to a .so
55INSANE_SKIP:${PN}-gtk3 = "dev-so"
56FILES:${PN}-gtk3 = "${libdir}/${BPN}-gtk3.so.* \
57                    ${libdir}/gtk-3.0/modules/*.so \
58                    ${bindir}/canberra-gtk3-play"
59
60FILES:${PN}-gnome = "${libdir}/gnome-settings-daemon-3.0/ \
61                     ${datadir}/gdm/ ${datadir}/gnome/"
62
63FILES:${PN}-systemd = "${systemd_unitdir}/system/*.service"
64