1# live555 OE build file
2# Copyright (C) 2005, Koninklijke Philips Electronics NV.  All Rights Reserved
3# Released under the MIT license (see packages/COPYING)
4
5DESCRIPTION = "LIVE555 Streaming Media libraries"
6HOMEPAGE = "http://live.com/"
7LICENSE = "LGPL-3.0-only"
8SECTION = "devel"
9
10DEPENDS = "openssl"
11
12URLV = "${@d.getVar('PV')[0:4]}.${@d.getVar('PV')[4:6]}.${@d.getVar('PV')[6:8]}"
13SRC_URI = "https://download.videolan.org/pub/contrib/live555/live.${URLV}.tar.gz \
14           file://config.linux-cross"
15
16# only latest live version stays on http://www.live555.com/liveMedia/public/, add mirror for older
17MIRRORS += "http://www.live555.com/liveMedia/public/ http://download.videolan.org/contrib/live555/ \n"
18
19SRC_URI[sha256sum] = "ce95a1c79f6d18e959f9dc129b8529b711c60e76754acc285e60946303b923ec"
20
21S = "${WORKDIR}/live"
22
23LIC_FILES_CHKSUM = "file://COPYING;md5=d32239bcb673463ab874e80d47fae504 \
24                    file://COPYING.LESSER;md5=e6a600fd5e1d9cbde2d983680233ad02 \
25                   "
26
27TARGET_CC_ARCH += "${LDFLAGS}"
28
29do_configure() {
30    cp ${WORKDIR}/config.linux-cross .
31    echo "COMPILE_OPTS+=" -fPIC -DXLOCALE_NOT_USED"" >> config.linux-cross
32    ./genMakefiles linux-cross
33}
34
35do_install() {
36    install -d ${D}${includedir}/BasicUsageEnvironment
37    install -d ${D}${includedir}/groupsock
38    install -d ${D}${includedir}/liveMedia
39    install -d ${D}${includedir}/UsageEnvironment
40    install -d ${D}${libdir}
41    cp -R --no-dereference --preserve=mode,links -v ${S}/BasicUsageEnvironment/include/*.hh ${D}${includedir}/BasicUsageEnvironment/
42    cp -R --no-dereference --preserve=mode,links -v ${S}/groupsock/include/*.h ${D}${includedir}/groupsock/
43    cp -R --no-dereference --preserve=mode,links -v ${S}/groupsock/include/*.hh ${D}${includedir}/groupsock/
44    cp -R --no-dereference --preserve=mode,links -v ${S}/liveMedia/include/*.hh ${D}${includedir}/liveMedia/
45    cp -R --no-dereference --preserve=mode,links -v ${S}/UsageEnvironment/include/*.hh ${D}${includedir}/UsageEnvironment/
46    # Find all the headers
47    for i in $(find . -name "*.hh") $(find . -name "*.h") ; do
48        install ${i} ${D}${includedir}
49    done
50    cp ${S}/*/*.a ${D}${libdir}
51    install -d ${D}${bindir}
52    for i in MPEG2TransportStreamIndexer openRTSP playSIP sapWatch testMPEG1or2ProgramToTransportStream testMPEG1or2Splitter testMPEG1or2VideoReceiver testMPEG2TransportStreamTrickPlay testOnDemandRTSPServer testRelay testAMRAudioStreamer testDVVideoStreamer testMP3Receiver testMP3Streamer testMPEG1or2AudioVideoStreamer testMPEG1or2VideoStreamer testMPEG2TransportStreamer testMPEG4VideoStreamer testWAVAudioStreamer vobStreamer; do
53        install -m 0755 ${S}/testProgs/${i} ${D}${bindir}/
54    done
55    install -m 0755 ${S}/mediaServer/live555MediaServer ${D}${bindir}/
56}
57
58RDEPENDS:${PN}-dev = ""
59PACKAGES =+ "live555-openrtsp live555-playsip live555-mediaserver live555-examples"
60FILES:live555-openrtsp = "${bindir}/openRTSP"
61FILES:live555-playsip = "${bindir}/playSIP"
62FILES:live555-mediaserver = "${bindir}/live555MediaServer"
63FILES:live555-examples = "${bindir}/*"
64