1SUMMARY = "Transparent Inter-Process Communication protocol"
2LICENSE = "GPL-2.0-only"
3LIC_FILES_CHKSUM = "file://tipclog/tipc.h;endline=35;md5=985b6ea8735818511d276c1b466cce98"
4
5SRC_URI = "git://git.code.sf.net/p/tipc/tipcutils;branch=master \
6           file://0001-include-sys-select.h-for-FD_-definitions.patch \
7           file://0002-replace-non-standard-uint-with-unsigned-int.patch \
8           file://0001-multicast_blast-tipcc-Fix-struct-type-for-TIPC_GROUP.patch \
9           file://0001-test-ptts-Set-recv-buffer-size-too-max-to-receive-as.patch \
10           "
11SRCREV = "7ab2211b87414ba240b0b2e4af219c1057c9cf9a"
12PV = "2.2.0+git${SRCPV}"
13
14inherit autotools pkgconfig
15
16DEPENDS += "libdaemon"
17
18RDEPENDS:${PN} = "iproute2-tipc"
19
20S = "${WORKDIR}/git"
21
22do_configure:prepend() {
23    ( cd ${S}; ${S}/bootstrap )
24}
25
26do_install:append() {
27    demos="benchmark hello_world topology_subscr_demo connection_demo \
28           multicast_demo stream_demo"
29    for i in $demos;do
30        install -d ${D}/opt/tipcutils/demos/$i
31        install ${B}/demos/$i/client_tipc ${D}/opt/tipcutils/demos/$i/
32        install ${B}/demos/$i/server_tipc ${D}/opt/tipcutils/demos/$i/
33    done
34    install -d ${D}/opt/tipcutils/demos/inventory_sim
35    install ${B}/demos/inventory_sim/inventory_sim ${D}/opt/tipcutils/demos/inventory_sim/
36
37    install -d ${D}/opt/tipcutils/ptts
38    install ${B}/ptts/tipcTS ${D}/opt/tipcutils/ptts/
39    install ${B}/ptts/tipcTC ${D}/opt/tipcutils/ptts/
40
41    install -d ${D}${sysconfdir}
42    cp -R --no-dereference --preserve=mode,links -v ${S}/scripts/etc/* ${D}${sysconfdir}/
43    chown -R root:root ${D}${sysconfdir}
44}
45
46PACKAGES += "${PN}-demos"
47FILES:${PN}-dbg += "/opt/tipcutils/demos/*/.debug /opt/tipcutils/ptts/.debug"
48FILES:${PN}-demos = "/opt/tipcutils/*"
49
50