1SUMMARY = "Augeas configuration API"
2HOMEPAGE = "http://augeas.net/"
3BUGTRACKER = "https://fedorahosted.org/augeas/report/1"
4
5LICENSE = "LGPL-2.1-or-later"
6LIC_FILES_CHKSUM = "file://COPYING;md5=bbb461211a33b134d42ed5ee802b37ff"
7
8SRC_URI = "http://download.augeas.net/${BP}.tar.gz \
9           file://sepbuildfix.patch \
10           file://0001-src-internal-Use-__GLIBC__-to-check-for-GNU-extentio.patch \
11          "
12SRC_URI[sha256sum] = "321942c9cc32185e2e9cb72d0a70eea106635b50269075aca6714e3ec282cb87"
13
14DEPENDS = "readline libxml2"
15
16inherit autotools pkgconfig
17
18PACKAGES =+ "${PN}-lenses lib${BPN}"
19
20FILES:${PN}-lenses = "${datadir}/augeas/lenses"
21FILES:lib${BPN} = "${libdir}/lib*${SOLIBS}"
22
23RDEPENDS:lib${BPN} += "${PN}-lenses"
24RRECOMMENDS:lib${BPN} += "${PN}"
25
26LEAD_SONAME = "libaugeas.so"
27
28do_install:append() {
29    rm -fr ${D}${datadir}/vim
30}
31
32PACKAGECONFIG ??= "${@bb.utils.filter('DISTRO_FEATURES', 'selinux', d)}"
33PACKAGECONFIG[selinux] = "--with-selinux,--without-selinux,libselinux"
34
35EXTRA_AUTORECONF += "-I ${S}/gnulib/m4"
36