1SUMMARY = "Sensor/Actuator repository for Mraa"
2HOMEPAGE = "https://github.com/intel-iot-devkit/upm"
3SECTION = "libs"
4
5LICENSE = "MIT"
6LIC_FILES_CHKSUM = "file://LICENSE;md5=66493d54e65bfc12c7983ff2e884f37f"
7
8DEPENDS = "libjpeg-turbo mraa"
9
10SRCREV = "5cf20df96c6b35c19d5b871ba4e319e96b4df72d"
11PV = "2.0.0+git${SRCPV}"
12
13SRC_URI = "git://github.com/eclipse/${BPN}.git;protocol=http \
14           file://0001-CMakeLists.txt-Use-SWIG_SUPPORT_FILES-to-find-the-li.patch \
15           file://0001-Use-stdint-types.patch \
16           file://0001-initialize-local-variables-before-use.patch \
17           file://0001-cmake-Disable-Wno-misleading-indentation-with-clang-.patch \
18           file://0001-cmake-Disable-using-Wno-maybe-uninitialized.patch \
19           "
20
21SRC_URI:append:toolchain-clang:x86 = " file://0001-nmea_gps-Link-with-latomic.patch "
22
23S = "${WORKDIR}/git"
24
25# Depends on mraa which only supports x86 and ARM for now
26COMPATIBLE_HOST = "(x86_64.*|i.86.*|aarch64.*|arm.*)-linux"
27
28inherit distutils3-base cmake pkgconfig
29
30EXTRA_OECMAKE += "-UPYTHON_EXECUTABLE -DWERROR=off"
31
32# override this in local.conf to get needed bindings.
33# BINDINGS:pn-upm="python"
34# will result in only the python bindings being built/packaged.
35# Note: 'nodejs' is disabled by default because the bindings
36# generation currently fails with nodejs (>v7.x).
37BINDINGS ??= "python"
38
39# nodejs isn't available for armv4/armv5 architectures
40BINDINGS:armv4 ??= "python"
41BINDINGS:armv5 ??= "python"
42
43PACKAGECONFIG ??= "${@bb.utils.contains('PACKAGES', 'node-${PN}', 'nodejs', '', d)} \
44 ${@bb.utils.contains('PACKAGES', '${PYTHON_PN}-${PN}', 'python', '', d)}"
45
46PACKAGECONFIG[python] = "-DBUILDSWIGPYTHON=ON -DPYTHON_LIBRARY=${STAGING_LIBDIR}/lib${PYTHON_DIR}${PYTHON_ABI}.so -DPYTHON_INCLUDE_DIR=${STAGING_INCDIR}/${PYTHON_DIR}${PYTHON_ABI}, -DBUILDSWIGPYTHON=OFF, swig-native ${PYTHON_PN},"
47PACKAGECONFIG[nodejs] = "-DBUILDSWIGNODE=ON, -DBUILDSWIGNODE=OFF, swig-native nodejs-native,"
48
49do_configure:prepend() {
50    sed -i s:\"lib/${_packages_path}:\"${baselib}/${_packages_path}:g ${S}/cmake/modules/OpenCVDetectPython.cmake
51}
52
53FILES:${PYTHON_PN}-${PN} = "${PYTHON_SITEPACKAGES_DIR}"
54RDEPENDS:${PYTHON_PN}-${PN} += "${PYTHON_PN}"
55
56FILES:node-${PN} = "${prefix}/lib/node_modules/"
57RDEPENDS:node-${PN} += "nodejs"
58
59### Include desired language bindings ###
60PACKAGES =+ "${@bb.utils.contains('BINDINGS', 'nodejs', 'node-${PN}', '', d)}"
61PACKAGES =+ "${@bb.utils.contains('BINDINGS', 'python', '${PYTHON_PN}-${PN}', '', d)}"
62