1SUMMARY = "F Virtual Window Manager "
2HOMEPAGE = "http://www.fvwm.org/"
3SECTION = "x11/wm"
4LICENSE = "GPL-2.0-only"
5LIC_FILES_CHKSUM = "file://COPYING;md5=f8204787357db6ea518dcc9b6cf08388"
6
7DEPENDS = " \
8    bison-native \
9    flex-native \
10    freetype-native \
11    gettext-native \
12    libxslt-native \
13    fontconfig \
14    libice \
15    libpng \
16    librsvg \
17    libsm \
18    libxau \
19    libxcb \
20    libxcursor \
21    libxdmcp \
22    libxext \
23    libxfixes \
24    libxft \
25    libxinerama \
26    libxml2 \
27    libxrender \
28    libxt \
29    virtual/libx11 \
30    xrandr \
31    zlib \
32"
33
34SRC_URI = " \
35    git://github.com/fvwmorg/fvwm.git;protocol=https;branch=master \
36    file://0001-Fix-compilation-for-disabled-gnome.patch \
37"
38
39SRCREV = "7baf540e56fb1a3e91752acba872a88543529d46"
40
41S = "${WORKDIR}/git"
42
43inherit autotools gettext update-alternatives pkgconfig python3native perlnative features_check
44# depends on virtual/libx11
45REQUIRED_DISTRO_FEATURES = "x11"
46
47ALTERNATIVE:${PN} = "x-window-manager"
48ALTERNATIVE_TARGET[x-window-manager] = "${bindir}/fvwm"
49ALTERNATIVE_PRIORITY[x-window-manager] = "20"
50
51EXTRA_OECONF = " \
52    --disable-bidi \
53    --disable-fontconfigtest \
54    --disable-htmldoc \
55    --disable-imlibtest \
56    --disable-nls \
57    --disable-perllib \
58    --disable-rsvg \
59    --disable-shape \
60    --disable-sm \
61    --disable-xfttest \
62    --with-imlib-exec-prefix=/nonexistent \
63    --with-imlib-prefix=/nonexistent \
64    --without-ncurses-library \
65    --without-readline-library \
66    --without-rplay-library \
67    --without-stroke-library \
68    --without-termcap-library \
69    --without-xpm-library \
70    ac_cv_func_mkstemp=no \
71    has_safety_mkstemp=yes \
72"
73
74# show the exact commands in the log file
75EXTRA_OEMAKE = " \
76    V=1 \
77"
78# clang treats them as errors by default now starting with 15.0+
79CFLAGS += "-Wno-error=int-conversion -Wno-error=implicit-int"
80
81do_install:append() {
82    install -d -m 0755 ${D}/${sysconfdir}/xdg/fvwm
83    # You can install the config file here
84
85    install -d -m 0755 ${D}/${datadir}/fvwm
86    touch ${D}/${datadir}/fvwm/ConfigFvwmDefaults
87    sed -i -e 's:${STAGING_BINDIR_NATIVE}/perl-native/perl:${USRBINPATH}/env perl:g' ${D}${bindir}/fvwm-*
88    sed -i -e 's:${STAGING_BINDIR_NATIVE}/perl-native/perl:${USRBINPATH}/env perl:g' ${D}${libexecdir}/fvwm/*/Fvwm*
89    sed -i -e 's:${STAGING_BINDIR_NATIVE}/python3-native/python3:${USRBINPATH}/env python3:g' ${D}${bindir}/fvwm-menu-desktop
90}
91
92# the only needed packages (note: locale packages are automatically generated
93# as well)
94PACKAGES = " \
95    ${PN} \
96    ${PN}-extra \
97    ${PN}-doc \
98    ${PN}-dbg \
99"
100
101# minimal set of binaries
102FILES:${PN} = " \
103    ${bindir}/fvwm \
104    ${bindir}/fvwm-root \
105    ${datadir}/fvwm/ConfigFvwmDefaults \
106"
107
108FILES:${PN}-extra = " \
109    ${bindir} \
110    ${libexecdir} \
111    ${sysconfdir}/xdg/fvwm \
112"
113FILES:${PN}-doc = " \
114    ${mandir} \
115    ${datadir}/fvwm \
116"
117RDEPENDS:${PN} = " \
118    xuser-account \
119"
120RDEPENDS:${PN}-extra += "\
121    perl \
122    python3-core \
123"
124