1DESCRIPTION = "The glog library implements application-level logging. This \
2library provides logging APIs based on C++-style streams and various helper \
3macros."
4HOMEPAGE = "https://github.com/google/glog"
5
6LICENSE = "BSD-3-Clause"
7LIC_FILES_CHKSUM = "file://COPYING;md5=dc9db360e0bbd4e46672f3fd91dd6c4b"
8
9SRC_URI = " \
10    git://github.com/google/glog.git;branch=master;protocol=https \
11    file://libexecinfo.patch \
12    file://0001-Change-SleepForMilliseconds-parameter-from-unsigned-.patch \
13"
14
15SRCREV = "b33e3bad4c46c8a6345525fd822af355e5ef9446"
16
17S = "${WORKDIR}/git"
18
19inherit cmake
20
21PACKAGECONFIG ?= "shared unwind 64bit-atomics"
22PACKAGECONFIG:remove:riscv64 = "unwind"
23PACKAGECONFIG:remove:riscv32 = "unwind 64bit-atomics"
24PACKAGECONFIG:remove:mipsarch = "64bit-atomics"
25PACKAGECONFIG:remove:armv5 = "64bit-atomics"
26PACKAGECONFIG:remove:armv6 = "64bit-atomics"
27
28PACKAGECONFIG:append:libc-musl:riscv64 = " execinfo"
29PACKAGECONFIG:append:libc-musl:riscv32 = " execinfo"
30
31PACKAGECONFIG[unwind] = "-DWITH_UNWIND=ON,-DWITH_UNWIND=OFF,libunwind,libunwind"
32PACKAGECONFIG[execinfo] = ",,libexecinfo"
33PACKAGECONFIG[shared] = "-DBUILD_SHARED_LIBS=ON,-DBUILD_SHARED_LIBS=OFF,,"
34PACKAGECONFIG[64bit-atomics] = ",-DCMAKE_CXX_STANDARD_LIBRARIES='-latomic',,"
35
36do_configure:append() {
37    # remove WORKDIR info to improve reproducibility
38    if [ -f  "${B}/config.h" ] ; then
39        sed -i 's/'$(echo ${WORKDIR} | sed 's_/_\\/_g')'/../g' ${B}/config.h
40    fi
41}
42
43FILES:${PN}-dev += "${datadir}/${BPN}/cmake"
44