1require gtk+.inc
2
3LIC_FILES_CHKSUM = "file://COPYING;md5=3bf50002aefd002f49e7bb854063f7e7 \
4                    file://gtk/gtk.h;endline=27;md5=c59e0b4490dd135a5726ebf851f9b17f \
5                    file://gdk/gdk.h;endline=27;md5=07db285ec208fb3e0bf7d861b0614202 \
6                    file://tests/testgtk.c;endline=27;md5=262db5db5f776f9863e56df31423e24c"
7SRC_URI = "http://ftp.gnome.org/pub/gnome/sources/gtk+/2.24/gtk+-${PV}.tar.xz \
8           file://xsettings.patch \
9           file://toggle-font.diff;striplevel=0 \
10           file://doc-fixes.patch \
11           file://strict-prototypes.patch \
12           file://0001-Do-not-look-into-HOME-when-looking-for-gtk-modules.patch \
13           file://0001-Fix-signature-of-create_menu-function.patch \
14           file://CVE-2024-6655.patch \
15           "
16
17SRC_URI[sha256sum] = "ac2ac757f5942d318a311a54b0c80b5ef295f299c2a73c632f6bfb1ff49cc6da"
18
19EXTRA_OECONF = "--enable-xkb --disable-glibtest --disable-cups --disable-xinerama"
20
21LIBV = "2.10.0"
22
23PACKAGES_DYNAMIC += "^gtk-immodule-.* ^gtk-printbackend-.*"
24
25python populate_packages:prepend () {
26    gtk_libdir = d.expand('${libdir}/gtk-2.0/${LIBV}')
27    immodules_root = os.path.join(gtk_libdir, 'immodules')
28    printmodules_root = os.path.join(gtk_libdir, 'printbackends');
29
30    d.setVar('GTKIMMODULES_PACKAGES', ' '.join(do_split_packages(d, immodules_root, r'^im-(.*)\.so$', 'gtk-immodule-%s', 'GTK input module for %s')))
31    do_split_packages(d, printmodules_root, r'^libprintbackend-(.*)\.so$', 'gtk-printbackend-%s', 'GTK printbackend module for %s')
32
33    if (d.getVar('DEBIAN_NAMES')):
34        d.setVar(d.expand('PKG:${PN}'), '${MLPREFIX}libgtk-2.0')
35}
36
37CFLAGS += "-Wno-error=incompatible-pointer-types"
38