1SUMMARY = "Common X11 scripts and support files"
2LICENSE = "GPL-2.0-only"
3LIC_FILES_CHKSUM = "file://COPYING;md5=751419260aa954499f7abaabaa882bbe"
4
5
6# we are using a gpe-style Makefile
7inherit features_check gpe
8
9REQUIRED_DISTRO_FEATURES = "x11"
10
11SRC_URI[md5sum] = "82f2f84cd96610e8f7b92c700cd31c14"
12SRC_URI[sha256sum] = "cd04c33418f776b1e13fcc7af3d6bd0c7cccd03fbabd7dbcd97f88166cc34210"
13
14SRC_URI:append = " \
15    file://0001-COPYING-add-GPLv2-license-file.patch \
16    file://0002-add-setdpi-Xinit.d-script.patch \
17    file://0006-add-support-for-etc-X11-xserver-system.patch \
18    file://0007-use-own-functions-file-instead-etc-init.d-functions.patch \
19    file://0008-xserver-common-add-dpi-and-nocursor-params-for-gta01.patch \
20    file://0009-xserver-common-add-support-for-n900-alias-nokia_rx-5.patch \
21    file://0010-xserver-common-add-support-for-nexus-S-alias-herring.patch \
22    file://0011-xserver-common-add-support-for-nexus-one-alias-mahim.patch \
23    file://0012-xserver-common-add-support-for-gta04-alias-OpenPhoen.patch \
24    file://0013-xserver-common-add-support-for-tuna-alias-Galaxy-Nex.patch \
25    file://0015-xserver-common-disable-TCP-connections.patch \
26    file://0001-Don-t-install-Xsession-or-Xserver.patch \
27"
28
29do_install:append() {
30    sed -i 's:^BINDIR=.*$:BINDIR=${bindir}:' ${D}/etc/X11/xserver-common
31    # Rename all Xsession files not ending with .sh
32    # Unfortunatelly when xinput-calibrator was moved to oe-core
33    # its Xsession file got name 30xinput_calibrate.sh and ls -X sorts it
34    # last, not respecting numbers for sorting them
35    for i in ${D}/${sysconfdir}/X11/Xsession.d/*; do
36        echo $i | grep '.sh$' || mv $i $i.sh
37    done
38}
39
40RDEPENDS:${PN} = "xmodmap xrandr xdpyinfo fbset xinput-calibrator"
41
42RCONFLICTS:${PN} = "xserver-kdrive-common x11-common"
43RREPLACES:${PN} = "xserver-kdrive-common x11-common"
44
45