1DESCRIPTION = "C-Kermit is a combined serial and network communication \
2software package offering a consistent, medium-independent, \
3cross-platform approach to connection establishment, terminal \
4sessions, file transfer, character-set translation, and automation \
5of communication tasks."
6HOMEPAGE = "www.kermitproject.org/ck90.html"
7SECTION = "console/network"
8LICENSE = "BSD-3-Clause"
9LIC_FILES_CHKSUM = "file://COPYING.TXT;md5=932ca542d6c6cb8a59a0bcd76ab67cc3"
10
11SRC_URI = "http://www.kermitproject.org/ftp/kermit/archives/cku${PV}.tar.gz;subdir=${BPN}-${PV}"
12SRC_URI[md5sum] = "eac4dbf18b45775e4cdee5a7c74762b0"
13SRC_URI[sha256sum] = "0d5f2cd12bdab9401b4c836854ebbf241675051875557783c332a6a40dac0711"
14
15
16export CC2 = "${CC}"
17export BINDIR = "${bindir}"
18export MANDIR = "${mandir}/man1"
19export INFODIR = "${infodir}"
20
21EXTRA_OEMAKE = "-e MAKEFLAGS="
22
23TARGET_CC_ARCH += "${LDFLAGS}"
24
25do_compile () {
26    # The original makefile doesn't differentiate between CC and CC_FOR_BUILD,
27    # so we build wart manually. Note that you need a ckwart.o with the proper
28    # timestamp to make this hack work:
29    ${BUILD_CC} -c ckwart.c
30    ${BUILD_CC} -o wart ckwart.o
31    ./wart ckcpro.w ckcpro.c
32
33    # read ${S}/ckccfg.txt to understand this :-)
34    oe_runmake wermit CFLAGS="${CFLAGS} -DLINUX -DCK_POSIX_SIG \
35        -DNOTCPOPTS -DLINUXFSSTND -DNOCOTFMC -DPOSIX -DUSE_STRERROR \
36        -DNOSYSLOG -DHAVE_PTMX -DNO_DNS_SRV -DNOGFTIMER \
37        -DNOB_50 -DNOB_75 -DNOB_134 -DNOB_150 -DNOB_200 \
38        -DNOB_1800 -DNOB_3600 -DNOB_7200 -DNOB_76K -DNOB_230K \
39        -DNOB_460K -DNOB_921K \
40        -DNOCSETS -DNONET -DNOUNICODE -DNOHELP -DNODEBUG \
41        -DNOFRILLS -DNOFTP -DNODIAL -DNOPUSH -DNOIKSD -DNOHTTP -DNOFLOAT \
42        -DNOSERVER -DNOSEXP -DNORLOGIN -DNOOLDMODEMS -DNOSSH -DNOLISTEN \
43        -DNORESEND -DNOAUTODL -DNOSTREAMING -DNOHINTS -DNOCKXYZ -DNOLEARN \
44        -DNOMKDIR -DNOPERMS -DNOCKTIMERS -DNOCKREGEX -DNOREALPATH \
45        -DCK_SMALL -DNOLOGDIAL -DNORENAME -DNOWHATAMI \
46        -DNOARROWKEYS"
47}
48
49do_install () {
50    install -d ${D}${BINDIR} ${D}${MANDIR} ${D}${INFODIR}
51    oe_runmake 'DESTDIR=${D}' install
52    # Fix up dangling symlink
53    rm ${D}${BINDIR}/kermit-sshsub
54    (cd ${D}${BINDIR} && ln -s ${BINDIR}/kermit kermit-sshusb)
55}
56