1SUMMARY = "v4l2 and IR applications"
2LICENSE = "GPL-2.0-only & LGPL-2.1-only"
3LIC_FILES_CHKSUM = "file://COPYING;md5=48da9957849056017dc568bbc43d8975 \
4                    file://COPYING.libv4l;md5=d749e86a105281d7a44c2328acebc4b0"
5PROVIDES = "libv4l media-ctl"
6
7DEPENDS = "jpeg \
8           ${@bb.utils.contains('DISTRO_FEATURES', 'x11', 'virtual/libx11', '', d)} \
9           ${@bb.utils.contains('DISTRO_FEATURES', 'systemd', 'systemd', '', d)} \
10           ${@bb.utils.contains('DISTRO_FEATURES', 'alsa', 'alsa-lib', '', d)} \
11           ${@bb.utils.contains_any('PACKAGECONFIG', 'qv4l2 qvidcap', 'qtbase qtbase-native', '', d)}"
12
13DEPENDS:append:libc-musl = " argp-standalone"
14DEPENDS:append:class-target = " udev"
15LDFLAGS:append = " -pthread"
16# v4l2 explicitly sets _FILE_OFFSET_BITS=32 to get access to
17# both 32 and 64 bit file APIs.  But it does not handle the time side?
18# Needs further investigation
19GLIBC_64BIT_TIME_FLAGS = ""
20
21inherit meson gettext pkgconfig
22
23PACKAGECONFIG ??= ""
24PACKAGECONFIG[qv4l2] = ",-Dqv4l2=disabled"
25PACKAGECONFIG[qvidcap] = ",-Dqvidcap=disabled"
26PACKAGECONFIG[v4l2-tracer] = ",-Dv4l2-tracer=disabled,json-c"
27
28SRC_URI = "\
29    git://git.linuxtv.org/v4l-utils.git;protocol=https;branch=stable-1.28 \
30    file://0001-media-ctl-Install-media-ctl-header-and-library-files.patch \
31    file://0002-media-ctl-Install-media-ctl-pkg-config-files.patch \
32"
33
34SRCREV = "fc15e229d9d337e46d730f00647821adbbd58548"
35
36S = "${WORKDIR}/git"
37
38UPSTREAM_CHECK_GITTAGREGEX = "v4l-utils-(?P<pver>\d+(\.\d+)+)"
39
40EXTRA_OEMESON = "-Dudevdir=${base_libdir}/udev -Dv4l2-compliance-32=false -Dv4l2-ctl-32=false"
41
42# Disable the erroneous installation of gconv-modules that would break glib
43# like it is done in Debian and ArchLinux.
44EXTRA_OEMESON += "-Dgconv=disabled"
45
46VIRTUAL-RUNTIME_ir-keytable-keymaps ?= "rc-keymaps"
47
48PACKAGES =+ "media-ctl ir-keytable rc-keymaps libv4l libv4l-dev qv4l2 qvidcap"
49
50RPROVIDES:${PN}-dbg += "libv4l-dbg"
51
52FILES:media-ctl = "${bindir}/media-ctl ${libdir}/libmediactl.so.*"
53FILES:qv4l2 = "\
54    ${bindir}/qv4l2 \
55    ${datadir}/applications/qv4l2.desktop \
56    ${datadir}/icons/hicolor/*/apps/qv4l2.* \
57"
58FILES:qvidcap = "\
59    ${bindir}/qvidcap \
60    ${datadir}/applications/qvidcap.desktop \
61    ${datadir}/icons/hicolor/*/apps/qvidcap.* \
62"
63
64FILES:ir-keytable = "${bindir}/ir-keytable ${base_libdir}/udev/rules.d/*-infrared.rules"
65RDEPENDS:ir-keytable += "${VIRTUAL-RUNTIME_ir-keytable-keymaps}"
66RDEPENDS:qv4l2 += "\
67    ${@bb.utils.contains('PACKAGECONFIG', 'qv4l2', 'qtbase', '', d)}"
68RDEPENDS:qvidcap += "\
69    ${@bb.utils.contains('PACKAGECONFIG', 'qvidcap', 'qtbase', '', d)}"
70
71FILES:rc-keymaps = "${sysconfdir}/rc* ${base_libdir}/udev/rc*"
72
73FILES:${PN} = "${bindir} ${sbindir}"
74
75FILES:libv4l += "${libdir}/libv4l*${SOLIBS} ${libdir}/libv4l/*.so ${libdir}/libv4l/plugins/*.so \
76                 ${libdir}/libdvbv5*${SOLIBS} \
77                 ${libdir}/libv4l/*-decomp \
78                 ${libdir}/libv4l2tracer.so \
79"
80
81FILES:libv4l-dev += "${includedir} ${libdir}/pkgconfig \
82                     ${libdir}/libv4l*${SOLIBSDEV} ${libdir}/*.la \
83                     ${libdir}/v4l*${SOLIBSDEV} ${libdir}/libv4l/*.la ${libdir}/libv4l/plugins/*.la"
84
85PARALLEL_MAKE:class-native = ""
86BBCLASSEXTEND = "native"
87