1require ${BPN}.inc
2
3DEPENDS = "alsa-lib zlib jpeg libpng libxext libxft"
4
5inherit features_check binconfig lib_package gtk-icon-cache mime mime-xdg
6REQUIRED_DISTRO_FEATURES = "x11"
7
8SRC_URI += "file://0003-fluid-CMakeLists.txt-Do-not-export-fluid-target.patch"
9
10EXTRA_OECMAKE = " \
11    -DOPTION_BUILD_SHARED_LIBS=ON \
12    -DOPTION_USE_THREADS=ON \
13    -DFLTK_BUILD_TEST=OFF \
14    -DOPTION_USE_XDBE=ON \
15    -DOPTION_USE_XFT=ON \
16    -DFLTK_CONFIG_PATH=${libdir}/cmake \
17"
18
19PACKAGECONFIG ??= "${@bb.utils.filter('DISTRO_FEATURES', 'opengl', d)}"
20
21PACKAGECONFIG[cairo] = "-DOPTION_CAIRO=ON,-DOPTION_CAIRO=OFF,cairo"
22PACKAGECONFIG[opengl] = "-DOPTION_USE_GL=ON,-DOPTION_USE_GL=OFF,virtual/libgl"
23PACKAGECONFIG[xinerama] = "-DOPTION_USE_XINERAMA=ON,-DOPTION_USE_XINERAMA=OFF,libxinerama"
24PACKAGECONFIG[xfixes] = "-DOPTION_USE_XFIXES=ON,-DOPTION_USE_XFIXES=OFF,libxfixes"
25PACKAGECONFIG[xcursor] = "-DOPTION_USE_XCURSOR=ON,-DOPTION_USE_XCURSOR=OFF,libxcursor"
26
27do_install:append() {
28    sed -i -e 's,${STAGING_DIR_HOST},,g' ${D}${bindir}/fltk-config
29}
30
31python populate_packages:prepend () {
32    if (d.getVar('DEBIAN_NAMES')):
33        d.setVar('PKG:${BPN}', 'libfltk${PV}')
34}
35
36LEAD_SONAME = "libfltk.so"
37
38# .desktop / icons / mime only necessary for fluid app
39FILES:${PN}-bin += " \
40    ${datadir}/applications \
41    ${datadir}/icons \
42    ${datadir}/mime \
43"
44
45# cmake files
46FILES:${PN}-dev += "${datadir}/fltk"
47