1require ttf.inc
2
3SUMMARY = "DejaVu font - TTF Edition"
4HOMEPAGE = "http://dejavu.sourceforge.net/wiki/"
5LICENSE = "BitstreamVera"
6LIC_FILES_CHKSUM = "file://../LICENSE;md5=449b2c30bfe5fa897fe87b8b70b16cfa"
7
8# all subpackages except ${PN}-common itself rdepends on ${PN}-common
9RDEPENDS:${PN}-sans = "${PN}-common"
10RDEPENDS:${PN}-sans-mono = "${PN}-common"
11RDEPENDS:${PN}-sans-condensed = "${PN}-common"
12RDEPENDS:${PN}-serif = "${PN}-common"
13RDEPENDS:${PN}-serif-condensed = "${PN}-common"
14RDEPENDS:${PN}-mathtexgyre = "${PN}-common"
15RDEPENDS:${PN}-common = ""
16PR = "r7"
17
18SRC_URI = "${SOURCEFORGE_MIRROR}/dejavu/dejavu-fonts-ttf-${PV}.tar.bz2 \
19           file://30-dejavu-aliases.conf"
20
21S = "${WORKDIR}/dejavu-fonts-ttf-${PV}/ttf"
22
23UPSTREAM_CHECK_URI = "https://sourceforge.net/projects/dejavu/files/dejavu/"
24
25do_install:append () {
26    install -d ${D}${sysconfdir}/fonts/conf.d/
27    install -m 0644 ${WORKDIR}/30-dejavu-aliases.conf ${D}${sysconfdir}/fonts/conf.d/
28}
29
30PACKAGES = "\
31            ${PN}-sans \
32            ${PN}-sans-mono \
33            ${PN}-sans-condensed \
34            ${PN}-serif \
35            ${PN}-serif-condensed \
36            ${PN}-mathtexgyre \
37            ${PN}-common"
38FONT_PACKAGES = "${PN}-sans ${PN}-sans-mono ${PN}-sans-condensed ${PN}-serif ${PN}-serif-condensed ${PN}-mathtexgyre"
39
40FILES:${PN}-sans            = "${datadir}/fonts/truetype/DejaVuSans.ttf ${datadir}/fonts/truetype/DejaVuSans-*.ttf"
41FILES:${PN}-sans-mono       = "${datadir}/fonts/truetype/DejaVuSansMono*.ttf"
42FILES:${PN}-sans-condensed  = "${datadir}/fonts/truetype/DejaVuSansCondensed*.ttf"
43FILES:${PN}-serif           = "${datadir}/fonts/truetype/DejaVuSerif.ttf ${datadir}/fonts/truetype/DejaVuSerif-*.ttf"
44FILES:${PN}-serif-condensed = "${datadir}/fonts/truetype/DejaVuSerifCondensed*.ttf"
45FILES:${PN}-mathtexgyre     = "${datadir}/fonts/truetype/DejaVuMathTeXGyre.ttf"
46FILES:${PN}-common          = "${sysconfdir}"
47
48SRC_URI[md5sum] = "d0efec10b9f110a32e9b8f796e21782c"
49SRC_URI[sha256sum] = "fa9ca4d13871dd122f61258a80d01751d603b4d3ee14095d65453b4e846e17d7"
50
51BBCLASSEXTEND = "native nativesdk"
52
53# Allow installation of fonts into recipe-sysroot-native
54SYSROOT_DIRS_IGNORE:remove = "${datadir}/fonts"
55
56