1SUMMARY = "Implementation of XDG Sound Theme and Name Specifications"
2DESCRIPTION = "Libcanberra is an implementation of the XDG Sound Theme and Name Specifications, for generating event sounds on free desktops."
3LICENSE = "LGPL-2.1-or-later"
4LIC_FILES_CHKSUM = "file://LGPL;md5=2d5025d4aa3495befef8f17206a5b0a1 \
5                    file://src/canberra.h;beginline=7;endline=24;md5=c616c687cf8da540a14f917e0d23ab03"
6
7DEPENDS = "libtool libvorbis"
8
9inherit autotools gtk-doc
10
11SRC_URI = " \
12    http://0pointer.de/lennart/projects/${BPN}/${BPN}-${PV}.tar.xz \
13    file://0001-build-gtk-and-gtk3-version-for-canberra_gtk_play.patch \
14    file://0001-gtk-Don-t-assume-all-GdkDisplays-are-GdkX11Displays-.patch \
15    file://0001-remove-dropped-templates.patch \
16"
17SRC_URI[md5sum] = "34cb7e4430afaf6f447c4ebdb9b42072"
18SRC_URI[sha256sum] = "c2b671e67e0c288a69fc33dc1b6f1b534d07882c2aceed37004bf48c601afa72"
19
20EXTRA_OECONF = "\
21    --enable-null \
22    --disable-oss \
23    --disable-tdb \
24    --disable-lynx \
25"
26
27PACKAGECONFIG ??= "${@bb.utils.filter('DISTRO_FEATURES', 'alsa pulseaudio', d)} \
28                   ${@bb.utils.contains('DISTRO_FEATURES', 'x11', 'gtk gtk3', '', d)} \
29"
30PACKAGECONFIG[alsa] = "--enable-alsa, --disable-alsa, alsa-lib"
31PACKAGECONFIG[pulseaudio] = "--enable-pulse, --disable-pulse, pulseaudio"
32PACKAGECONFIG[gstreamer] = "--enable-gstreamer, --disable-gstreamer, gstreamer1.0"
33PACKAGECONFIG[gtk] = "--enable-gtk, --disable-gtk, gtk+"
34PACKAGECONFIG[gtk3] = "--enable-gtk3, --disable-gtk3, gtk+3"
35
36python populate_packages:prepend() {
37    plugindir = d.expand('${libdir}/${BPN}-${PV}/')
38    do_split_packages(d, plugindir, r'^libcanberra-(.*)\.so$', 'libcanberra-%s', '%s support library', extra_depends='' )
39    do_split_packages(d, plugindir, r'^libcanberra-(.*)\.la$', 'libcanberra-%s', '%s support library', extra_depends='' )
40}
41
42PACKAGES =+ "${PN}-gnome ${PN}-gtk2 ${PN}-gtk3 ${PN}-systemd"
43PACKAGES_DYNAMIC += "^libcanberra-.*"
44
45FILES:${PN} = "${bindir}/ ${libdir}/${BPN}.so.*"
46
47FILES:${PN}-dev += "${datadir}/vala/vapi ${libdir}/*/modules/*.la ${libdir}/*/*.la"
48
49FILES:${PN}-dbg += "${libdir}/${BPN}-${PV}/.debug ${libdir}/gtk-*/modules/.debug"
50
51FILES:${PN}-gtk2 = "${libdir}/${BPN}-gtk.so.* \
52                    ${libdir}/gtk-2.0/modules/*.so \
53                    ${bindir}/canberra-gtk-play"
54
55# -gtk3 ships a symlink to a .so
56INSANE_SKIP:${PN}-gtk3 = "dev-so"
57FILES:${PN}-gtk3 = "${libdir}/${BPN}-gtk3.so.* \
58                    ${libdir}/gtk-3.0/modules/*.so \
59                    ${bindir}/canberra-gtk3-play"
60
61FILES:${PN}-gnome = "${libdir}/gnome-settings-daemon-3.0/ \
62                     ${datadir}/gdm/ ${datadir}/gnome/"
63
64FILES:${PN}-systemd = "${systemd_unitdir}/system/*.service"
65